Alternativ funktion i Excel 2010

Hej gott folk.

Tänkte bara va det finns för alternativ till detta:

=OM(ELLER(OCH(E15<=E16;F15<=F16;G15<=G16;osv...)
;C16="x");"Utfört";"Ej Utfört")

Den blir ganska lång, och det lär väl finnas nån smidig funktion för detta kanske?

Tacksam för svar
Daniel

En variant är att mata in det som en matrisformel, dvs:
=OM(ELLER(OCH(E15:G15<=E16:G16);C16="x");"Utfört";"Ej Utfört")
Och sedan avsluta med att trycka trycka [ctr]+[shift]+[enter] så att den får måsvingar

Men personligen skulle jag göra någonting sånt här (matas in som en vanlig formel):
=OM(ELLER(PRODUKTSUMMA((E15:G15>E16:G16)*1)=0;C16="x");"Utfört";"Ej Utfört")
Lite längre och "egentligen" en Matrisformel, men man slipper hålla reda på om man tryckt på rätt knappar.

Fördelen med den första formeln är naturligtvis att den kan vara lättar att förstå.

/MV

Strålande!
alt 2 får de bli.
Tack så mycket!

Kan ju passa på att ställa en liknande fråga:
Säg att man står i V15 och ska ha Summan av E11*E15, F11*F15 ovs. Sen ska summan av det gångras med 6, nån ide för detta?

Och sen kan man passa på att fråga, vad gör {} för något?

//Daniel

Det beror på hur/när det används.
Om du har en formel som skall matas med en vektor/matris så skriver man normalt sett in ett cellintervall som innehåller de data du vill göra något med. Om t.ex A1:C3 innehåller tre tal i stil med:
1|2|3
Så ger det här summan 6
=Summa(A1:C3)

Antag att du av någon anledning inte kan/vill ha data i celler då kan du istället fylla på data med en "manuell matris", typ:
=SUMMA({1;2;3}) (motsvarar data i kolumn)
eller
=SUMMA({1\2\3}) (motsvarar data i rad)
Som skrivs in som vanlig

(skitdåligt exempel eftersom Summa lika gärna kan skrivas =SUMMA(1;2;3))
Men det finns en massa saker du kan använda det till
Ett exempel som returnerar siffror när du skriver in bokstäver i A1:
=LETARAD(A1;{"a"\75;"b"\100;"c"\110};2;FALSKT)
Vet inte vad du skall ha det till, i 99,99999% av fallen är det bättre att skriva upp data i celler, men det går i alla fall att göra så här.

Den andra användningen är sk Matrisformler.
Antag att du vill göra någonting i stil med det du visade innan. Typ
E15*E16+F15*E16+G15*G16 ...

Det smartaste är naturligtvis att skriva den här formeln i E17
=E15*E16
Kopierar man formeln till höger så får man en rad med produkter (multiplikationsresultat ).
Sen är det enkelt att summera ihop rad 17
Summa(E17:E17)

En matrisformel innebär alltså att man gör motsvarigheten till Rad 17 genom att skriva någonting i den här stilen och tryck CTRL+shift+enter
Då skriver excel in måsvingarna och behandlar hela formeln som en matrisfromel:
{=SUMMA(E15:K15*E16:K16)}
helt plötsligt multipliceras varje tal i rad 15 med motsvarande tal i rad 16 och sen summeras det
Måsvingarna är bara där för att visa att det behandlas som en matris

Ganska kinkigt eftersom du måste se till att det är lika många tal i båda "matriserna"

Återigen: det är i de allra flesta fall smidigare att lägga in formler på bladet.

PS, för exemplet finns det redan en färdig funktion i excel:
=PRODUKTSUMMA(E15:K15;E16:K16)
Men jag tänkte att summa var lätt att förstå.

Ehhh, googla Matrisformler, det finns garanterat mer pedagogiska exempel
/MV

Summan av E11*E15, F11*F15

Såg inte din första fråga, men det blir en variant av förra svaret:

Du tar hand om summeringen med Produktsumma, och det resultatet multipliceras med 6, dvs någonting i stil med

=6*PRODUKTSUMMA(E11:J11;E15:J15)
Eller en matrisformel:
{=6*SUMMA(E11:J11*E15:J15)}

Jag får än en gång tacka för väldigt bra svar!

Bra att inte bara veta hur det ska se ut, utan också varför.
//Daniel