Kalender Script

Hur gör jag detta till en vanlig länk utan javascript popup?

Response.Write "<a href='javascript:popup(""view.asp?dd=" & dag & "&mm=" & mm & "&yy=" & yyyy & """,330,200);'>" & dag & "</a>"

Mvh Erik

Så att tex den 24 December 2003 blir länken,

view.asp?dd=24&mm=12&yy=2003

såhär?

<%
  Response.Write("<a href=""view.asp?dd=" & dag & "&mm=" & mm & "&yy=" & yyyy & ">" & idag & "</a>")
%>

Tack, men nja... det funkade inte som det skulle med den länk koden, det blev hel fel i tabellen.
Någon som vet hur man ska göra?
Här kommer hela sidan calendar.asp

<%
Function getMonth(monthNr)

	Select Case monthNr
		Case 1 manad = "January"
		Case 2 manad = "February"
		Case 3 manad = "March"
		Case 4 manad = "April"
		Case 5 manad = "May"
		Case 6 manad = "June"
		Case 7 manad = "July"
		Case 8 manad = "August"
		Case 9 manad = "September"
		Case 10 manad = "October"
		Case 11 manad = "November"
		Case 12	manad = "December"
	End Select
	
	getMonth = manad
	
End Function

Function getDays(monthNr)

	Select Case monthNr
		Case 1 days = 31
		Case 2 days = 28
		Case 3 days = 31
		Case 4 days = 30
		Case 5 days = 31
		Case 6 days = 30
		Case 7 days = 31
		Case 8 days = 31
		Case 9 days = 30
		Case 10 days = 31
		Case 11 days = 30
		Case 12	days = 31
	End Select
	
	getDays = days
	
End Function

Function getNext(s)
' s = sign (eg +,-)
' am = aktuell månad
' ay = aktuellt år
	
	If s = "+" Then
		If mm = 12 Then
			am = 1
			ay = yyyy + 1
		Else
			am = mm + 1
			ay = yyyy
		End If
	Else
		If mm = 1 Then
			am = 12
			ay = yyyy - 1
		Else
			am = mm - 1
			ay = yyyy
		End If
	End if
	
	getNext = am & "&y=" & ay
	
End Function

' Plocka fram aktuellt datum
datum	= Date
aManad 	= Month(datum)
aDag	= Day(datum)
aAr		= Year(datum)

' Vilken månad skall visas?
If Request.QueryString("m") <> "" Then
	mm 		= Request.QueryString("m")
	yyyy 	= Request.QueryString("y")
Else
	mm 		= Month(datum)
	yyyy 	= Year(datum)
End If

' Hur många rutor skall skippas första veckan?
skip 	=  DatePart("w", mm & "/1-"&yyyy, vbMonday) - 1

%>

<SCRIPT LANGUAGE="javascript">
<!--
function popup(url,width,height)
{
	unik=new Date();
	unik=unik.getSeconds()+"_"+unik.getMinutes()+"_"+unik.getHours();
	stuff = "toolbar=no,menubar=no,scrollbars=yes,resizable=no,width= " +width + ", height = " +height
	window.open(url , unik , stuff );
}
//-->
</SCRIPT>
<table width="175" border="0" cellspacing="0" cellpadding="1" bgcolor="#FFFFFF">
  <tr> 
    <td> 
      <div align="center"><b>M</b></div>
    </td>
    <td> 
      <div align="center"><b>T</b></div>
    </td>
    <td> 
      <div align="center"><b>W</b></div>
    </td>
    <td> 
      <div align="center"><b>T</b></div>
    </td>
    <td> 
      <div align="center"><b>F</b></div>
    </td>
    <td> 
      <div align="center"><b>S</b></div>
    </td>
    <td> 
      <div align="center"><b>S</b></div>
    </td>
  </tr>
  <%
		set Rs = Server.CreateObject("ADODB.Recordset") 
		RS.ActiveConnection = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & Server.Mappath("db/calendar.mdb") 
		RS.Source = "Select DISTINCT(dd) From handelser Where mm = " & mm & " And yyyy = " & yyyy & " Order By dd"
		RS.Open()

		dag = 1 - skip 
		x = 0 
		Do Until x > (getDays(mm) + skip) / 7 

			Response.Write "<tr>" 

			For y = 1 To 7 

				bgColor = "#FFFFFF" 
				If not RS.EOF Then 
					If int(dag) = int(RS("dd")) Then 
						bgColor = "#999999" 
						fontColor = "#33CCFF"
						skriv = "true"
						
						'RS.MoveNext 
					End If 
				End If
				
				If aDag&aManad&aAr = dag&mm&yyyy Then
					bgColor = "#FFFFFF"
				End If

				If dag > 0 AND dag < getDays(mm)+1 Then 
					borderColor = "#999999" 
				Else 
					borderColor = "#FFFFFF" 
				End If 

				Response.Write "<td width='25'>" 
				Response.Write "<table width = '100%' border='0' cellspacing='0' cellpadding='1' bgcolor='" &borderColor &"'>"_ 
						& "<tr><td>" 
				Response.Write "<table width = '100%' border='0' cellspacing='0' cellpadding='1' bgcolor='" & bgColor & "'>"_ 
						& "<tr><td>" 

				Response.Write "<div align='center'><font size='1' face='Verdana, Arial, Helvetica, sans-serif'>" 

				If dag > 0 And dag < getDays(mm)+1 Then 
					If skriv = "true" Then
						[red]Response.Write "<a href='javascript:popup(""view.asp?dd=" & dag & "&mm=" & mm & "&yy=" & yyyy & """,330,200);'>" & dag & "</a>"[/red]
						RS.MoveNext
						skriv = "false"
					Else
						Response.Write dag
					End if
				End If 

				Response.Write "</font></div></td></tr></table></td></tr></table></td>" 

				dag = dag + 1 

			Next 
			Response.Write "</tr>" 

			x = x + 1 
		Loop 

		RS.Close() 
		%>
  <tr> 
    <td width="25"> 
      <div align="center"><a href="<%=sidan%>?m=<%=getNext("-")%>">&laquo;&laquo;</a></div>
    </td>
    <td colspan="5"> 
      <div align="center"> 
        <%Response.Write "<b>" & getMonth(mm) & " " & yyyy & "</b>"%>
      </div>
    </td>
    <td width="25"> 
      <div align="center"><a href="<%=sidan%>?m=<%=getNext("+")%>">&raquo;&raquo;</a></div>
    </td>
  </tr>
</table>

MKT Tacksam för hjälp & tips!

Det löste sig såhär:

Response.Write("<a href='view.asp?dd=" & dag & "&mm=" & mm & "&yy=" & yyyy & "'>" & dag & "</a>")

Thanx

min kod fungerade om du la till två "" på slutet... innan >