eller, och, om i samma formel - excell

4 svar · 638 visningar · startad av Yoda 7 juni 2008

YodaMedlem sedan nov. 2002291 inlägg

Frågan7 juni 2008 21:08#1

Hej!

Jag har ett em-tips som jag tänkte göra en rättningsmall till. Jag har fyra om-formler som fungerar. Dessa vill jag binda ihop i en eller-formel men får inte ihop det.

=OM(OCH(Owe!J8=Resultat!J8;Owe!L8=Resultat!L8);3;0)
=OM(OCH(Owe!J8=Owe!L8;Resultat!L8=Resultat!J8);1;0)
=OM(OCH(Owe!J8>Owe!L8;Resultat!J8>Resultat!L8);1;0)
=OM(OCH(Owe!J8<Owe!L8;Resultat!J8<Resultat!L8);1;0)

Första är om man tippat exakt rätt resultat, då får man 3 poäng.
Andra är om man tippat rätt tecken, ett X, då får man 1 poäng.
Tredje är om man tippat rätt tecken, en 1:a, då får man 1 poäng.
Fjärde är om man tippat rätt tecken, en 2:a, då får man 1 poäng.

Antingen infaller den ena eller andra eller tredje eller fjärde och då tänker jag mig en eller-sats. Men jag får inte ihop det.

Jag har skrivit så här:

=eller(OM(OCH(Owe!J8=Resultat!J8;Owe!L8=Resultat!L8);3;0); OM(OCH(Titti!J8=Titti!L8;Resultat!L8=Resultat!J8);1;0); OM(OCH(Karin!J8>Karin!L8;Resultat!J8>Resultat!L8);1;0); OM(OCH(Peter!J8<Peter!L8;Resultat!J8<Resultat!L8);1;0))

Men då returnerar den "falskt" eller "sant". Jag vill ju att det ska komma upp en 3:a eller en 1:a eller en 0:a. Inget annat.

Någon som har förslag?

TosseMedlem sedan aug. 2004126 inlägg

8 juni 2008 09:20#2

du får sätta en if runt hela uttrycket.

=if(ditt uttryck;värde om sant;värde om falskt)

YodaMedlem sedan nov. 2002291 inlägg

8 juni 2008 17:46#3

Okej, fast jag ska ju ha in två olika värden om det är sant. Får inte till det. Just nu har jag så här:

=OM(ELLER(OCH(Owe!J8=Owe!L8;Resultat!L8=Resultat!J8);OCH(Owe!J8>Owe!L8;Resultat!J8>Resultat!L8);OCH(Owe!J8<Owe!L8;Resultat!J8<Resultat!L8));1;0)

Och då får jag en 1:a om något av värdena är sanna eller också 0. Men jag ska ju ha in om man har exakt rätt resultat också och då ska det returneras en 3:a. Den här formeln ska också in:

=OM(OCH(Owe!J8=Resultat!J8;Owe!L8=Resultat!L8);3;0)

Hur får jag in det då?

/Christin

TosseMedlem sedan aug. 2004126 inlägg

9 juni 2008 07:44#4

Byt ut ettan mot den formeln då. Utan =-tecknet förstås.

MindreVetandeMedlem sedan okt. 2005371 inlägg

11 juni 2008 15:56#5

Förutsätter att dina första formler är korrekta (vet inte riktigt vad du vill göra).

Börja med din första formel (exakt rätt=3p) och sätt in din ellerformel istället för nollan. Då körs inte den delen av formeln om "exakt rätt" vilkoret är uppfyllt

=OM(OCH(owe!J8=resultat!J8;owe!L8=resultat!L8);3;OM(ELLER(OCH(owe!J8=owe!L8;resultat!L8=resultat!J8);OCH(owe!J8>owe!L8;resultat!J8>resultat!L8);OCH(owe!J8<owe!L8;resultat!J8<resultat!L8));1;0))

Du kan även förenkla "ellerformeln" (villkoren kan väl inte vara sanna samtidigt?)

(owe!J8=owe!L8)*(resultat!L8=resultat!J8)+(owe!J8>owe!L8)*(resultat!J8>resultat!L8)+(owe!J8<owe!L8)*(resultat!J8<resultat!L8)

vilket ger en marginellt kortare formel:

=OM(OCH(owe!J8=resultat!J8;owe!L8=resultat!L8);3;(owe!J8=owe!L8)*(resultat!L8=resultat!J8)+(owe!J8>owe!L8)*(resultat!J8>resultat!L8)+(owe!J8<owe!L8)*(resultat!J8<resultat!L8))

eller:

=OM((owe!J8=resultat!J8)*(owe!L8=resultat!L8);3;(owe!J8=owe!L8)*(resultat!L8=resultat!J8)+(owe!J8>owe!L8)*(resultat!J8>resultat!L8)+(owe!J8<owe!L8)*(resultat!J8<resultat!L8))