---
title: "[b][/b][i][/i] hurdå?"
type: "forum-thread"
url: "https://www.webforum.nu/amne/asp/92015-b-b-i-i-hurdå/page2"
topic: "ASP"
topic_url: "https://www.webforum.nu/amne/asp"
author: "M.Cheraghi"
published: "2003-12-06T16:27:45.000Z"
updated: "2003-12-12T19:36:01.000Z"
replies: 29
views: 1010
page: 2
pages: 2
language: "sv-SE"
site: "webForum — webforum.nu"
rights: "Upphovsrätten till varje inlägg tillhör dess författare."
attribution: "Citera som: webForum, https://www.webforum.nu/amne/asp/92015-b-b-i-i-hurdå"
---

# [b][/b][i][/i] hurdå?

_Sida 2 av 2._

## #21 — Cannabis_Tomten, 2003-12-11T19:08Z

Hello hejsan!

jag har nu stött på ett lite smärt problem! jag använder WF kod på min sida :P om man säger så alla förstår vad det innebär!
men när jag använder just min lilla **COLOR** funktion, så händer det absolut ingenting... 
och sedan om man använder de övriga som \[b \]\[i \]\[u \] taggarna fler gånger så blir det lite halv knas :S vissa omvandlas inte till HTML medans hälften fgör det, och d blir ingen fungerande kod på nån av alternativen =/ blir bara en stor gröt..
ni kan juhe testa för er själva

byt ut strText högst upp mot någon kul text med lite koder i å testa er fram.. jag förstår inget utav det.. en tanke som slog mej var typ nått som "For each item in" eller nån slags "loop"
eller nått liknande jaja hoppas på mysiga förslag =)

```
<%
strText = RS("profil")
strText = Server.HTMLEncode(strText)

Function ReplaceTags(strPattern, strReplace, strSource)
  Dim objRX
  Set objRX = New RegExp
  objRX.IgnoreCase = True
  objRX.Global = True
  objRX.Pattern = strPattern

  ReplaceTags = objRX.Replace(strSource, strReplace)
End Function

strText = ReplaceTags("\[b\]((.|\s)*)\[/b\]", "<b>$1</b>", strText)
strText = ReplaceTags("\[i\]((.|\s)*)\[/i\]", "<i>$1</i>", strText)
strText = ReplaceTags("\[u\]((.|\s)*)\[/u\]", "<u>$1</u>", strText)
strText = ReplaceTags("\[center\]((.|\s)*)\[/center\]", "<center>$1</center>", strText)
strText = ReplaceTags("\[img\]((.|\s)*)\[/img\]", "<IMG SRC=""$1"" border=""0"">", strText)
strText = ReplaceTags("\[url\]((.|\s)*)\[/url\]", "<a href=""$1"">$1</a>", strText)
strText = ReplaceTags("\[color=""(.*?)""\]([\s\S]*)\[/color\]", "<font color=""$1"">$2</font>", strText)
strText = replace(strText, "[br]" , "<br>")

response.write replace(strText, vbCrLf , "<br>")
%>
```

Permalänk: https://www.webforum.nu/p/1227299

## #22 — Engine^, 2003-12-11T21:51Z

Jag skulle föreslå att du just för din color-funktion skippar att använda citationstecken. Dom strular bara till det i onödan.

```
strText = ReplaceTags("\[color=(.*)\]((.|\s)*)\[/color\]", "<font color=""$1"">$2</font>", strText)
```

Permalänk: https://www.webforum.nu/p/1227401

## #23 — Cannabis_Tomten, 2003-12-11T22:44Z

> **Engine^ skrev:**
>
> Jag skulle föreslå att du just för din color-funktion skippar att använda citationstecken. Dom strular bara till det i onödan.
>
> ```
> strText = ReplaceTags("\[color=(.*)\]((.|\s)*)\[/color\]", "<font color=""$1"">$2</font>", strText)
> ```

Okej okej.. det fungerade mkt mkt bättre nu =) hehe!

men nu ere fortfarande problemet om att om jag använder Flera \[b \]\[/b \] så blire helt skevt! hur ska man lösa det?

Permalänk: https://www.webforum.nu/p/1227422

## #24 — henkz, 2003-12-12T18:38Z

Hade samma problem som dig. Klistrar in lite kod för att visa hur jag löste det.

```
Function ReplaceTags(strPattern, strReplace, om_mig)
Dim objRX
set objRX = New RegExp
objRX.IgnoreCase = True
objRX.Global = True
objRX.Pattern = strPattern
ReplaceTags = objRX.Replace(om_mig, strReplace)
End Function

om_mig = Server.HTMLEncode(om_mig)

om_mig = ReplaceTags("\[B\](.*?)\[\/B\]", "<b>$1</b>", om_mig)
om_mig = ReplaceTags("\[I\](.*?)\[\/I\]", "<i>$1</i>", om_mig)
om_mig = ReplaceTags("\[U\](.*?)\[\/U\]", "<u>$1</u>", om_mig)
om_mig = ReplaceTags("\[C\](.*?)\[\/C\]", "<center>$1</center>", om_mig)
om_mig = ReplaceTags("\[H\](.*?)\[\/H\]", "<p align='right'>$1</p>", om_mig)
om_mig = ReplaceTags("\[M=([^\]]*)\]([^\[]*)\[/M\]", "<a href='medlem.asp?id=$1'>$2</a>", om_mig)
om_mig = ReplaceTags("\[K=([^\]]*)\]([^\[]*)\[/K\]", "<a href='klubbar_visa.asp?gruppid=$1'>$2</a>", om_mig)
om_mig = ReplaceTags("\[URL\](.*?)\[\/URL\]", "<a href='http://$1' target='_blank'>$1</a>", om_mig)
om_mig = ReplaceTags("\[MAIL\]((.|\s)*)\[/MAIL\]", "<a href='mailto:$1'>$1</a>", om_mig)

om_mig = Replace(om_mig, "[br]", "<br>")
```

Permalänk: https://www.webforum.nu/p/1227818

## #25 — Cannabis_Tomten, 2003-12-12T18:40Z

hmmm... jag ser inte direkt nån större skillnad??

Permalänk: https://www.webforum.nu/p/1227820

## #26 — henkz, 2003-12-12T18:41Z

testa att köra så ser du skillnaden att du kan använda te.x flera

Permalänk: https://www.webforum.nu/p/1227821

## #27 — Cannabis_Tomten, 2003-12-12T18:46Z

okej.. men vjag ser ingen skilnad i koden :S jag som e blind.. kan du förklara lite kring det hela? =)

Permalänk: https://www.webforum.nu/p/1227822

## #28 — henkz, 2003-12-12T18:53Z

Om du jämför de båda koderna ser du förändrigarna, det gör att du kan använda fler  m.fl utan att det blir fel vid presentationen.

```
strText = ReplaceTags("\[b\]((.|\s)*)\[/b\]", "<b>$1</b>", strText)
```

```
strText = ReplaceTags("\[b\](.*?)\[\/b\]", "<b>$1</b>", strText)
```

Permalänk: https://www.webforum.nu/p/1227828

## #29 — Cannabis_Tomten, 2003-12-12T18:58Z

ahh =) okej nu förstod jag! tack såmkt för ditt svar!

Permalänk: https://www.webforum.nu/p/1227833

## #30 — Asa, 2003-12-12T19:36Z

HAr denna kod på Chippiland som gör om diverse forumkod. Inte för att det kanske är nån hjälp men iallafall!

```
<%Function Code(strText)
   strText = Server.HTMLEncode(strText)

   Set regExp = New regexp

   regExp.Global = true
   regExp.IgnoreCase = true

   regExp.Pattern = "([url]ftp://[/url])([\S]*)"
   strText = regExp.Replace(strText,"<a href=""$1$2"" target=""_blank"">$1$2</a> ")

   regExp.Pattern = "([\S]*@[\S]*[.se|.com|.nu|.net|.org])"
   strText = regExp.Replace(strText,"<a href=""mailto:$1"">$1</a> ")

   regExp.Pattern = "\[color=(.*?)\]"
   strText = regExp.Replace(strText,"<font color=""$1"">")

   regExp.Pattern = "(\[\/color\])"
   strText = regExp.Replace(strText,"</font>")

   regExp.Pattern = "\[img](.*)\[/img\]" 
   strText = regExp.Replace(strText, "<img src=""$1""> ")

   regExp.Pattern = "\[(b|/b|i|/i|u|/u|center|/center)\]" 
   strText = regExp.Replace(strText,"<$1>")

   regExp.Pattern = "(\[hr\])"
   strText = regExp.Replace(strText,"<hr noshade size=""1""> ")

   regExp.Pattern = "\[url](.*)\[/url\]" 
   strText = regExp.Replace(strText, "<a href=""$1"" target=""_blank"">$1</a> ")

   regExp.Pattern = "\[url=(.*?)\](.*)\[/url\]" 
   strText = regExp.Replace(strText, "<a href=""$1"" target=""_blank"">$2</a> ")

   Code = strText
End Function%>
```

Permalänk: https://www.webforum.nu/p/1227840

---

Tråden på webben: https://www.webforum.nu/amne/asp/92015-b-b-i-i-hurdå/page2  
Föregående sida: https://www.webforum.nu/amne/asp/92015-b-b-i-i-hurdå.md