If sats - Syntaxfel

Varför går inte detta?

<%
'***** Skapar Connection-objektet *****'
Set Connect = Server.CreateObject("ADODB.Connection")
'***** Specifierar sökvägen *****'
MdbFilePath = Server.MapPath("../../../db/test.mdb")
'***** öppnar databasen *****'
Connect.Open "Driver={Microsoft Access Driver (*.mdb)}; DBQ=" & MdbFilePath & ";"

Set RStemp = Connect.Execute("Select \* From BOK where DATUM\>=#" & dateadd("d",-30,now) & "# order by DATUM desc, TITEL")

%>

<table width="100%" border="0" cellspacing="1" cellpadding="2">
<%
Do Until RStemp.EOF
cnt = cnt + 1
strColor = "#EEEEEE"
If cnt Mod 2 = 0 then strColor = "#E5E5E5"
Response.Write "<tr bgcolor='" & strColor & "' onMouseOver=this.style.backgroundColor='#CDCDCD'; onMouseOut=this.style.backgroundColor='';>" &_
"<td width=12><IMG src=../bilder/windows.gif></td>" &_
"<td> " & RStemp("FNAMN") & "</td>" &_
"<td width=10> " & RStemp("ENAMN") & "</td>" &_
"<td width=10> " & RStemp("ADRESS") & "</td>" &_
"<td width=10> " & RStemp("PNR") & "</td>" &_
"<td width=75 align=center> " & RStemp("STAD") & "</td>" &_
%>
<%
If RStemp("LINK") = "" then
"<td width=75 align=center> </td>" &_
Else
"<td width=75 align=center> " & RStemp("TELE") & " </td>" &_
%>
<%
"</tr>"
RStemp.MoveNext
Loop
%>
</table>

Det är alltså på raden där If börjar som felet uppstår? Får ett syntaxfel?
Varför?

------------------
/Sammy Swärd

Jo, därför att

Response.Write "<tr bgcolor='" & strColor & "' onMouseOver=this.style.backgroundColor='#CDCDCD'; onMouseOut=this.style.backgroundColor='';>" &_
"<td width=12><IMG src=../bilder/windows.gif></td>" &_
"<td> " & RStemp("FNAMN") & "</td>" &_
"<td width=10> " & RStemp("ENAMN") & "</td>" &_
"<td width=10> " & RStemp("ADRESS") & "</td>" &_
"<td width=10> " & RStemp("PNR") & "</td>" &_
"<td width=75 align=center> " & RStemp("STAD") & "</td>" [b]&_[/b]
%>
<%
If RStemp("LINK") = "" then

Om du tar bort &_ precis innan %> så borde det gå bättre.

------------------
essentitia preter non sans multiplicandum

[Redigerat av LarsG den 24 aug 2001]

Då blev det fel på nästa rad? Testade att ta bort "-teckena men det fungerade inte heller?

Hur göra?

PS. - Tack för ditt snabba svar...

------------------
/Sammy Swärd

Det går inte att skriva på det viset.

Du får lägga till nya response.write

Response.Write "<tr bgcolor='" & strColor & "' onMouseOver=this.style.backgroundColor='#CDCDCD'; onMouseOut=this.style.backgroundColor='';>" &_
"<td width=12><IMG src=../bilder/windows.gif></td>" &_
"<td> " & RStemp("FNAMN") & "</td>" &_
"<td width=10> " & RStemp("ENAMN") & "</td>" &_
"<td width=10> " & RStemp("ADRESS") & "</td>" &_
"<td width=10> " & RStemp("PNR") & "</td>" &_
"<td width=75 align=center> " & RStemp("STAD") & "</td>" 
%>
<%
If RStemp("LINK") = "" then
response.write "<td width=75 align=center> </td>" 
Else
response.write "<td width=75 align=center> " & RStemp("TELE") & " </td>" 
end if
%>
<%
response.write "</tr>"
RStemp.MoveNext
Loop
%>

Jag lade till en end if också som jag tycker saknas.

------------------
essentitia preter non sans multiplicandum

Kom underfund med det ;)

Nu till nästa felmeddelande...

'loop' utan 'do'

?

Jag har ju 'do' med?

------------------
/Sammy Swärd

men det beror väl på att du har glömt en end if (som jag lade till).

------------------
essentitia preter non sans multiplicandum

Exakt ;)

Lade märke till det nu...

LarsG... du är en klippa..

Nu är allt löst...

Tack så mycket!

------------------
/Sammy Swärd