Har veckonummer och dag i form av måndag kan jag få ut datum?

Jag hittade en funktion i mitt funktionsarkiv som skulle kunna passa! :)

<%
	Dim myYear, myWeek, myDay
	
	myYear = year(Date())
	myWeek = 48
	myDay = getDayByName("Torsdag")
	
	Response.Write(getWeekDay(myYear, myWeek, myDay))
	
	
	'Hämtar vald dag i vald vecka ==============================================
	Public Function getWeekday(Byval Current_year, Byval Current_week, Byval Current_weekday)
		Dim Current_date
		Current_weekday = Current_weekday-1
		Current_date = Current_year & "-01-01"
		Do Until DatePart("WW", Current_date, 2, 2) = Current_week
			Current_date = DateAdd("D", 1, Current_date)
		Loop
		getWeekday = DateAdd("D", Current_weekday, Current_date)
	End Function
	
	
	'Gör om dag i text till nummer ============================================
	Public Function getDayByName(strName)
		Dim RetVal
		Select Case lcase(strName)
			Case "måndag" : RetVal = 1
			Case "tisdag" : RetVal = 2
			Case "onsdag" : RetVal = 3
			Case "torsdag" : RetVal = 4
			Case "fredag" : RetVal = 5
			Case "lördag" : RetVal = 6
			Case "söndag" : RetVal = 7
		End Select
		
		getDayByName = RetVal
	End Function
%>

Tack