paging

Jag använder

<%
Set objRs = Server.Createobject("Adodb.Recordset")
strSQL = "Select * from anvandare Order by id asc"

strConString = "Provider=Microsoft.Jet.OLEDB.4.0;Data source=" &_
  Server.MapPath("/") & "/db/users.mdb"

intPageId = request.querystring( "pageid" )
if intPageId = "" then intPageId = 1

with objRs
  .cursorlocation = 3 'adUseClient
  .open strSQL, strConString 'öppnar databasen och hämtar info.
  .pagesize = 10 'bestämmer hur många poster per sida.
  .absolutepage = intPageId 'bestämmer vilken sida som skall visas.
end with

intPages = cint( objRs.pagecount ) 'Kollar hur många sidor som finns i recordsettet.
intCurrentPost = 0 'Nollställer räknaren som skall hålla kolla på vilken post vi är på.

do while not objRs.eof and intCurrentPost < objRs.pagesize
  strContents = strContents &_
    "<tr><td>" & objRs( "Namn" ) & "</td>" &_
    "<td>" & objRs( "Alder" ) & "</td></tr>"
  intCurrentPost = intCurrentPost + 1
  objRs.MoveNext
loop

function getFirstLink()
  getFirstLink = " <a href='?pageid=1'>Första sidan</a> "
end function

function getPreviousLink( intPageId )
  if intPageId > 1 then
    getPreviousLink = " <a href='?pageid=" & intPageId - 1 & "'><< Föregående</a> "
  end if
end function

for i = 1 to objRs.pagecount
  strNavigation = strNavigation & " <a href='?pageid=" & i & "'>" & i & "</a>"
next

function getNextLink( intPageId, intPageCount )
  if cint( intPageId ) < cint( intPageCount ) then
    getNextLink = " <a href='?pageid=" & intPageId + 1 & "'>Nästa >></a> "
  end if
end function

function getLastLink( intPageCount )
  getLastLink = " <a href='?pageid=" & intPageCount & "'>Sista sidan</a> "
end function

function getPageInfo( intPageId, intPageCount )
  getPageInfo = " Antal sidor: " & intPageCount & ", nuvarande sida: " & intPageId & " "
end function

response.write "<table>" & strContents & "</table>"
response.write "<table><tr><td>" & getFirstLink & " " & getPreviousLink & " " & strNavigation & " " & getNextLink & " " & getLastLink & " " & getPageInfo & "</td></tr></table>" 

%>

o får felmeddelandet

Körningsfel i Microsoft VBScript (0x800A01C2)
Fel antal argument eller felaktig egenskapstilldelning.: 'getPreviousLink'

[Redigerat av Cactuz den 30 jan 2002]

Du "passar" inte med några argument till dina funktioner:

response.write "<table><tr><td>" & getFirstLink & " " & getPreviousLink & " " & strNavigation & " " & getNextLink & " " & getLastLink & " " & getPageInfo & "</td></tr></table>"

"Passa" in de variabler som varje funktion behöver.

cya,
PatrikB

------------------
-=* IF there is a wrong way to do something, then someone will do it *=-

Du har inga parametrar med i funktionsanropen

response.write "<table><tr><td>" & getFirstLink() & " " & getPreviousLink(intPageId) & " " & strNavigation & " " & getNextLink(intPageId, intPages) & " " & getLastLink(intPages) & " " & getPageInfo(intPageId, intPages) & "</td></tr></table>"

------------------
essentitia preter non sans multiplicandum

najs lars.. nu funkar det fint :)