---
title: "hämta xml via http?"
type: "forum-thread"
url: "https://www.webforum.nu/amne/xml/5192-hämta-xml-via-http"
topic: "XML"
topic_url: "https://www.webforum.nu/amne/xml"
author: "Vide"
published: "2001-06-02T19:57:00.000Z"
updated: "2003-05-12T21:05:25.000Z"
replies: 13
views: 902
page: 1
pages: 1
language: "sv-SE"
site: "webForum — webforum.nu"
rights: "Upphovsrätten till varje inlägg tillhör dess författare."
attribution: "Citera som: webForum, https://www.webforum.nu/amne/xml/5192-hämta-xml-via-http"
---

# hämta xml via http?

## #1 — Vide, 2001-06-02T19:57Z

Hejsan, håller på och testar lite... det är så att jag använder ASPs inbyggda parser för att presentera XML-filen mha en XSL-fil.

Nuvarande kod:

```
sourceFile = Request.ServerVariables("Appl_physical_path") & "xml\contacts.xml"
styleFile = Request.ServerVariables("Appl_physical_path") & "xml\contacts.xsl"

Set source = Server.CreateObject("Microsoft.XMLDOM")
source.async = false
source.load(sourceFile)

Set style = Server.CreateObject("Microsoft.XMLDOM")
style.async = false
style.load(styleFile)

HTMLcode = source.transformNode(style)
Response.write HTMLcode
```

Jag vill alltså göra såhär:

```
sourceFile = "http://www.lurgoyf.com/xml/contacts.xml"
styleFile = Request.ServerVariables("Appl_physical_path") & "xml\contacts.xsl"

Set source = Server.CreateObject("Microsoft.XMLDOM")
source.async = false
source.load(sourceFile)

Set style = Server.CreateObject("Microsoft.XMLDOM")
style.async = false
style.load(styleFile)

HTMLcode = source.transformNode(style)
Response.write HTMLcode
```

Men det fungerar inte. Hur skall jag gå tillväga?

Permalänk: https://www.webforum.nu/p/5192

## #2 — MattiasW, 2001-06-03T09:23Z

Så här gör jag i Delphi. Använder samma COM objekt som du gör i ASP, lite annan syntax bara:
Jag använder XMLHTTPRequest för att först hämta XML’en från en URL.

```
XMLHTTP:= CoXMLHTTPRequest.Create;
XMLHTTP.open('GET', 'http://www.slashdot.org/slashdot.xml', False, Unassigned, Unassigned);

XMLHTTP.setRequestHeader('Content-type', 'text/xml');		// Describe what we are expecting.
XMLHTTP.send(Unassigned);	// Go get it.

XMLDoc:= CoDomDocument.Create;
XMLDoc.async:= False;
XMLDoc.loadXML(XMLHTTP.ResponseText);
```

Blir väl ungefär så här i ASP:

```
Set XMLHTTP = Server.CreateObject("Microsoft.XMLHTTPRequest")
XMLHTTP.open('GET', 'http://www.slashdot.org/slashdot.xml', False);
XMLHTTP.setRequestHeader('Content-type', 'text/xml');		' Describe what we are expecting.
XMLHTTP.send();	' Go get it.

Set XMLDoc = Server.CreateObject("Microsoft.XMLDOM")
source.async = false
source.loadXML(XMLHTTP.ResponseText)
```

Permalänk: https://www.webforum.nu/p/238090

## #3 — Vide, 2001-06-03T09:36Z

Tackar... men han verkar inte kunna skapa objektet XMLHTTPRequest, är det något som har implementerats i verison 4 av MSXML?

Permalänk: https://www.webforum.nu/p/238091

## #4 — MattiasW, 2001-06-04T08:13Z

Ursäkta mig.

Jag hittade denna kod-snutt från MSDN

```
The following code snippet comes from a VBScript file and illustrates simple interaction between a client application and a URL—in particular, an ASP page: 

Set xmlhttp = CreateObject("Microsoft.XMLHTTP")
xmlhttp.open "GET", "http://expoware/test.asp", False

xmltext = "<magazine>MIND</magazine>"
Set xmldom = CreateObject("Microsoft.XMLDOM")
xmldom.loadXML xmltext
xmlhttp.send xmldom

MsgBox xmlhttp.responseText
```

Heter tydligen Microsoft.XMLHTTP istället för Microsoft.XMLHTTPRequest.

Där ser man

Permalänk: https://www.webforum.nu/p/238092

## #5 — Vide, 2001-06-04T09:22Z

Hmm... det objektet fanns... men sidan visas utan själva innehållet (XMLfilen) som skall formateras av min XSL-fil.

Några tips om tutorialer i ämnet HTTP med XML?

Tack för hjälpen hitintills... :)

Permalänk: https://www.webforum.nu/p/238093

## #6 — MattiasW, 2001-06-04T10:00Z

Jag sökte på efter "XMLHTTPRequest" på msdn.microsoft.com och hittade denna sida  <http://msdn.microsoft.com/library/periodic/period00/cutting0400.htm> 

Du kan även läsa om IXMLHTTPRequest på denna sida  <http://msdn.microsoft.com/library/psdk/xmlsdk/xmld8bp0.htm> 

Har du prova att skriva ut innehållet från "http://www.lurgoyf.com/xml/contacts.xml" utan att köra det genom XMLDOM?

Permalänk: https://www.webforum.nu/p/238094

## #7 — Vide, 2001-06-04T14:39Z

Jag har testat att skriva ut innehållet och då skapas sidan korrekt (utan XSL).

Men hur går jag härifrån, när jag använder XMLDOM så laddar man ju en fil, men nu vill jag ju köra en sträng genom XSL-parsern.

\*letar vidare\*

Permalänk: https://www.webforum.nu/p/238095

## #8 — emission, 2001-06-04T15:20Z

set objXMLHTTP = Server.CreateObject("Microsoft.XMLHTTP")

objXMLHTTP.open "GET","http://www.lurgoyf.com/xml/contacts.xml",false

set source = objXMLHTTP.responseXML

osv..

Permalänk: https://www.webforum.nu/p/238096

## #9 — Vide, 2001-06-04T15:24Z

Självklart... :e

Tackar så mycket för hjälpen båda två... :)

Permalänk: https://www.webforum.nu/p/238097

## #10 — daPhil, 2003-05-12T14:27Z

> **emission skrev:**
>
> set objXMLHTTP = Server.CreateObject("Microsoft.XMLHTTP")
> 
> objXMLHTTP.open "GET","http://www.lurgoyf.com/xml/contacts.xml",false
> 
> set source = objXMLHTTP.responseXML
> 
> osv..

Vadå "osv.."? Hur får jag in XSL referensen i koden?

Permalänk: https://www.webforum.nu/p/1043847

## #11 — SPiN, 2003-05-12T14:56Z

Ur Vides första inlägg:

```
Set style = Server.CreateObject("Microsoft.XMLDOM")
style.async = false
style.load(styleFile)

HTMLcode = source.transformNode(style)
```

source och style är objekt av typen Microsoft XMLDOM, med metoden transformNode() kan du använda ditt XSL-dokument ( style ) mot XML-filen ( source ).

Permalänk: https://www.webforum.nu/p/1043869

## #12 — daPhil, 2003-05-12T16:57Z

Jag får det absolut inte att funka.

```
set objXMLHTTP = Server.CreateObject("Microsoft.XMLHTTP")
	objXMLHTTP.open "GET","http://123.123.123.123:8000/admin.cgi?mode=viewxml",false, "xxxx", "xxxx"
	set sourceFile = objXMLHTTP.responseXML

	styleFile = Server.Mappath("template.xsl")
	
	Set source = Server.CreateObject("Microsoft.XMLDOM")
	source.async = false
	source.load(sourceFile)
	
	Set style = Server.CreateObject("Microsoft.XMLDOM")
	style.async = false
	style.load(styleFile)
	
	HTMLcode = source.transformNode(style)
	Response.write HTMLcode
```

En blank sida är allt jag får. URLen till XMLen stämmer. XSL dokumentet är rätt.

Permalänk: https://www.webforum.nu/p/1043956

## #13 — daPhil, 2003-05-12T20:49Z

Jag fixade det ändå.. Här ifall någon vill ha:

```
<%
	'Manuella variabler
	ServerDomain = 	"www.x.com" 	'Domän
	ServerPass =	"xxxx"					'Lösenord
	ServerPort =	"xxxx"					'Port
	
	'Den fullständiga adressen
	ServerURL = "http://"& ServerDomain &":"& ServerPort &"/admin.cgi?pass="& ServerPass &"&mode=viewxml"
	
	'XMLDOM
	Set oXML = Server.Createobject("Microsoft.XMLDOM")
	oXML.async = "false"
	
	'XMLHTTP
	Set oTrans = Server.CreateObject("Microsoft.XMLHTTP")
	oTrans.Open "GET", ServerURL, "false"
    oTrans.Send
	oXML.LoadXML(oTrans.ResponseText)
	
	Set Songs = oXML.SelectNodes("//SONG")
%>

<b>Låtar:</b>
<br>
<br>
<% For Each Song In Songs %>
	<%=Song.selectSinglenode("TITLE").text%><br>
<% Next %>
```

Men jag lyckades aldrig använda XSL ihop med extern XML via HTTP tyvärr.. Jag trodde XML via HTTP var en av de "stora" plusen med XML? Nåja..

Permalänk: https://www.webforum.nu/p/1047243

## #14 — niko, 2003-05-12T21:05Z

Tycker steget över XMLHTTP känns onödigt.

```
<%
	'Manuella variabler
	ServerDomain = 	"www.x.com" 	'Domän
	ServerPass =	"xxxx"					'Lösenord
	ServerPort =	"xxxx"					'Port
	'Den fullständiga adressen
	ServerURL = "http://"& ServerDomain &":"& ServerPort &"/admin.cgi?pass="& ServerPass &"&mode=viewxml"
	'XMLDOM
	Set oXML = Server.Createobject("Microsoft.XMLDOM")
	oXML.async = false
	oXML.setProperty "ServerHTTPRequest", true
	oXML.Load ServerURL
	Set Songs = oXML.SelectNodes("//SONG")
%>
<b>Låtar:</b>
<br>
<br>
<% For Each Song In Songs %>
	<%=Song.selectSinglenode("TITLE").text%><br>
<% Next %>
```

 .. borde gå lika bra.

Permalänk: https://www.webforum.nu/p/1047255

---

Tråden på webben: https://www.webforum.nu/amne/xml/5192-hämta-xml-via-http