---
title: "Plocka bort HTML-kommentarer ur Databasen"
type: "forum-thread"
url: "https://www.webforum.nu/amne/asp/94838-plocka-bort-html-kommentarer-ur-databasen"
topic: "ASP"
topic_url: "https://www.webforum.nu/amne/asp"
author: "Davida"
published: "2004-01-15T08:37:45.000Z"
updated: "2004-01-15T09:50:05.000Z"
replies: 6
views: 290
page: 1
pages: 1
language: "sv-SE"
site: "webForum — webforum.nu"
rights: "Upphovsrätten till varje inlägg tillhör dess författare."
attribution: "Citera som: webForum, https://www.webforum.nu/amne/asp/94838-plocka-bort-html-kommentarer-ur-databasen"
---

# Plocka bort HTML-kommentarer ur Databasen

## #1 — Davida, 2004-01-15T08:37Z

Hej!

Jag har sparar en del HTML i en databas och när jag läser ut koden vill jag plocka bort alla kommentarer (\<!-- Här kan stå... --\>).

Hur gör jag det?

MVH
David

Permalänk: https://www.webforum.nu/p/94838

## #2 — Jesper T, 2004-01-15T08:49Z

En variant kan ju vara att låta bli att spara html i databasen.
Vad använder du det till?

Permalänk: https://www.webforum.nu/p/1252456

## #3 — Davida, 2004-01-15T08:54Z

Jag sparar vissa inställningar inom kommentaren men jag vill inte att de ska ligga i koden om man tar visa...källa

Permalänk: https://www.webforum.nu/p/1252461

## #4 — J.N., 2004-01-15T09:07Z

HEJ!

Enkelt :stud, RegExp är det som gäller! Plockar här bort html-taggar, och avslutar med ... om är fler än 250 tecken.

```
Function TaBortHTML(brodtext)
	Dim RegEx, utanhtml
	Set RegEx = New RegExp
	RegEx.Pattern = "<[^>]*>"
	RegEx.Global = True
	'utan html blir det
	utanhtml = RegEx.Replace(brodtext,"")
	if Len(utanhtml)<=250 then
		taborthtml=Trim(Replace(utanhtml, VbCrLf, ""))
	else
		if InStr(250,utanhtml," ")<>0 then
			'tar >250 tecken, till första mellanslaget, (som tas bort) efter det + ...
			taborthtml = Left(utanhtml,InStr(250,utanhtml," ")-1) & "..."
		else
			'om inte finns mellanslag efter 250 tecken
			taborthtml = utanhtml
		end if
	end if
End Function

Funktionen kallas via 
response.write TaBortHTML(RS("forklaring"))

'kod från [url]http://www.aspalliance.com/stevesmith/articles/removehtml.asp[/url]
```

Permalänk: https://www.webforum.nu/p/1252471

## #5 — Jesper T, 2004-01-15T09:33Z

Detta pattern borde funka om du endast vill plocka bort kommentarer.

```
RegEx.Pattern = "<!--[^>]*-->"
```

Permalänk: https://www.webforum.nu/p/1252496

## #6 — J.N., 2004-01-15T09:47Z

HEJ!

Ojdå, jag övertolkade \<!-- Här kan stå... --\>  till att vara \<\*\>, dvs alla taggar...

Permalänk: https://www.webforum.nu/p/1252503

## #7 — Erik Juhlin, 2004-01-15T09:50Z

```
Function RemoveComment(ByVal sHTML)
	
	Dim objRegExp
	Set objRegExp = New RegExp
	
	sHTML = Trim(sHTML & "")
	
	objRegExp.Global = True
	objRegExp.Pattern = "<!--[\s\S]*?-->"
	
	RemoveComment = objRegExp.Replace(sHTML, "")
	
	Set objRegExp = Nothing
	
End Function
```

Permalänk: https://www.webforum.nu/p/1252504

---

Tråden på webben: https://www.webforum.nu/amne/asp/94838-plocka-bort-html-kommentarer-ur-databasen