Include - problem, vad annars

Hej!
Jag är inte så bra på asp, men fösöker lära mig..

Problemet mitt nu är att jag inte fattar hur det går till att inkludera en asp fil i en annan aspfil. Jag vil att de 3 senaste nyheterna från nyhetsscriptet skall visas på första sidan (jag kallar den test.asp just nu). Nyheterna ligger här news/news2.asp

Jag har skrivit <!--#include file="news/news2.asp"--> i test.asp, och i news2.asp har jag angett att det är test.asp som skall inkludera just news2.asp.

När jag då skall testa test.asp får jag detta felmeddelandet:

Microsoft JScript compilation error '800a03f7'

Unterminated string constant

/news/news2.asp, line 3

NyhetPerSida = 3 'Antal nyhetsrubriker per sida
---------------------------------------------------------------------------------^

Så här ser de relevanta linjerna ut:

<%
'##############ÄNDRA DETTA#############################'
NyhetPerSida = 3 'Antal nyhetsrubriker per sida
URL = "../test.asp" 'Sidan du inkluderar news2.asp i
db = Server.MapPath("db/news.mdb") 'Databasens sökväg
Width = "50" 'Bredd på bilden
'#####################################################'
%>

Jag har testat olika saker som jag trodde kanske var fel, men jag är nog bara en stackars amatör... ;)

Hoppas inte jag har glömt något nu..*hmm*
Tacksam för hjälp! PÅ förhand tack.

Är nyhetpersida en int eller en string? (eller den är odimmad och oanvänd innan?)

Jag skickar hela koden i news2.asp:

<%
'##############ÄNDRA DETTA#############################'
NyhetPerSida = 3 'Antal nyhetsrubriker per sida
URL = "../test.asp" 'Sidan du inkluderar news2.asp i
db = Server.MapPath("db/news.mdb") 'Databasens sökväg
Width = "50" 'Bredd på bilden
'#####################################################'
%>

<!--
##########################################
Gruvsjo Nyheter v3
Åsa Gruvsjö ©
https://www.gruvsjo.com
Asa@gruvsjo.com

Fri att använda om ni låter copyrightkoden stå kvar!
##########################################
--><style type="text/css">
<!--
body {
margin-left: 0px;
margin-top: 0px;
margin-right: 0px;
margin-bottom: 0px;
background-color: #EFEFE4;
}
-->
</style>

<table cellpadding="1" cellspacing="0" width="100%" border="0">

<%Set Conn = Server.CreateObject("ADODB.Connection")
Conn.Open "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & db

If Request.QueryString("ID") = "" Then

Set RecSet = Server.CreateObject("ADODB.Recordset")
Sidan = Request.QueryString("sida")
If Sidan = "" then
sida = 1
Else
sida = Sidan
End If

With RecSet
.CursorLocation = 3
.CacheSize = NyhetPerSida
End With

SQL = "SELECT * FROM news Order By id desc"
RecSet.Open SQL, Conn

If RecSet.EOF Then%>
<tr>
<td>Inga nyheter inlagda!</td>
</tr>
<%Else

With RecSet
.MoveFirst
.PageSize = NyhetPerSida
.AbsolutePage = sida
End With

Sidor = RecSet.PageCount
x = 0
Do While Not RecSet.EOF And x < RecSet.PageSize%>
<tr>
<td><img src="bilder/news.gif" border="0" valign="middle"></td><td width="94%"><b><%=RecSet("rubrik")%></b> | <%=FormatDateTime(RecSet("datum"),2)%> (<%=FormatDateTime(RecSet("datum"),4)%>)</td>
</tr>
<tr>
<td valign="top" colspan="2"><%If Len(RecSet("nyhet")) > 150 Then%><%=Left(RecSet("nyhet"),150)%>...<%Else%><%=RecSet("nyhet")%><%End If%></td>
</tr>
<tr>
<td colspan="2"><b><a href="<%=URL%>?ID=<%=RecSet("ID")%>">Läs mer</a></b></td>
</tr>
<tr height="20">
<td colspan="2"> </td>
</tr>
<%x=x+1
RecSet.MoveNext
Loop
RecSet.Close
If Sidor > 1 Then%>
<tr>
<td valign="top" colspan="2">
<%For Sid = 1 To Sidor
If (Int(Sid)) = (Int(sida)) Then%><b><%=Sid%></b><%Else%> <a href="<%=URL%>?sida=<%=Sid%>"><%=Sid%></a> <%End If
Next%>
</td>
</tr>
<%End If
End If
End If
If Request.QueryString("ID") <> "" Then
Set RS=Conn.Execute("Select * From news Where id=" & Request.QueryString("ID"))%>
<tr>
<%If RS("bild") <> "" Then%>
<td rowspan="3" valign="top"><img src="<%=RS("bild")%>" border="1" width="<%=Width%>"></td>
<td rowspan="3" width="5"> </td>
<%End If%>
<td width="6%"><img src="bilder/news.gif" border="0" valign="middle"></td><td width="94%"><b><%=RS("rubrik")%></b> | <%=FormatDateTime(RS("datum"),2)%> (<%=FormatDateTime(RS("datum"),4)%>)</td>
</tr>
<tr>
<td colspan="2"><%=Replace(RS("nyhet"),vbCrLf,"<br>")%><br><br>/<%=RS("namn")%></td>
</tr>
<tr>
<td colspan="2"><br><a href="<%=URL%>">« Tillbaka</a></td>
</tr>
<%End If%>
</table>

Om jag tar bort alla kommentarer överst, fram till och med copyrighttexten, får jag detta felmeddelandet:
Microsoft JScript compilation error '800a03ec'

Expected ';'

/news/news2.asp, line 31

Set Conn = Server.CreateObject("ADODB.Connection")
----^

Men du, JSCRIPT compilation error står där. Jag kan vara helt fel på det, men det här är VBscript kod du kör?

Lägg till:

<%@LANGUAGE="VBSCRIPT" CODEPAGE="1252"%>

Överst

Ah, nu fixade det sig. Det stod något om javascript på test.asp. Bytte ut det med den koden du gav mig Jymdis. Tack så mycket för hjälpen! :)