Skriver till databasen långsamt...

Om det inte hade varit för id-numret som du hämtar från tblNextId så hade du kunnat göra hela importen med en enda SQL-sats (INSERT INTO .... SELECT ...), men som det är nu är det i princip rätt.

Det verkar vara en rutin som körs under kontrollerade former, så du skulle kunna nöja dig med att hämta ut värdet från tblNextId en enda gång, och uppdatera tblNextId en enda gång. Du vet ju att räknaren ökar med 1 för varje varv.

Kategorinamnet går att hämta ut i första frågan.

SELECT a.articlenumber, a.articleName, a.articleUnit, l.listName 
FROM tblArticle a
LEFT JOIN tblList l ON LEFT(a.articleNumber,2)=l.listNr 
ORDER BY a.articlenumber

Och ja, man förlorar en del prestanda på att jobba över databasgränsen. Hur mycket är svårt att sia om.

Tack för det emission....

Kankse något sådant här:

<%
Dim sSQL, objConn, objRS1, objRS2,  iStatus, sNote, sCategory, sName, sArtNr, sUnit, iPrice, iNextId, sArticleNumber, sArticleName, sList, iSupplierId, dStartTimer, totalTime, iCounter

'Starta timern
dStartTimer = timer()

'Nollställa räknare
iCounter = 0

'Ange status; 0 = "synkroniserad med SPCS", 1 = "Inte synkroniserad mot SPCS"
iStatus = 0

'Notering
sNote = ""
'Pris
iPrice = 0

' Öppna databasen
' ***************
Set objConn = Server.CreateObject("ADODB.Connection")
objConn.ConnectionString = Application("sConn")
objConn.Open

'Hämta nästa Id
Set objRS = objConn.Execute ("SELECT nextId FROM UppdragNu.dbo.tblNextId WHERE [table] = 'tblArticle'")
		
If not objRS.EOF then	
	iNextId = cLng(objRS("NextId")) 	
End If
		
objRS.Close
Set objRS = Nothing

sSQL = 		"SELECT a.articlenumber, a.articleName, a.articleUnit, l.listName " &_
			"FROM tblArticle a " &_
			"LEFT JOIN tblList l ON LEFT(a.articleNumber,2)=l.listNr " &_
			"ORDER BY a.articlenumber"
			
Set objRS = Server.CreateObject("ADODB.Recordset")
objRS.Open sSQL, objConn, 3, 1

If not objRS.EOF then

' Räkneverk
' *********
Response.write("<div id=""message"">Vänta, skriver till databasen...</div>")
Response.write("<div id=""progress""></div>")
Response.Flush()
	
	do while not objRS.EOF
	
		' Villkor för att flusha
		' **********************
		iCounter = iCounter +1
		if iCounter mod 10 = 0 then
			Response.write ("<script>document.getElementById(""progress"").innerHTML=""" & iCounter & """;</script>")
			Response.flush
		end if
	
		sArticleNumber = objRS("articleNumber")
		sArticleName = objRS("articleName")
		sUnit = lCase(objRS("articleUnit"))
		sCategory = objRS("listName")	
	
		sSQL = 	"INSERT INTO UppdragNu.dbo.tblArticle ([Id], [Status], [Modified], [Nr], [Name], [Category], [Unit], [Price], [Note]) " &_
				"VALUES(" & iNextId & ", " & iStatus & ", getdate(), '" & sArticleNumber & "', '" & sArticleName & "', " &_
				"'" & sCategory & "', '" & sUnit & "', " & iPrice & ", '" & sNote & "')"
	
		objConn.execute sSQL,,128
		
		iNextId = iNextId + 1
			
		objRS.Movenext
	
	Loop

'Uppdatera tblNextId
sSQL = "UPDATE UppdragNu.dbo.tblNextId SET nextId = " & iNextId & " WHERE [Table] = 'tblArticle'"
		objConn.Execute sSQL,, 128

'Skriv ut att artiklarna lagrats
Response.write("<script>document.getElementById(""message"").innerHTML=""Datat har lagrats i databasen! "";</script><br><br>")

'Skriv ut timern
totalTime = timer() - dStartTimer
Response.Write FormatMinSec(totalTime) & "<br><br>"

'Stänga objRS
objRS.Close
Set objRS = Nothing

Else
	Response.write "Fel!"	
End if

%>

Har dock inte hunnit provköra än... Men det ser ju lite smidigare ut, och borde gå lite fortare...

Mvh
Henrik

Det verkar gå fortare.... Nu är det ju 200 000 artiklar som skall loopas ut, så visst tar det lite tid. Men detta är en operation som görs 3 gånger per år.

Inget annat som går att optimera i koden?

Mvh
Henrik