Snitt på olika kolumner

Jag vill ha följande "uträkning" i excel, men vet inte hur jag ska göra det.
Mitt exceldokument ser ut ungefär såhär.
Kolumn A: 1,2, 3 o.s.v. på olika rader
Sedan kolumn D-N innehåller olika statistik t.ex
Speluppfattning, Styrka, Skridsko...

Jag vill kunna ha en uträkning som gör att den som har bäst snitt på dessa 3,
visas på ett ställe.
Och sedan den som har bäst snitt på t.ex
3 andra kolumner hamnar där o.s.v.

Jag vet hur man räknar ut snittet på "alla" attribut, och därigenom vet jag hur jag t.ex kan ta snittet på "3" attribut och visa varje persons värde.

Men det tar för lång tid att göra en sådan uträkning (om man räknar per person).
Så jag vill ha en stor uträkning som räknar ut detta, och sedan visar mig dom "3" bästa t.ex.

Någon som har en ANING om ens vad jag pratar om,
och ev. kan hjälpa mig med en bra lösning?

Kan skicka excel-filen vid behov.

Min första spontana tanke är att lägga till en kolumn för varje snitt du vill räkna ut. Sedan använda villkorad formatering tillsammans med MAX()/RANG() för att visa på den/de rad(er) som har högst poäng.

Men du kanske söker något mer sofistikerat?

Nu skall jag försöka var pedagogisk (det brukar inte gå så bra, det här kommer nog mest att bli obegripligt...). Så ha lite tålamod.

Antag att du bara har tre data i kolumn B-D (Speluppfattning, Styrka, Skridsko)
Nu skulle du ju kunna räkna ut medel för varje rad genom att kopiera formeln
=MEDEL(B2:D2)
hela vägen ner i kolumn E (DVS det som tosse är inne på).

sedan kan du kolla rangordningen i kolumn F genom att kopiera in formeln
=RANG(E2;E:E)
hela vägen ner i f: kolumnen

En annan variant. För att hitta de 3 högsta värdet i E-kolumnen kan du skriva in formler i stil med:
=STÖRSTA(E:E;1)
=STÖRSTA(E:E;2)
=STÖRSTA(E:E;3)
(Eller MAX som TOSSE föreslår)

Nu har vi ett par problem.
1. Om flera spelare har samma "toppnotering" så går de inte att skilja åt. Det är svårlöst :-(
2. Du får ju bara reda på högsta medel, inte spelarens ID.
3. Det blir en massa extrakolumner.

1:an är svårlöst, men 2&3 borde gå att fixa. Man får utnytja "matrisformler". Exempel med 71 rader:
=STÖRSTA(((B2:B71+C2:C71+D2:D71)/3);1)

när du står i formeln så trycker du CTRL+SHIFT+ENTER. Då blir det "måsvingar"
{=STÖRSTA(((B2:B71+C2:C71+D2:D71)/3);1)}

Då kommer STÖRSTA att "se" en matris som består av 70 rader med medelvärden och STÖRSTA kan sedan plocka ut det högsta värdet (utan att vi behöver skapa medel i kolumn E).

Om man inte tycker om att trycka CTRL+SHIFT+ENTER (eller bara tycker att matrisformler är häxkonst, vilket det är ibland) så kan du använda PRODUKTSUMMA. Den jobbar som en matrisformel, men man slipper hålla på med {}
Exempel
=PRODUKTSUMMA(STÖRSTA((B2:B71+C2:C71+D2:D71)/3;1))

Ok, nu vet du det högsta medlet, nu behöver du bara lista ut vem det är :-)

=PRODUKTSUMMA((STÖRSTA((B2:B71+C2:C71+D2:D71)/3;1)=(B2:B71+C2:C71+D2:D71)/3)*1;RAD(B2:B71))

Ger radnummret (när medelvärdet är = högsta värdet så blir villkoret sant och radnumret returneras, det går naturligtvis åt skogen om det finns flera med högsta medel).

Om man känner till radnumret så kan man använda "INDIREKT" för att få excel att returnera värdet i en speciell cell, typ:
=INDIREKT("A"&15)
Skulle returnera data som står i kolumn A, rad 15

Så slutformeln för individen blir:

=INDIREKT("A"&PRODUKTSUMMA((STÖRSTA((B2:B71+C2:C71+D2:D71)/3;1)=(B2:B71+C2:C71+D2:D71)/3)*1;RAD(B2:B71)))

Och medelvärdet:
=PRODUKTSUMMA(STÖRSTA((B2:B71+C2:C71+D2:D71)/3;1))
Ändra 1:an längs bak i "STÖRSTA" till en 2:a för att hitta den näst högsta värdet osv.

Allt det här går naturligtvis åt skogen om du har flera spelare i topp...
Skulle föreslå att du gör någonting i stil med Tosses förlag istället. Det går ju lätt att dölja kolumner som ingen behöver se.