Fotodagbok, databas?

En tabell räcker gott :)

Det där med att visa alla bilder inkl. kommentar från just ett datum går förstås. Du behöver dock ett datumfält som lagrar datumet då du lade till posten.

Så som du skriver nu går det nog inte (eller jo, det går, men det blir en massa krångel ;)). Det blir alltså lättare om man infogar datum i Querystring:en i stället, ex. visadag.asp?dtm=2003-10-01. För hur ska den annars veta från vilka poster som du vill få ut? ;)

Jag menade om man hade ett unikt ID för alla datum, men det går ju lika bra som du skriver "visadag.asp?dtm=2003-10-01".

Fälten i databasen:
Datum Bild1 Text1 Bild2 Text2 etc..

Eller?

En annan sak!
Om jag bara vill visa en bild i taget, och ha en länk "nästa bild" och "föregående bild" då?
På visadag.asp?dtm=xxxx-xx-xx alltså...

Det bästa sättet att bygga upp databasen på borde väl bara såhär:

ID    Datum       Bild        Text
__________________________________

1     2003-02-13  bild1.jpg   Min cykel
2     2003-02-13  bild2.jpg   Min bil
3     2003-03-19  bild3.jpg   Min sommarstuga

Osv...

Okej, ska testa.
:)

Suck.
Skulle nån vilja vara snäll och hjälpa mig?
Jag vet inte hur jag ska skriva för att visa bilderna på sidan!

"visadag.asp?dtm=2003-10-31"

Tabellen ser ut som Sebbe skrev ovan...

För det första vill jag få ut alla bilder från det datumet, och för det andra vill jag visa en i taget, paging alltså.

If Request.QueryString("page") = "" OR NOT IsNumeric(Request.QueryString("page")) Then
  intPage = 1
Else
  intPage = CInt(Request.QueryString("page"))
End If

If Request.QueryString("dtm") = "" OR NOT IsDate(Request.QueryString("dtm")) Then
  dtmDate = Date()
Else
  dtmDate = CDate(Request.QueryString("dtm"))
End If

Set objConn = Server.CreateObject("ADODB.Connection")
objConn.Open "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & Server.MapPath("[i]databas.mdb[/i]")
strSQL = "SELECT * FROM [i]tabell[/i] WHERE datum = #" & dtmDate & "# ORDER BY id"
Set objRS = Server.CreateObject("ADODB.Recordset")

With objRS
  .Open strSQL, objConn, 1, 3
  .PageSize = 1
End With

If NOT objRS.EOF Then
  objRS.AbsolutePage = intPage
  Response.Write("<img src=""" & objRS("bild") & """><br>" & objRS("text") & vbCrLf)

  If objRS.PageCount > 1 Then
    Response.Write("<br>" & vbCrLf)

    For i = 1 To objRS.PageCount
      If i <> intPage Then
        Response.Write("<a href=""?dtm=" & dtmDate & "&page=" & i & """>" & i & "</a> " & vbCrLf)
      Else
        Response.Write(i & " " & vbCrLf)
      End If
    Next
  End If
End If

objRS.Close : Set objRS = Nothing
objConn.Close : Set objConn = Nothing

För att plocka ut en unik bild så är det bara att plocka fram ett unikt ID ur databasen. För att plocka ut alla bilder från just ett datum då de lades in så är det bara att att plocka ut poster som har just det datumet i fältet datum. (Se sebbes exempelkod)

Det fungerar bra!
Tack, jag återkommer säkert om (när) jag får problem...
:)

Varför blir det "visadag.asp?dtm=10/31/2003" och inte "visadag.asp?dtm=10-31-2003"?

Lägg till

Session.LCID = 1053

överst på sidan.

Ok!