ADODB Upload

Sitter här och försöker uploada till min MySQL 4.1 med drivaren MySQL ODBC 3.51.
Får detta felmeddelande när jag försöker uploada:

Microsoft Cursor Engine fel '80040e21'

En flerstegsåtgärd skapade fel. Kontrollera alla statusvärden.

/process_upload.asp, rad 38

Använder för tillfället denna kod:

<%

Set Upload = Server.CreateObject("Persits.Upload")

' we use memory uploads, so we must limit file size
Upload.SetMaxSize 1048576, True

' Save to memory. Path parameter is omitted
Count = Upload.Save

' Obtain file object
Set File = Upload.Files("file")

If Not File Is Nothing Then
   ' Build ADO connection string
   Connect = "Driver={MySQL ODBC 3.51 Driver};Server=localhost;Uid=****;Pwd=****;Database=upl"
   
   ' Use ADO Recordset object
   Set rs = Server.CreateObject("adodb.recordset")

   ' Optional: check whether this file already exists using MD5 hash
   Hash = File.MD5Hash
   rs.Open "SELECT * from files WHERE hash='" & Hash & "'", Connect, 2, 3
   If Not rs.EOF Then
   h = rs("hash")
   	rs.Close
      Response.Redirect("upload_error.asp?e=1&h=" & h)
   End If
   rs.Close

   rs.CursorLocation = 3

   ' Reopen recordset to insert file
   rs.Open "files", Connect, 2, 3
   
   rs.AddNew
   rs("file_blob") = File.Binary
   rs("file_name") = File.FileName ' ---------- Rad 38
   rs("file_size") = File.Size
   rs("hash") = Hash
   rs("description") = Upload.Form("description")
   rs("uploader") = Upload.Form("who")
   rs.Update

   Response.Redirect("upload_complete.asp?h=" & Hash)
Else
   Response.Redirect("upload_error.asp?e=2")
End If

%>

Jag använder mig av AspUpload. Någon som har någon idé på hur man kan lösa detta?

Testa detta:

Connect.CursorLocation = 3
rs.Open "files", Connect, 3, 3

Fungerade tyvärr inte.

Ingen skillnad med OLE DB?

Provider=MySQLProv;Data Source=mydb;User Id=UserName;Password=asdasd;

Hmm, jag lade till Option=3 bakom min ODBC-connection så fungerade det finfint. Tack för hjälpen ändå. :)