---
title: "Recordset mismatch en baggis... eeehhh!"
type: "forum-thread"
url: "https://www.webforum.nu/amne/asp/93636-recordset-mismatch-en-baggis-eeehhh"
topic: "ASP"
topic_url: "https://www.webforum.nu/amne/asp"
author: "Johanneshov"
published: "2003-12-30T09:39:18.000Z"
updated: "2003-12-30T10:13:28.000Z"
replies: 2
views: 216
page: 1
pages: 1
language: "sv-SE"
site: "webForum — webforum.nu"
rights: "Upphovsrätten till varje inlägg tillhör dess författare."
attribution: "Citera som: webForum, https://www.webforum.nu/amne/asp/93636-recordset-mismatch-en-baggis-eeehhh"
---

# Recordset mismatch en baggis... eeehhh!

## #1 — Johanneshov, 2003-12-30T09:39Z

Hi its me!  :x 

Bifogar en lång radda kod som ger felet:

ADODB.Recordset error '800a0bb9' 

Arguments are of the wrong type, are out of acceptable range, or are in conflict with one another. 

/johanneshov/anvtraning.asp, line 478 

Felraden markerad nedan... Börjar bli lite hemmablind!
Har sökt och letat men inte hittat några mismatch. Var kan felet ligga? Har debuggat bort datumanropen så dessa är det inte... :l 

```
If Request.Querystring("do")= "uppdatera" Then

Set Conn = Server.CreateObject("ADODB.Connection")
Conn.Open "driver={Microsoft Access Driver (*.mdb)}; DBQ=" & Server.MapPath("db/nyheter.mdb")
Set RecSet = Conn.Execute("SELECT * FROM traning WHERE id="& Request.Querystring("id"))%>

<td width="575" valign="top" class="text" align="center"><br><br>
<table width="400" bgcolor="silver">
<form method="post" action="anvtraning.asp?action=andra&id=<%=RecSet("id")%>" name="add">
<tr>
  <td><b>Datum:</b><br><input type="text" name="datum" value="<%=RecSet("datum")%>" size="45"></td>
  </tr>
  <tr>
    <td><b>Typ av träning:</b><br><input type="text" name="pass" value="<%=RecSet("pass")%>" size="45"></td>
  </tr>
  <tr>
    <td><b>Träningstid:</b><br><input type="text" name="tid" value="<%=RecSet("tid")%>" size="45"></td>
  </tr>
  <tr>
    <td><b>Sträcka:</b><br><input type="text" name="str" value="<%=RecSet("str")%>" size="45"></td>
  </tr>
  <tr>
    <td><b>Kommentar:</b><br><textarea cols="40" rows="5" name="kommentar"><%=RecSet("kommentar")%></textarea></td>
  </tr>
  <tr>
    <td><input type="Submit" name="andra" value="Ändra"></td>
  </tr>
</form>
</table>
</td>
<%
RecSet.Close
Set RecSet = Nothing
Conn.Close
Set Conn = Nothing

End If

If Request.Querystring("action")= "andra" Then

Set Conn	= Server.CreateObject("ADODB.Connection")
Set RecSet = Server.CreateObject("ADODB.Recordset")
Conn.Open "Driver={Microsoft Access Driver (*.mdb)}; DBQ=" & Server.MapPath("db/nyheter.mdb")

Uppdatera = "SELECT * FROM traning WHERE id= "& Request.Querystring("id") &" " 
*felrad 478!*  RecSet.Open Uppdatera, Conn, adOpenStatic, adLockOptimistic  *felrad 478!*

RecSet("datum") =  Request.Form("datum")
RecSet("pass") = Request.Form("pass")
RecSet("tid") = Request.Form("tid")
RecSet("str") = Request.Form("str")
RecSet("kommentar") = Request.Form("kommentar")

RecSet.Update
RecSet.Close
Conn.Close

Response.Redirect "anvtraning.asp?do=editera"
End If %>
```

Please help!

Permalänk: https://www.webforum.nu/p/93636

## #2 — Engine^, 2003-12-30T09:52Z

Det torde bero på att ADO inte vet vad dina konstanter är för något. Ändra *adOpenStatic* till 3 och *adLockOptimistic* till 3.

Du kan även ta och använda dig av OleDb istället för ODBC, när du ansluter till databasen.

```
[blue]'Ändra från:[/blue]
Conn.Open "Driver={Microsoft Access Driver (*.mdb)}; DBQ=" & Server.MapPath("db/nyheter.mdb")

[blue]'Till:[/blue]
Conn.Open "Provider=Microsoft.Jet.OleDb.4.0;Data Source=" & Server.MapPath("db/nyheter.mdb")
```

Permalänk: https://www.webforum.nu/p/1238574

## #3 — Johanneshov, 2003-12-30T10:13Z

Hmmm... att det skall vara så svårt ibland. Verkar som du satte huvvet på spikeb där!

TACK!

Permalänk: https://www.webforum.nu/p/1238578

---

Tråden på webben: https://www.webforum.nu/amne/asp/93636-recordset-mismatch-en-baggis-eeehhh