Recordset utan databas.

Sitter med Vides exempelkod på Recordset utan databas.

Hur gör jag om jag vill lista ut denna data men EJ visa de grupper som inte innehåller något? (Ej har några personer i sig)

<!--#include file="../adovbs.inc"-->
<%
Set rs = Server.CreateObject("Adodb.Recordset")
With rs
   .CursorLocation = adUseClient
   .Fields.Append "Id", adInteger
   .Fields.Append "Name", adVarChar, 50
   .Fields.Append "Group", adVarChar, 50
   .open
End With

Set rsGroup = Server.CreateObject("Adodb.Recordset")
With rsGroup
   .CursorLocation = adUseClient
   .Fields.Append "Id", adInteger
   .Fields.Append "Name", adVarChar, 50
   .open
End With

Sub addGroup( Id, Name )
   rsGroup.AddNew
      rsGroup( "Id" ) = Id
      rsGroup( "Name" ) = Name
   rsGroup.Update
End Sub

Sub addPerson( Id, Name, Group )
   rs.AddNew
      rs( "Id" ) = Id
      rs( "Name" ) = Name
      rs( "Group" ) = Group
   rs.Update
End Sub

'** Lägger till grupper:
addGroup 1, "ASP"
addGroup 2, "PHP"
addGroup 4, "HTML"
addGroup 5, "VB"

'** Lägger till personer:
addPerson 1, "Vide" , 1
addPerson 2, "@nders" , 1
addPerson 3, "jorgen" , 1
addPerson 4, "Alpha II" , 2
addPerson 5, "casca" , 2
addPerson 6, "jonne" , 2

'** Sorterar grupprecordsettet efter namn:
rsGroup.Sort = "Name Asc"

'** Loopar grupperna:

Do until rsGroup.eof
   Response.write "<b>" & rsGroup( "Name" ) & "</b><br>"

   '** Loopar personerna beroende på grupp.
   rs.Filter = "Group = " & rsGroup( "id" )
   Do until rs.eof
      Response.write rs( "Name" ) & "<br>"
      rs.MoveNext
   Loop
   rs.Filter = ""

   Response.write "<br>"
   rsGroup.MoveNext
Loop
%>

Så här blir det nu:
ASP
Vide
@nders
jorgen

HTML

PHP
Alpha II
casca
jonne

VB

Jag vill allltså inte visa HTML samt VB.

Varfor anvander man recordsets utan databaser?

För att tex. sortera arrays som jag bygger upp med FSO.

Nu är du allt skyldig mig ett svar du med. ;)

Hm, måste kolla om rs innehåller något, i så fall skriv ut rsGroup annars hoppa till nästa...
hm...

Do until rsGroup.eof
   
   '** Loopar personerna beroende på grupp.
   rs.Filter = "Group = " & rsGroup( "id" )
   if  not rs.eof then
       Response.write "<b>" & rsGroup( "Name" ) & "</b><br>"

       Do until rs.eof
            Response.write rs( "Name" ) & "<br>"
            rs.MoveNext
       Loop
   end if
   rs.Filter = ""

   Response.write "<br>"
   rsGroup.MoveNext
Loop
%>

Så jäkla bra!

Tackar tackar.

...fast borde man inte sett det där själv egentligen?