15 svar · 363 visningar · startad av syrolis
Hej igen.
Min hemsida EuropéNytt har fungerat klanderfritt på vår server här hemma nu ett tag och idag skulle jag köra den skarpt...
Eftersom jag har en domänadress (https://www.europenytt.com) så pekade jag naturligtvis om den till europe.no-ip.com/dd/
där hemsidan ligger och trodde allt var frid och fröjd.
Men icke!
Jag kan inte uppdatera databaser, lägga upp bilder eller gå in i admin när jag kommer in via min riktiga domänadress. (Det senare fungerade när jag skrev in hela sökvägen med europe. no-ip i länken till admin)
Allt annat funkar när jag går in via no-ip...
Nu sliter jag mitt hår... varför blir det så här??
Vad har jag missat??
Någon som förstår vad jag menar??
*smått hysterisk*
Filsystemsrättigheter måste vara satta korrekt för mappar där databaser ligger, och mappar dit filer skall laddas upp.
Dessa inställningar måste göras av serverns administratör. Säg till vad du vill vara tvungen att göra i de olika mapparna, så borde administratören ha kompetens nog att göra korrekta inställningar.
Mvh,
Tja. Allt ligger ju kvar på vår server och ingenting har ju bytt plats.
Som sagt så fungerar ju det att nå sidan utifrån (kompisar har hjälpt till att uppdatera med bilder) med europe.no-ip.com/dd/
Det är bara nu när jag vill använda min egna domänadress och har pekat om den till ovan nämnda no-ip-adress som det inte fungerar längre.
.
Allting ligger alltså på exakt samma fysiska plats som tidigare?
Eftersom det är en no-ip.com-adress, så gissar jag på att sidan ligger lokalt hemma hos syrolis. Med andra ord måste du kolla igenom dina mappar och se till så att rättigheterna är rätt inställda.
Jo vår server är en Win2000 Server och står i ett utrymme här hemma. Vi har ju uppkoppling via ADSL och använder en no-ip adress som ändrar sig automatiskt om leverantören skulle få för sig att byta IP-adress (praktiskt)
Så jag har ju kört hela hemsidan från början "över Internet" för att vara säker på att allting fungerar som det ska.
Mina mappar har läs och skrivrättigheter där databaserna ligger.
Allt fungerar som sagt om jag använder europe.no-ip.com/dd/ adressen för att nå sidan.
Det är när jag går in via https://www.europenytt.com till samma sida (oförändrad) som det blir problem.
(Den här tråden kanske inte hör hemma här i detta forum förresten??)
Vi ska starta om servern nu och se om det hjälper...
(testar allt just nu)
Konstigt...
Vi har nu startat om servern och nu fungerar allting...
*blir så trött*
Tack för hjälpen i alla fall.
Moderatorn får gärna radera hela den här tråden eftersom problemet inte verkade existera mer än i vår egen server...
Tyvärr verkar alla script utom forumet vara löst nu med omstarten av servern.
Forumet fungerar INTE när det ligger i mappen med min hemsida. (Det har den gjort förut)
Däremot fungerar den om jag kopierar den och lägger den i roten (direkt i www)
Varför drabbar detta just mig idag när det är premiär...
Nu orkar jag inte felsöka längre... dubbelsuck
//Sylvia
Forumet fungerar INTE när det ligger i mappen med min hemsida. (Det har den gjort förut)
Är rättigheterna på den mappen korrekt satta då, för databaser och ev. uppladdning?
Felmeddelande?
Mappen med databasen har alla rättigheter (läs och skriv) till alla användare.
Inget felmeddelande.
Jag skriver i ett inlägg och trycker på skicka och allt raderas utan något skickas till databasen. Kvar står man med formuläret...
Prova gärna. https://www.europenytt.com
Forumet finns i menyn under "Kommunikation"
Ok, koden till sidan man skickar inläggen till databasen kommer nedan.
Sökvägen till databasen är 100% rätt.
<!-- #INCLUDE FILE="config.inc" -->
<HTML>
<HEAD>
<TITLE>Discussion Forum : by Manas Tungare</TITLE>
<META HTTP-EQUIV="Content-Type" CONTENT="text/html; charset=iso-8859-1">
<LINK REL="stylesheet" HREF="forum.css">
<SCRIPT LANGUAGE="JavaScript">
<!-- This script and many more are available free online at -->
<!-- The JavaScript Source!! [url]http://javascript.internet.com[/url] -->
<!-- Begin
function topWindow(){
popup = window.open("forumkodsida.asp","" ,"height=300,width=400,scrollbars=yes, left = 575, top = 210");
}
// End -->
</SCRIPT>
</HEAD>
<BODY BGCOLOR="#FFFFFF" LEFTMARGIN="0" TOPMARGIN="0" MARGINWIDTH="0" MARGINHEIGHT="0">
<%Function Smiley(text)
text = server.HTMLEncode(text)
text = Replace(text,vbCrLf,"<br>")
text = Replace(text,":)","<img src=""smileys/glad.gif"" alt=*Glad*>")
text = Replace(text,":(","<img src=""smileys/sur.gif"" alt=*Ledsen*>")
text = Replace(text,";)","<img src=""smileys/flirtar.gif"" alt=*Flirtar*>")
text = Replace(text,":?","<img src=""smileys/confused.gif"" alt=*Förvirrad*>")
text = Replace(text,":D","<img src=""smileys/skrattar2.gif"" alt=*Skrattar*>")
text = Replace(text,":r","<img src=""smileys/1.gif"" alt=*Retas*>")
text = Replace(text,":/","<img src=""smileys/sad.gif"" alt=*Sur*>")
text = Replace(text,":o","<img src=""smileys/oj.gif"" alt=*Oj*>")
text = Replace(text,":x","<img src=""smileys/arg.gif"" alt=*Arg*>")
text = Replace(text,":s","<img src=""smileys/rodnar.gif"" alt=*Rodnar*>")
text = Replace(text,":!","<img src=""smileys/idea.gif"" alt=*Idé*>")
text = Replace(text,":k","<img src=""smileys/hearts.gif"" alt=*Pussar*>")
text = Replace(text,":8","<img src=""smileys/stir.gif"" alt=*Stirrar*>")
text = Replace(text,":z","<img src=""smileys/zzz.gif"" alt=*Sover*>")
text = Replace(text,":b","<img src=""smileys/flower.gif"" alt=*Blommor*>")
text = Replace(text,":nix","<img src=""smileys/nix.gif"" alt=*Ingen aning*>")
text = Replace(text,":g","<img src=""smileys/gaspar.gif"" alt=*Gäspar - uttråkad*>")
text = Replace(text,":sj","<img src=""smileys/sick.gif"" alt=*Sjuk*>")
Smiley = text
End Function
Function FixaTecken(str)
FixaTecken = Replace(Trim(str),"'","''")
End function%>
<TABLE WIDTH="100%" BORDER="0" CELLSPACING="0" CELLPADDING="12" BGCOLOR="#F0F0F0">
<TR VALIGN="TOP">
<TD ALIGN="center"><H3>Diskussionsforum hos <%= SiteTitle %></H3></TD>
</TR>
</TABLE>
<BR>
<%
Dim DB, InReplyTo, rsInReplyTo, IsAReply
Set DB = Connect (ForumMDB)
If Request ("Action") = "Send Message" Then
' We are into the second step: We should be inserting the records now.
' Open a Recordset so that we can insert it into the "Messages" table.
Dim rsMessage
Set rsMessage = Server.CreateObject ("ADODB.Recordset")
rsMessage.Open "Messages", DB, adOpenStatic, adLockPessimistic
' Create a new, blank record.
rsMessage.AddNew
' Now set all fields to the values we got from the form.
rsMessage ("ForumID") = Request ("ForumID")
rsMessage ("PostedBy") = Request ("PostedBy")
rsMessage ("Email") = Request ("Email")
rsMessage ("Subject") = Request ("Subject")
rsMessage ("Body") = Request ("Body")
rsMessage ("InReplyTo") = Request ("InReplyTo")
rsMessage ("Date") = Now
' And save them.
rsMessage.Update
' We also need to update the "Last Post on" and "Total Posts"
' for the corresponding forum.
Dim rsForum
Set rsForum = Server.CreateObject ("ADODB.Recordset")
rsForum.Open "SELECT Posts, LastPost FROM Forums WHERE ForumID = " & Request ("ForumID"), DB, adOpenStatic, adLockPessimistic
' Update the values with the new values:
' Increment "Posts" & set the time of the last post as Now.
rsForum ("Posts") = rsForum ("Posts") + 1
rsForum ("LastPost") = Now
rsForum.Update
' Set cookies for the "From" and "Email" fields,
' so that the user need not enter them again
' if he sends another message in the same session.
' Cookies are saved only for the session, not permanently.
Response.Cookies (SiteTitle)("PostedBy") = Request("PostedBy")
Response.Cookies (SiteTitle)("Email") = Request("Email")
' Take the user to the Forum page, so he can see the
' message he just posted.
Response.Redirect "forum.asp?ForumID=" & Request ("ForumID")
Else
' Else means, we are still in Step1,
' and we should display the form.
' Is this message in reply to some other message,
' or is it an original message?
InReplyTo = Request ("InReplyTo")
' "IsAReply" is a Boolean variable that means the following:
' True : This is in reply to a message.
' False : This is an original message.
If InReplyTo <> 0 And InReplyTo <> "" Then
IsAReply = True
Set rsInReplyTo = DB.Execute ("SELECT * FROM Messages WHERE MessageID = " & InReplyTo)
End If
' If it's not a reply, and the ForumID is not supplied,
' then something is wrong. Take the user back.
' Beware, it is NOT an error if this is a reply & the ForumID.
' If we have the original message, we can determine which Forum this belongs to.
If Not IsAReply And (Request ("ForumID") = "" Or Request ("ForumID") = 0) Then
Response.Redirect "forum.asp"
End If
%>
<TABLE WIDTH="90%" BORDER="1" CELLSPACING="0" CELLPADDING="8" ALIGN="CENTER">
<TR ALIGN="LEFT" VALIGN="TOP" BGCOLOR="#FFFFFF">
<TD COLSPAN="2">Posta ett meddelande <% If IsAReply Then Response.Write " som svar till <B>" & rsInReplyTo("Subject") & "</B> av <B>" & rsInReplyTo ("PostedBy") & "</B>"%></TD>
</TR>
<TR ALIGN="LEFT" VALIGN="TOP" BGCOLOR="#FFFFFF">
<TD COLSPAN="2">
<FORM ACTION="<%= Request.ServerVariables ("PATH_INFO") %>">
<INPUT TYPE="hidden" NAME="ForumID" VALUE="<% If IsAReply Then Response.Write rsInReplyTo ("ForumID") Else Response.Write Request ("ForumID") %>">
<INPUT TYPE="hidden" NAME="InReplyTo" VALUE="<% If InReplyTo = "" Then Response.Write "0" Else Response.Write InReplyTo %>">
<TABLE WIDTH="100%" BORDER="0" CELLSPACING="0" CELLPADDING="4" ALIGN="CENTER">
<TR ALIGN="LEFT" VALIGN="TOP">
<TD WIDTH="20%" ALIGN="RIGHT">Från:</TD>
<TD WIDTH="80%">
<INPUT TYPE="text" NAME="PostedBy" SIZE="60" MAXLENGTH="50" VALUE="<%= Request.Cookies (SiteTitle)("PostedBy") %>">
</TD>
</TR>
<TR ALIGN="LEFT" VALIGN="TOP">
<TD WIDTH="20%" ALIGN="RIGHT">Email Adress:</TD>
<TD WIDTH="80%">
<INPUT TYPE="text" NAME="Email" SIZE="60" MAXLENGTH="100" VALUE="<%= Request.Cookies (SiteTitle)("Email") %>">
</TD>
</TR>
<TR ALIGN="LEFT" VALIGN="TOP">
<TD WIDTH="20%" ALIGN="RIGHT">Ämne:</TD>
<TD WIDTH="80%">
<INPUT TYPE="text" NAME="Subject" SIZE="60" MAXLENGTH="100" VALUE="<% If IsAReply Then Response.Write "Re: " & rsInReplyTo ("Subject")%>">
</TD>
</TR>
<TR ALIGN="LEFT" VALIGN="TOP">
<TD WIDTH="20%" ALIGN="RIGHT">Meddelande:</TD>
<TD WIDTH="80%">
<TEXTAREA NAME="Body" COLS="50" ROWS="12"><% If IsAReply Then Response.Write "> " & (Replace (rsInReplyTo("Body"), vbCrLf, vbCrLf + "> "))%></TEXTAREA>
</TD>
</TR>
<TR ALIGN="LEFT" VALIGN="TOP">
<TD WIDTH="20%" ALIGN="RIGHT"> </TD>
<TD WIDTH="80%">
<INPUT TYPE="submit" NAME="Action" VALUE="Skicka">
</TD>
</TR>
</TABLE>
</FORM>
</TD>
</TR>
</TABLE>
<p align="center">
<%
End If
%>
<BR>
<font face="Tahoma" size="2"><b><a href=# onClick="topWindow()">Hur
lägger jag in smileys? Eller visar foton/bilder?</a></b></font>
<TABLE WIDTH="100%" BORDER="0" CELLSPACING="0" CELLPADDING="6" ALIGN="CENTER">
<TR ALIGN="CENTER" VALIGN="TOP">
<TD COLSPAN="2" ALIGN="LEFT">
<H6>© 2000, Manas Tungare.</H6>
</TD>
<TD ALIGN="RIGHT" WIDTH="20%">
<DIV ALIGN="RIGHT"><A HREF="http://www.manastungare.com/asp/"><IMG SRC="mt45x45.gif" WIDTH="45" HEIGHT="45" BORDER="0"></A></DIV>
</TD>
</TR>
</TABLE>
</BODY>
</HTML>
Och här kommer include filen
<%
' This is the only file you will need to modify in order to
' customize the Discussion Forum Script for your own site
%>
<% Option Explicit %>
<!-- #INCLUDE FILE="adovbs.inc" -->
<%
Response.Buffer = True
Response.Expires = -1000
' ForumMDB should be the relative filename of your database.
' Since we have placed it in the same directory as all the other
' files, it is just the filename.
' If you place it one directory up, it should be "../forum.mdb"
' or if you place in a subdirectory called "database", it should be
' "database/forum.mdb"
Const ForumMDB = "forum.mdb"
' This is the title of your site. It will appear across the top of
' every page. You can remove this if you want.
Const SiteTitle = "EuropéNytt"
' Function ShowError() to display errors uniformly.
' Highlights errors in RED.
Public Sub ShowError(Err)
If CStr(Err) <> "" Then
Response.Write "<P CLASS=""Error"">" + CStr(Err) + "</P>"
End If
End Sub
' Given the path of a database, function Connect() will return a
' Connection object.
' Remember to use it as:
' Set DB = Connect (Database)
' and not as:
' DB = Connect (Database)
' The Set keyword is important since we are assigning a reference.
Function Connect (Path2DB)
Dim DB
Set DB = Server.CreateObject("ADODB.Connection")
DB.Mode = adModeReadWrite 'Since we will be adding entries.
DB.Open ("PROVIDER=Microsoft.Jet.OLEDB.4.0;DATA SOURCE=" + Server.MapPath(Path2DB))
Set Connect = DB
End Function
' Function Escape() replaces single-quotes with a pair of single-quotes.
' Otherwise we face problems inserting it into SQL statements.
Function Escape(sz)
Escape = Replace(sz, "'", "''")
End Function
' Function ShortData() formats a given Data as a nice-looking
' small string of the format:
' DD MMM, YYYY.
Public Function ShortDate(dtDate)
If Not IsNull (dtDate) Then
ShortDate = Day(dtDate) & " " & Left(MonthName (Month(dtDate)), 3) & ", " & Year(dtDate)
Else
ShortDate = dtDate
End If
End Function
%>
I ditt formulär ser det ut så här:
<INPUT TYPE="submit" NAME="Action" VALUE="Skicka">
I din asp-kod kontrollerar du värdet på denna, och utför endast insättningen i databas om värdet är Send Message. Det är det aldrig. Antingen Skicka eller inget alls. Ändra:
If Request ("Action") = "Send Message" Then
till:
If Request ("Action") = "Skicka" Then
Mvh
Jag har nu ändrat värdet ovan enligt ditt recept.
Och det fungerar igen.
Det knepiga är att scriptet är från början engelskt och har fungerat förut (under en månad) !
Jag är enbart konfunderad faktiskt. Men väldigt tacksam för att du kom på vad det var som var fel. Nu hoppas jag att det håller i sig och inte krånglar igen...
Tack!
//Sylvia