recordset och array på samma sida

KarlssonMedlem sedan maj 2000252 inlägg

4 apr. 2004 20:31#1

Halloj
Visste inte riktigt hur jag skulle beskriva problemet...
Har en paging i en gästbok som funkar... har en sida med ett recordset som funkar, men inte när jag provar ha dom på samma sida!
Tycker jag provat det mesta och börjar bli jäkligt trött på det här nu, skulle vara tacksam för svar.
Ursäkta den långa koden

<%
'Option Explicit
Response.Buffer = FALSE
%>
<!DOCTYPE HTML PUBLIC "-//W3C//DTD HTML 4.01 Transitional//EN" "http://www.w3.org/TR/1999/REC-html401-19991224/loose.dtd">
<HTML>
<HEAD>
<link href="Stylesheet/fjallsaker.css" rel="stylesheet" type="text/css">
</HEAD>
<body>
<div class="left">
<%
Session.LCID = 1053

'## -- hämta alla poster --
Function getRecords
	Dim conn
	Dim m_strConnString
	Dim m_strSQL
	Dim m_objRS
	Dim m_arrRecords
	

	'## -- skapa connection object och öppna upp databasen --
	Set conn = Server.CreateObject("ADODB.Connection")
	Set rs = Server.CreateObject("ADODB.Recordset")
	%>
	<!--#include file="connect.asp"-->
<%
		'## -- sql-fråga för att hämta alla poster --
		'## -- denna ska du ändra så att den stämmer
		'##    med det som du vill hämta --
		m_strSQL = "SELECT id, namn, [datum], inlagg, epost, svar " & _
			"FROM gastbok WHERE visa = 0 " & _
			"ORDER BY [datum] DESC"
			'## -- SQL-sats för att visa aktuella saker på högersidan --
		sSQL="SELECT TOP 5 * FROM [texter] WHERE [content] = '"& "nyhet" &"' ORDER BY [datum] DESC"
				
			'## -- recordset för att hämta alla poster --
			Set m_objRS = conn.Execute(m_strSQL)
			
				If Not m_objRS.EOF Then
					m_arrRecords = m_objRS.GetRows
					getRecords = m_arrRecords
				End If
				
				'## -- clean up --
				m_objRS.Close
			Set m_objRS = Nothing
			
		conn.Close
	Set conn = Nothing

End Function

'## -- skriver ut sidnavigeringen --
'## -- skriv ut föregående sida --
Sub PrevPage(ByVal WichPage)
	Dim strScriptName
	strScriptName = Request.ServerVariables("SCRIPT_NAME")

	'## -- skriv ut en länk till föregående sida --
	If CInt(WichPage) > 1 Then
		Response.Write "<p style='text-align: center'>" & "<A href='" & strScriptName & "?" & _
			"page=" & WichPage - 1 & "' style='text-decoration: none'><< Föregående</A> "
	Else
		Response.Write "<p style='text-align: center'>" & "<< Föregående "
	End If
End Sub

'## -- skriv ut nästa sida --
Sub NextPage(ByVal HowManyPages, ByVal WichPage)
	Dim strScriptName
	strScriptName = Request.ServerVariables("SCRIPT_NAME")
	
	'## -- skriv ut en länk till nästa sida --
	If CInt(WichPage) < CInt(HowManyPages) Then
		Response.Write "<A href='" & strScriptName & "?" & _
			"page=" & WichPage + 1 & "' style='text-decoration: none'>Nästa >></A>" & "<p style='text-align: center'>"
	Else
		Response.Write " Nästa >>" & "<p style='text-align: center'>"
	End If
End Sub
 
'## -- skriv ut sidnummer navigeringen --
Sub PageNumbers(ByVal HowManyPages, WichPage)
	Dim strScriptName
	Dim I
	
	'## -- kolla om det finns några sidor --
	If HowManyPages = 0 Then
		Response.Write "0"
		Exit Sub
	End If
	
	strScriptName = Request.ServerVariables("SCRIPT_NAME")

	'## -- skriv ut länkar till sid nummer n. 
	'##    Den sida som visas ska ej vara länkad --
	For I = 1 To HowManyPages
		If CInt(I) <> CInt(WichPage) Then
			Response.Write "<A href='" & strScriptName & "?" & _
				"page=" & I & "' style='text-decoration: none'>" & I & "</A> "
		Else
			Response.Write "<B>" & I & "</B> "
		End If
	Next

End Sub

'## -- vilken post ska pagingen börja på --
Function getStartID(ByVal PageSize, ByVal ViewPage) ' As Integer
	Dim m_intStart
	m_intStart = ((PageSize * ViewPage) - PageSize)
	getStartID = m_intStart
End Function

'## -------------------------------------------------------------
'## -- räkna ut hur många sidor som ska visas --
'## -- updated: July 14, 2001
'## -- update by: Patrik Berggren, [email]mrwize@mrwize.nu[/email]
'## -------------------------------------------------------------
'##
'## -- vid vissa tillfällen returnerades fel sidantal.
'##    Felet/Buggen berodde på avrundningen med CInt()
'##    och CLng().
'## -- Avrundningen som jag gjorde:
'##
'##    m_intTotalPages = CInt((HowManyRecords / PageSize) + 0.5)
'##
'##    vart i vissa fall fel och sid antalet vart fler än 
'##    vad det egentligen skulle vara.
'##    Lösningen, hoppas jag, är att kolla hur stor resten
'##    blir vid avrundning.
'##    Om resten är större än 0 eller mindre än 0.5 så ska en sida
'##    läggas till.
'##    I annat fall så gäller avrundningen.
'##    Har testat flera olika kombinationer med olika records antal
'##    och sidstorlekar och ej hittat några buggar.
'##    Så nu hoppas jag att denna paging är buggfri *ler*
'## -------------------------------------------------------------
Function countPages(ByVal HowManyRecords, ByVal PageSize)
	Dim m_intTotalPages, m_intRest

	m_intTotalPages = HowManyRecords / PageSize

	If m_intTotalPages < 1 Then
		m_intTotalPages = 1
	Else
		m_intRest = m_intTotalPages - CLng(m_intTotalPages)
		
		If m_intRest > 0 AND m_intRest < 0.5 Then
			m_intTotalPages = CLng(m_intTotalPages) + 1
		Else
			m_intTotalPages = CLng(m_intTotalPages)
		End If
	End If

	'## -- return how many pages --
	countPages = m_intTotalPages
End Function
'##***********************************************************************************

Dim arrRecords
Dim intPageSize
Dim intPage
Dim intStartID
Dim I
Dim intId
Dim strNamn
Dim dteDatum
Dim strEpost
Dim strInlagg
Dim strSvar
Dim intTotalPages
Dim intTotalRecords

'## -- vilken sida ska visas --
intPage = Request.QueryString("page")
If intPage = "" Then intPage = 1

'## -- hur många poster ska visas per sida --
intPageSize = 5

'## -- hämta alla records, hämtas med metoden getrows och returneras 
'##    som en array. --
arrRecords = getRecords

'## -- vilken post är den första --
intStartID = getStartID(intPageSize, intPage)

'## -- printa ut sidan som ska visas
'##    alla poster finns i arrayen arrRecords som
'##    kommer från funktionen getRecords --
If IsArray(arrRecords) Then
	'## -- hur många records finns det totalt --
	intTotalRecords = UBound(arrRecords,2) + 1
	
	'## -- hur många sidor finns det i recordsetet --
	intTotalPages = countPages(intTotalRecords, intPageSize)
	%>
   
<p class="fet12">L&auml;mna ett fotsp&aring;r eller varf&ouml;r inte ett f&auml;rdmeddelande</p>
    <form name="form1" method="post" action="adda_gastbok.asp">
      <p>namn:<br>
        <input name="namn" type="text" id="namn" size="50">
        <br>
        e-post:<br>
        <input name="epost" type="text" id="epost" size="50">
        <br>
        Och detta vill jag s&auml;ga: <br>
        <textarea name="inlagg" rows="5" id="inlagg" cols="38"></textarea>
      </p>
      <p> 
        <input type="submit" name="Submit" value="Skicka mitt inl&auml;gg" style="width: 320px;"> 
       <br> 
      <input type="reset" name="Submit2" value="Radera" style="width: 320px;">
      </p>
    </form>
    <%
	Response.Write "<P>Visar nu sida <B>" & intPage & "</B> av " & intTotalPages & ", " & "antal inlägg: " & intTotalRecords &"</P>" & "<hr>"
	For I = intStartID To ((intStartID + intPageSize) -1)
	
		intId = arrRecords(0,I)
		strNamn = arrRecords(1,I)
		dteDatum = arrRecords(2,I)
		strInlagg = arrRecords(3,I)
		strEpost = arrRecords(4,I)	
		strSvar = arrRecords(5,I)
			
		'##-- Växlat till HTML för att få bättre överblick över visningen
		%>
    <P><%=dteDatum%><br><br>
      <%
		if strEpost <> "" then
		%>
      <a href="mailto:<%=strEpost%>"><b><%=strNamn%></b></a><br><br>
      <%else%>
      <b><%=strNamn%></b><br><br>
      <%end if%>
      <%=Server.HTMLEncode(strInlagg)%><br>
      <%if strSvar <> "" then%>
      <%=strSvar%> 
      <%end if%>
    <hr>
    <%
		If I = UBound(arrRecords,2) Then Exit For
	Next
Else
	'## -- inga poster fanns i db --
	intPage = 0
	intTotalRecords = 0
	intTotalPages = 0
	
	'## -- skriv ut att inga poster hittades --
	Response.Write "<P>Inga inlägg i gästboken</P>"
End If

'## -- skriv ut sidnavigerings menyn --
Call PrevPage(intPage)
Response.Write " | "

Call NextPage(intTotalPages,intPage)

Response.Write "&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;Sidor: "

Call PageNumbers(intTotalPages,intPage)
%>
</div>

<div class="middle">
&nbsp;
</div>
<!--
**********************************************************************************************
Här börjar den högra delen av gästboken
**********************************************************************************************
-->
<div class="right">
<img src="bilder/gfx/rubrik_aktuellt_smal.gif" alt="" width="159" height="60" hspace="0" vspace="0"><br>
<img src="bilder/gfx/graydot.gif" width="500" height="1">
<%
rs.Open sSQL, Conn
%>
<div class="right">
<img src="bilder/gfx/rubrik_aktuellt_smal.gif" alt="" width="159" height="60" hspace="0" vspace="0"><br>
<img src="bilder/gfx/graydot.gif" width="500" height="1">
<%Do While Not rs.EOF
nyss = rs("datum")
kortnyss = FormatDateTime (nyss,vbShortdate)
%>		
		<br><span class="fet11"><%=kortnyss%></span>
		<br><span class="rubliten10fet"><%=rs("rubrik")%></span>
		<br><span class="ingress"><%=rs("ingress")%></span>
		<br><img src="bilder/gfx/las_mer.gif" width="10" height="12" hspace="0" vspace="0"><a class="rubliten10fet" href="aktuellt.asp?id=<%=rs("id")%>">läs mer...</a><br> 
		<br><img src="bilder/gfx/graydot.gif" width="500" height="1">
<%
rs.MoveNext
Loop
rs.Close
Conn.close
Conn = nothing
%>
</div>
</BODY>
</HTML>

/MK

KarlssonMedlem sedan maj 2000252 inlägg

4 apr. 2004 21:14#2

Kan för mitt liv inte hitta redigerafunktionen!!!!
Har glömt en sak, det är den andra delen av koden som inte fugnerar, den med recordsetet.
Får felmeddelande

Körningsfel i Microsoft VBScript fel '800a01a8' 

Objekt krävs.: '' 

/fjallsaker/gbok.asp, rad 344

Rad 344:
rs.Open sSQL, Conn
Nu ska det väl vara allt hoppas jag

LarsGMedlem sedan dec. 200012 464 inlägg

4 apr. 2004 21:18#3

När du kommer till rad 344 så finns inte Conn längre då du tidigare gör

set conn = nothing

KarlssonMedlem sedan maj 2000252 inlägg

4 apr. 2004 21:22#4

så deprimerande! jag trodde ju att jag kunde öppna den med rs.open osv, men hur gör jag då?

LarsGMedlem sedan dec. 200012 464 inlägg

4 apr. 2004 21:33#5

Ta bort dessa rader t.ex.

conn.close
set conn = nothing

eller öppna det ånyo.

KarlssonMedlem sedan maj 2000252 inlägg

4 apr. 2004 21:45#6

Ursäkta min tröghet, men jag har redan provat ta bort dom, hur skriver jag för att öppna dom igen?

KarlssonMedlem sedan maj 2000252 inlägg

5 apr. 2004 12:14#7

Tänk vad lite sömn kan göra för den mänskliga hjärnan.... :-)
Nu funkar det, men tack för hjälpen iaf