Summera besökare mellan två veckor

Du får omvandla till ISO-veckor:

http://www.tek-tips.com/viewthread.cfm?qid=1244574&page=1 skrev:

CREATE FUNCTION ISOWeek (@TheDate smalldatetime)
RETURNS int
AS
BEGIN
   DECLARE @D int, @D2 int
   SET @D = Convert(int, DateAdd(dd, DateDiff(dd, 0, @TheDate), 0))
   SET @D = @D - @D % 7 + 3
   SET @D2 = Convert(int, DateAdd(yy, DateDiff(yy, 0, DateAdd(dd, @D, 0)), 0))
   SET @D2 = @D2 + 6 - (@D2 - 4) % 7
   RETURN (@D - @D2) / 7 + 1
END

Njae, så hade jag först men det håller tyvärr inte (eller?) eftersom att startdatum kan vara ex. 1:a veckan 2007 och slutdatum kan vara 3:e veckan 2008.
Det innebär att det finns 2 st vecka 1, både 2007 samt 2008 och dessa får inte slås ihop.
En snabb (ful) fix kan se ut så här:

ALTER PROCEDURE [dbo].[Stat_GetWeekUniqueVisitors]
	@StartDate datetime = NULL,
	@EndDate datetime = NULL
AS
BEGIN
	SET NOCOUNT ON;
	SET DATEFIRST 1;

	WITH CTE_Weeks AS (
		SELECT SUM(CntVisitors) AS CntVisitors, 
			CASE DATEPART(WW,CurrentDate) WHEN 53 THEN
				 YEAR(CurrentDate)+1 
				ELSE 
					YEAR(CurrentDate) END AS CurrentYear, 
			CurrentMonth=0, 
			CASE DATEPART(WW,CurrentDate) WHEN 53 THEN
				1 
			ELSE 
				DATEPART(WW,CurrentDate) END AS CurrentWeek,
			CurrentDay=0
		FROM vw_Stat_UniqueVisitors
		WHERE (CurrentDate BETWEEN @StartDate AND @EndDate)
		GROUP BY YEAR(CurrentDate), DATEPART(WW,CurrentDate)
	)

	SELECT SUM(CntVisitors), CurrentYear, CurrentMonth, CurrentWeek, CurrentDay
	FROM CTE_Weeks
	GROUP BY CurrentYear, CurrentMonth, CurrentWeek, CurrentDay
	ORDER BY CurrentYear, CurrentWeek
	
END

Jag vet inte om den kommer att funka på alla sorters datum men den funkar på ovanstående i alla fall! Men snyggt? Nää!

Nu hänger jag inte med. Varför fungerar inte:

ALTER PROCEDURE [dbo].[Stat_GetWeekUniqueVisitors]
	@StartDate datetime = NULL,
	@EndDate datetime = NULL
AS
BEGIN
	SET NOCOUNT ON;
	SET DATEFIRST 1;

	SELECT SUM(CntVisitors) AS CntVisitors, YEAR(CurrentDate) AS CurrentYear, CurrentMonth=0, 
		CurrentWeek = ISOWeek(CurrentDate), CurrentDay=0
	FROM vw_Stat_UniqueVisitors
	WHERE (CurrentDate BETWEEN @StartDate AND @EndDate)
	GROUP BY YEAR(CurrentDate), ISOWeek(CurrentDate)
	ORDER BY YEAR(CurrentDate), ISOWeek(CurrentDate)
END

?

Därför! ;)
Resultatet blir i ditt fall så här:

3	2007	0	1	0
12	2007	0	52	0
19	2008	0	1	0

Och det är fel eftersom det inte finns några besök alls v1. 2007.
Korrekt resultatet ska bli så här:

12	2007	0	52	0
22	2008	0	1	0

Eftersom flera år kan hämtas så kan jag inte bara köra isoweek på veckorna eftersom det grupperas årsvis också!

Du får väl göra en isoyear-funktion som patchar om året till nästa om isoweek blir 1 för ett datum i december.