Aspjpeg problem (loopia)

Denna aspjpeg kör jag på Nyttodata och den fungerar helt klockrent...men nu skall jag även lägga denna på en hemsida hos loopia. Allt rullar igenom, inga felkoder, men bilden finns inte i mappen! Har provat en massa och läst på deras hemsida men de står inget vettigt om detta! Är det ngn annan som haft problem med loopia och hur löste ni de i så fall?

<!-- spara bild -->
<% If Request.Querystring("spara") = "foto" Then

If session("trecup") = "ja" THEN
mappid = Request.Querystring("mappid")
Set Upload = Server.CreateObject("Persits.Upload")

Upload.OverwriteFiles = False

Upload.Save(Server.MapPath("../../uploadbilder/"))
Set File = Upload.Files("file")
	
If Not File Is Nothing Then
        ' Är det en bild?
	If File.ImageType = "UNKNOWN" Then
		File.Delete
		Response.Write("Filen du försöker ladda upp är ingen bild...")
		Response.End
End If

' Skapa AspJpeg Objekten
	Set JpegPic	= Server.CreateObject("Persits.Jpeg")
	Set JpegTmb	= Server.CreateObject("Persits.Jpeg")
	
' Välj ett filnamn (File.Name är 'originalnamnet') och spara filen
	FilNamn = Upload.Files("file").ExtractFileName
	
' Öppna den uppladdade bilden för att skala om den:
    JpegPic.Open Server.MapPath("../../uploadbilder") & "/" & FilNamn

' Om storleken ä'r större än xxx, skala ner den till xxx, behåll proportionerna.
If JpegPic.OriginalWidth > JpegPic.OriginalHeight Then
   'Liggande bild.
	JpegPic.PreserveAspectRatio = True
	JpegPic.Width = 800
Else
   'Stående bild
	JpegPic.PreserveAspectRatio = True
	JpegPic.Height = 600
End If

JpegPic.Canvas.Font.Color = &HFFFFFF
JpegPic.Canvas.Font.Family = "Tahoma"
JpegPic.Canvas.Font.Bold = true
JpegPic.Canvas.Font.Size = 13
JpegPic.Canvas.Font.Quality = 10
JpegPic.Canvas.Font.BkMode = "Transparent"
JpegPic.Canvas.Print 5, 2, "Copyright © 2007 minsida.se"

' Spara bilden
	JpegPic.Save Server.MapPath("../../uploadbilder") & "/" & FilNamn

' Öppna bilden en gång till för att skapa miniatyr:			
	JpegTmb.Open Server.MapPath("../../uploadbilder/") & "/" & FilNamn
	mHeightt = 70
	JpegTmb.PreserveAspectRatio = True
	JpegTmb.Height = mHeightt

' Spara miniatyr
	JpegTmb.Save Server.MapPath("../../uploadbilder/pics") & "/" & FilNamn

'Spara in till databas

	Set Connect = Server.CreateObject("ADODB.Connection")
	Connect.Open "driver={Microsoft Access Driver (*.mdb)};dbq=" & Server.MapPath("../../../db/asskickers.mdb") & ";pwd=hehe;"
	Set RecSet = Server.CreateObject("ADODB.Recordset")

	Adbild = "SELECT * FROM bild"
	RecSet.Open Adbild, Connect, adOpenDynamic, adLockOptimistic

RecSet.AddNew

	If FilNamn <> "" Then
	RecSet("filnamn") = FilNamn
	end if
	
	If Upload.Form("kommentar") <> "" Then
	RecSet("kommentar") = Upload.Form("kommentar")
	End If
	
	If Upload.Form("skapad") <> "" Then
	RecSet("skapad") = Upload.Form("skapad")
	End If
	
	If Upload.Form("mappid") <> "" Then
	RecSet("mappid") = Upload.Form("mappid")
	End If
		
	RecSet.Update

	RecSet.Close
	Set RecSet = Nothing

	Connect.Close
	Set Connect = Nothing
	
' Stäng objekten
	Set JpegPic		= Nothing
	Set JpegTmb		= Nothing
	
	End If
	Set Upload		= Nothing

	end if
	
	Response.Redirect("default.asp?meny=bildbank&skapa=bild&mappid="&mappid&"&status=Bilden är sparad")
%>

<% end if %>

Skulle tippa på att loopia har parent paths satt till disabled. Då får du koda om så att du utgår från root katalogen och bläddra dig ned i strukturen.

Server.MapPath("/")

Konkatinera sedan ihop sökvägen till dit du ska spara och arbeta med filerna.
Eller var det "\" .. Har det inte riktigt kvar i knoppen. Det var ett tag sedan jag gjorde det.

Lycka till

Zaiman skrev:

Skulle tippa på att loopia har parent paths satt till disabled. Då får du koda om så att du utgår från root katalogen och bläddra dig ned i strukturen.

Server.MapPath("/")

Konkatinera sedan ihop sökvägen till dit du ska spara och arbeta med filerna.
Eller var det "\" .. Har det inte riktigt kvar i knoppen. Det var ett tag sedan jag gjorde det.

Lycka till

Hänger inte riktigt med på vad du menar...skall jag använda domän sökvägen då eller?

Jo såhär..
Server.MapPath("/") ger dig rootkatalogen till din webplats ex "c:\websiter\siten"
Sedan konkatinerar du ihop det du behöver för att nå dina bilder
ex: myPath = Server.MapPath("/") & "\bilder\nyarkivet\"
Då får du en annan sökväg.. "c:\websiter\siten\bilder\nyarkivet\

Lycka till

Jag har också varit med om att serverMapPath inte fungerar, men jag minns inte i vilket sammanhang. Men om du, i global.asa, skapar en variabel och sen använder den variabeln i all kod så är det typ inte jobbigt alls.

Kolla vilken sökväg du har till dina mappar och sen sätter du:
session("myPath") = "e:\rätt sökväg"

***
Hmm... jag ser nu att det inte var i riktigt detta sammanhanget som jag använder detta... men kanske du ändå blir inspirerad!?

Testa att skriva ut Server.MapPath("../../uploadbilder/") och kolla vart den hamnar...

Du kanske letar efter bilderna i fel mapp. För om det skulle vara nåt fel med mappen bilderna läggs in i så tror jag den skulle visa nåt slags felmeddelande. (ej säker dock)

Men om Server.MapPath("../../uploadbilder/") visar sig att vara en helt annorlunda mapp då vet du iaf vad du ska ändra ;)

Men prova först att göra som jag skrev med konkatineringen av rootkatalog och stega dig nedåt. Om ParentPaths är avstängd kommer det inte att fungera med Server.MapPath("../../uploadbilder/"). Bättre att utgå från rootkatalogen.