webForumDet fria alternativet
Logga in / Bli medlem

Får inte igång bineros mailforumlär.

ASP

15 svar · 4 610 visningar · startad av Akerlundh

Akerlundhs avatarAkerlundhMedlem sedan maj 20031 682 inlägg
Frågan#1

Har försökt få igång bineros mail forumlär men inte lyckats förmodligen någon miss jag gjort. får följande fel meddelande.

Persits.MailSender.4 error '800a0004'

Connection refused.

/formmail.asp, line 128

Akerlundhs avatarAkerlundhMedlem sedan maj 20031 682 inlägg
#2

Nu löste jag de felet men då kom nästa..

Persits.MailSender.4 error '800a0006'

554 5.7.1 <info@domän.....se>: Relay access denied

/formmail.asp, line 128

voigtann1s avatarvoigtann1Medlem sedan juni 20019 519 inlägg
#3

Hade nog underlättat att veta vad rad 128 är...

Akerlundhs avatarAkerlundhMedlem sedan maj 20031 682 inlägg
#4

Set mySmartMail = Server.CreateObject("Persits.MailSender")
mySmartMail.Host = strMailserver
mySmartMail.FromName = strSenderName
mySmartMail.From = strSender
mySmartMail.AddAddress strRecipient, strRecipientName
mySmartMail.Subject = strSubject
mySmartMail.Body = strExtra & strMessage
mySmartMail.Send <----- 128

voigtann1s avatarvoigtann1Medlem sedan juni 20019 519 inlägg
#5

Och stämmer strMailserver med det du har hos Binero för att skicka mail?

testade med: http://www.aspemail.com/manual_02.html och ändrade koden till min smtp på binero, inga problem att skicka mail.

Akerlundhs avatarAkerlundhMedlem sedan maj 20031 682 inlägg
#6

här är hela koden känns inte som något är fel.


<%@LANGUAGE="VBSCRIPT" CODEPAGE="1252"%>
<%
Option Explicit
Response.Buffer = true			'Just internal tcp buffers
Response.Expires=0			'Must not be less-zero by
Response.ExpiresAbsolute = Now() -2	'To compensate different timezones
Response.AddHeader "pragma", "no-cache"
Response.AddHeader "cache-control", "private"
Response.CacheControl = "no-cache"	'IIS Internal disabled
%>
<!DOCTYPE HTML PUBLIC "-//W3C//DTD HTML 4.01 Transitional//EN" "http://www.w3.org/TR/html4/loose.dtd">
<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=iso-8859-1">
<title></title>
<style type="text/css">
<!--
body {
	font-family: Verdana, Arial, Helvetica, sans-serif;
	font-size: 10px;
	color: #000000;
	text-decoration: none;
}
-->
</style>
</head>

<body>
<%
Dim strSender, strRecipient, strSubject, strMessage, strSenderName, strReturnAddress, strUseExtraText
Dim strCity, strPhone, strZip, strAddress, strExtra,strFax,strMobile, mySmartMail, strCompany, strRecipientName
Dim strReply, strReplySubject, strReplyMessage, SmartMail, strWebsite, strAuth, strMailserver 

'För att förhindra att mailformuläret används för att skicka sam så hårdkodar mottagaren.
'ange nedan mottagarens adress samt namn
'********************************************************************************************
strRecipient	= "info@xxxx.se"
strRecipientName= "Info"
'********************************************************************************************
'********************************************************************************************

'Ange utgående mailserver nedan
'********************************************************************************************
strMailserver = "smtp.xxxx.se"
'********************************************************************************************
'********************************************************************************************

strSender 		= Request("Email")
strSubject		= Request("Subject")
strMessage		= Request("Message")
strSenderName		= Request("Name")
strCompany		= Request("Company")
strCity			= Request("City")
strPhone		= Request("Phone")
strFax			= Request("Fax")
strMobile		= Request("Mobile")
strZip			= Request("Zip")
strAddress		= Request("Address")
strUseExtraText		= Request("Extra")
strReturnAddress	= Request("ReturnAddress")
strReply		= Request("Reply")
strReplySubject 	= Request("ReplySubject")
strReplyMessage		= Request("ReplyMessage")
strWebsite		= Request("Website")
strAuth			= Request("Auth")
strExtra 		= ""

IF strUseExtraText = "yes" or strUseExtraText = "1" THEN
	
	IF strCompany <> "" THEN
		strExtra = strExtra & "Företag: " & strCompany & vbcrlf
	END IF
	IF strSenderName <> "" THEN
		strExtra = strExtra & "Namn: " & strSenderName & vbcrlf
	END IF
	IF strAddress <> "" THEN
		strExtra = strExtra & "Adress: " & strAddress & vbcrlf
	END IF
	IF strZip <> "" THEN
		strExtra = strExtra & "Postnummer: " & strZip & vbcrlf
	END IF
	IF strCity <> "" THEN
		strExtra = strExtra & "Stad: " & strCity & vbcrlf
	END IF
	IF strPhone <> "" THEN
		strExtra = strExtra & "Telefon: " & strPhone & vbcrlf
	END IF
	IF strFax <> "" THEN
		strExtra = strExtra & "Fax: " & strFax & vbcrlf
	END IF
	IF strMobile <> "" THEN
		strExtra = strExtra & "Mobil: " & strMobile & vbcrlf
	END IF
	IF strSender <> "" THEN
		strExtra = strExtra & "E-post: " & strSender & vbcrlf
	END IF
	IF strWebsite <> "" THEN
		strExtra = strExtra & "Hemsida: " & strWebsite & vbcrlf
	END IF
	IF strSubject <> "" THEN
		strExtra = strExtra & "Ärende: " & strSubject & vbcrlf
	END IF
	IF strMessage <> "" THEN
		strExtra = strExtra & "Meddelande: " & vbcrlf & vbcrlf
	END IF
End If

IF 	strSender = "" OR strRecipient = "" OR Session("AUTH") <> strAuth THEN
	
	IF 	strSender = "" THEN
		Response.Write("&#8226; Avsändaradress saknas.")
	END IF
	IF 	strRecipient = "" THEN
		Response.Write("&#8226; Mottagaradress saknas.")
	END IF
	IF Session("AUTH") <> strAuth THEN
		Response.Write("&#8226; Felaktig kod.")
	END IF
ELSE
	Set mySmartMail = Server.CreateObject("Persits.MailSender")
	mySmartMail.Host = strMailserver
	mySmartMail.FromName = strSenderName
	mySmartMail.From = strSender
	mySmartMail.AddAddress strRecipient, strRecipientName
	mySmartMail.Subject = strSubject
	mySmartMail.Body = strExtra & strMessage
	mySmartMail.Send

	if Err<>0 then
		Response.Write("<b>FEL:</b> " & Err.description)
	else
		IF strReply = "yes" or strReply = "1" THEN
			Set SmartMail = Server.CreateObject("Persits.MailSender")
			SmartMail.Host = strMailserver
			SmartMail.FromName = strRecipientName
			SmartMail.From = strRecipient
			SmartMail.AddAddress strSender, strSenderName
			SmartMail.Subject = strReplySubject
			SmartMail.Body = strReplyMessage
			SmartMail.Send
			if Err<>0 then
				Response.Write("<b>FEL:</b> " & Err.description)
			END IF
		END IF
		
		IF strReturnAddress = "" THEN
			Response.Write("&#8226; Tack, e-post har skickats till "& strRecipient & ".")
		ELSE
			Response.Redirect(strReturnAddress)
		END IF
	end if
END IF
%> 
</body>
</html>
Quids avatarQuidMedlem sedan juni 20006 022 inlägg
#7

Är det samma domän på e-postadressen du skickar från och smtp-servern? Annars blir det sk. relaying och det är ofta blockerat för att förhindra spam.

Akerlundhs avatarAkerlundhMedlem sedan maj 20031 682 inlägg
#8

Quid skrev:

Är det samma domän på e-postadressen du skickar från och smtp-servern? Annars blir det sk. relaying och det är ofta blockerat för att förhindra spam.

Ja det är det.

fakenick!Medlem sedan juli 2002202 inlägg
#9

Hej!

Hade samma problem häromdagen. Vad som krävs är:

MySmartMail.Host = "smtp.dindomän.se"
MySmartMail.Username = "info@dindomän.se"
MySmartMail.Password = "lösen_till_epostkontot"

Man måste alltså sätta upp ett epostkonto på binero som man sedan i scriptet loggar in med för att skicka email!

Hoppas det löser ditt problem!

Akerlundhs avatarAkerlundhMedlem sedan maj 20031 682 inlägg
#10

fakenick! skrev:

Hej!

Hade samma problem häromdagen. Vad som krävs är:

MySmartMail.Host = "smtp.dindomän.se"
MySmartMail.Username = "info@dindomän.se"
MySmartMail.Password = "lösen_till_epostkontot"

Man måste alltså sätta upp ett epostkonto på binero som man sedan i scriptet loggar in med för att skicka email!

Hoppas det löser ditt problem!

Det löste nog problemet en bit nu kommer nästa felmeddelande

Persits.MailSender.4 error '800a0006'

535 5.7.8 Error: authentication failed: UGFzc3dvcmQ6

/formmail.asp, line 129

Set mySmartMail = Server.CreateObject("Persits.MailSender")
MySmartMail.Host = "smtp.domän.se"
MySmartMail.Username = "info@domän.se"
MySmartMail.Password = "pass"
mySmartMail.FromName = strSenderName
mySmartMail.From = strSender
mySmartMail.AddAddress strRecipient, strRecipientName
mySmartMail.Subject = strSubject
mySmartMail.Body = strExtra & strMessage
mySmartMail.Send \<---- 129
Akerlundhs avatarAkerlundhMedlem sedan maj 20031 682 inlägg
#11

ingen?

voigtann1s avatarvoigtann1Medlem sedan juni 20019 519 inlägg
#12

Om dina uppgifter stämmer och du får felmeddelande så är mitt tips är att kontakta binero, jag har inga problem att använda koden med mina uppgifter på mitt konto hos binero 2.0

Akerlundhs avatarAkerlundhMedlem sedan maj 20031 682 inlägg
#13

voigtann1 skrev:

Om dina uppgifter stämmer och du får felmeddelande så är mitt tips är att kontakta binero, jag har inga problem att använda koden med mina uppgifter på mitt konto hos binero 2.0

Ja de få nog bli så. Tack alla för hjälpen.

civilpolisens avatarcivilpolisenMedlem sedan dec. 2009872 inlägg
#14

Jag har skickat mail i 10 år hos Binero med denna koden:
Behövs inget konto eller lösenord och fungerar på olika sajter.

' ## M A I L
FUNCTION funcSendEmail(strSubject, strText, strSender, strReciver)
	IF strSender  = "default" THEN strSender = "info@domän.se"
	IF strReciver = "default" THEN strReciver = "jag@domän.se"
	IF strText <> "" THEN
		' ## SEND MAIL TO HOST
		Set CDOMail = Server.CreateObject("CDONTS.NewMail")
		CDOMail.From = strSender
		CDOMail.To = strReciver
'		CDOMail.BCc = "jag@domän.se" 
		CDOMail.Subject = strSubject & " - " & Request.ServerVariables("SERVER_NAME")
		CDOMail.Body = strText & vbCRLF & vbCRLF _
		& "* * * * * * * * * * * * * * * * * * * * * * * * *" & vbCRLF _
		& "Code found in file:" & vbCRLF _
		& Request.ServerVariables("SERVER_NAME") & " " & Request.ServerVariables("PATH_INFO") _
		& vbCRLF & "See form at:" & vbCRLF & Request.ServerVariables("HTTP_REFERER")
		CDOMail.Send
		Set CDOMail = Nothing
	END IF
END FUNCTION
aleborgMedlem sedan jan. 20013 341 inlägg
#15

civilpolisen skrev:

Jag har skickat mail i 10 år hos Binero med denna koden:
Behövs inget konto eller lösenord och fungerar på olika sajter.

I Binero 2.0 krävs det tyvärr att du skickar med autentiseringsuppgifter.

civilpolisens avatarcivilpolisenMedlem sedan dec. 2009872 inlägg
#16

OK....
Öken!!
Kommer att medföra MYCKET extra arbete.
Kan man ha nåt universalkonto som man kan använda eller är det knutet till respektive domän?

Måste förbereda mig och mina kunder på detta scenario.
Lustigt att allt fortfarande fungerar för mig och alla andra... men det är väl bara en tidsfråga, antar jag då i så fall...!!

****
Kan "någon vänlig själ" (typ Mr Aleborg??) vara vänlig att länka till kod som man ska byta till?
Detta gäller ju även på webbplatser där man har en sån "skicka lösenordet till mig" -funktion.

284 ms totalt · 4 externa anrop · v20260731065814-full.a51de22e
124 ms — deklarationer (db)
0 ms — hämta statistik (cache)
151 ms — hämta tråd, inlägg och bilagor (db)
129 ms — ändringar (db)