Dynamiskt antal år

<select name="selectYear" class="listmeny" onChange="this.form.submit();">
<%
For i = Year(Now) - 2 To Year(Now)
	%>
	<option value="<%=i%>"<%If i = Year(Now) Then Response.Write " selected"%>><%=i%></option><%
Next 'i
%>
</select>

Weeee!

Tackar! ;)

//Henrik

Det fungerar ju...

Men jag skulle vilja få till det att när man ändrar i listmenyn, och därmed submittar, så vill jag att det årtal man valt stannar kvar.

Testade med:

<option value="<%=i%>"<%If i = Year(Now) or i = request("selectYear") Then Response.Write "selected"%>><%=i%></option>

Men det fungerade inte. Det hoppade tillbaka till 2006... :(

//Henrik

Lagra målvärdet innan, och jämför med det

theYear=request("selectYear") 
if theYear="" then theYear=Year(Now)

Okej!

Hmmm..
Testade med:

theYear = request("selectYear")

if theYear= "" then theYear = Year(Now)

...

<select name="selectYear" class="listmeny" onChange="this.form.submit();">
				<%
				For i = Year(Now) - 2 To Year(Now)
					%>
					<option value="<%=i%>"<%If i = theYear Then Response.Write "selected"%>><%=i%></option><%
				Next
				%>
			</select>

Men det vill sig inte... Om jag bytter år, dvs submittar så stannar året inte kvar...

Vad har jag gjort för fel?

//Henrik

Hej!
Efter lite pillande så fick jag det att fungera typkonverterade det jag jämförde till en sträng:

<option value="<% =i %>"<% If cstr(i) = cstr(theYear) Then Response.Write "selected" %>><% =i %></option>

Jag har därför förstått att jag jämförde päron med äpplen.... Men är detta rätt sätt att gå, eller ska jag göra på något annat, bättre sätt? Det fungerar ju nu visserligen...

//Henrik

Rätt

Okidoki :D

Då kör jag på det!

//Henrik

Följande kod blev det till slut:

theYear = request("selectYear")

if theYear= "" then theYear = Year(Now)

...

		  	<select name="selectYear" class="listmeny" onChange="this.form.submit();">
				<%
				For i = Year(Now) - 2 To Year(Now)
					%>
					<option value="<% =i %>"<% If cstr(i) = cstr(theYear) Then Response.Write "selected" %>><% =i %></option><%
				Next
				%>
			</select>

Henrik

När det faktiskt är siffror så är det bara onödigt och fult att göra strängjämförelser.

theYear = request("selectYear")
if theYear = "" then theYear = Year(Now)
theYear = CLng(theYear)
...
<select name="selectYear" class="listmeny" onChange="this.form.submit();">
<%
For i = Year(Now) - 2 To Year(Now)
	%>
	<option value="<% =i %>"<% If i = theYear Then Response.Write " selected" %>><% =i %></option><%
Next
%>
</select>

Eller ännu hellre:

'i din util fil
Function Coalesce(Value1, Value2)
	If Trim(Value1 & "") <> "" Then
		Coalesce = Value1
	ElseIf Trim(Value2 & "") <> "" Then
		Coalesce = Value2
	End If
End Function

'sidan där util filen är inkluderad
theYear = CLng( Coalesce(request("selectYear"), Year(Now)) )
...
<select name="selectYear" class="listmeny" onChange="this.form.submit();">
<%
For i = Year(Now) - 2 To Year(Now)
	%>
	<option value="<% =i %>"<% If i = theYear Then Response.Write " selected" %>><% =i %></option><%
Next
%>
</select>

Aha!

Okej!

Jag ska testa det också!

//Henrik