---
title: "öppna i rätt frame"
type: "forum-thread"
url: "https://www.webforum.nu/amne/asp/86553-öppna-i-rätt-frame"
topic: "ASP"
topic_url: "https://www.webforum.nu/amne/asp"
author: "aDay"
published: "2003-09-21T11:20:39.000Z"
updated: "2003-09-21T11:22:10.000Z"
replies: 1
views: 164
page: 1
pages: 1
language: "sv-SE"
site: "webForum — webforum.nu"
rights: "Upphovsrätten till varje inlägg tillhör dess författare."
attribution: "Citera som: webForum, https://www.webforum.nu/amne/asp/86553-öppna-i-rätt-frame"
---

# öppna i rätt frame

## #1 — aDay, 2003-09-21T11:20Z

hur ska jag få länke på rad 58 att öppnas i "main", använder alltså frames...

```
%>

<table cellpadding="3" cellspacing="1" width="130">
 <tr>
  <td align="center" height="15">Senaste foruminlägg</td>
 </tr>
 <tr>
  <td width="33%" align="center" nowrap height="25">
<%
Dim rsLastestPostsMod
Dim adoLastestPostsModCon
Dim strLastestPostsModCon
Dim strSQLLastsPostsMod
Dim strLastestPostsModTopicSubject
Dim strMembersModForumPath

'The path to the forum
strMembersModForumPath = "../forum/"

'Database connection
'-----------------------------
'-----------------------------

'Default connection
strLastestPostsModCon = "DRIVER={Microsoft Access Driver (*.mdb)}; DBQ=" & Server.MapPath("admin/database/wwforum.mdb")

'Uncomment for a full phsyical path. Then change the path
'strLastestPostsModCon = "DRIVER={Microsoft Access Driver (*.mdb)}; DBQ=http://www.project15.org/scripts/webwizforum/forum/admin/database/wwforum.mdb"

'Uncomment for a DSN connection
'strLastestPostsModCon = "DSN=DSN_NAME"

'-----------------------------
'-----------------------------

Set adoLastestPostsModCon = Server.CreateObject("ADODB.Connection")
adoLastestPostsModCon.Open strLastestPostsModCon

Set rsLastestPostsMod = Server.CreateObject("ADODB.Recordset")

strSQLLastsPostsMod = "SELECT Top 2 tblTopic.Topic_ID, tblTopic.Subject, tblForum.Forum_ID "
strSQLLastsPostsMod = strSQLLastsPostsMod & "FROM tblForum INNER JOIN tblTopic ON tblForum.Forum_ID = tblTopic.Forum_ID "
strSQLLastsPostsMod = strSQLLastsPostsMod & "WHERE ((tblForum.Password) Is Null) "
strSQLLastsPostsMod = strSQLLastsPostsMod & "ORDER BY tblTopic.Last_entry_date DESC;"

rsLastestPostsMod.Open strSQLLastsPostsMod, adoLastestPostsModCon

If rsLastestPostsMod.EOF Then
	Response.Write "<span class=""smltext"">No Forum Posts Made</span>"
Else
	Do while NOT rsLastestPostsMod.EOF
		If len(rsLastestPostsMod("Subject")) > 18 then
			strLastestPostsModTopicSubject = left(rsLastestPostsMod("Subject"),18) & "...&nbsp;"
		Else
			strLastestPostsModTopicSubject = rsLastestPostsMod("Subject")
		End If

		Response.Write("<a href=""" & strMembersModForumPath & "forum_posts.asp?TID=" & rsLastestPostsMod("Topic_ID") & "&PN=1"">" & strLastestPostsModTopicSubject & "</a>")

	rsLastestPostsMod.MoveNext
	If NOT rsLastestPostsMod.EOF Then Response.Write("<br>")
	Loop
End If

'Reset Server Objects
rsLastestPostsMod.Close
Set rsLastestPostsMod = Nothing
adoLastestPostsModCon.Close
Set adoLastestPostsModCon = Nothing
%></td>
 </tr>
</table>
```

Permalänk: https://www.webforum.nu/p/86553

## #2 — @nders, 2003-09-21T11:22Z

Är detta rad 58?

```
Response.Write("<a href=""" & strMembersModForumPath & "forum_posts.asp?TID=" & rsLastestPostsMod("Topic_ID") & "&PN=1"">" & strLastestPostsModTopicSubject & "</a>")
```

I så fall, lägg till target i länken.

```
Response.Write("<a href=""" & strMembersModForumPath & "forum_posts.asp?TID=" & rsLastestPostsMod("Topic_ID") & "&PN=1"" target=""main"">" & strLastestPostsModTopicSubject & "</a>")
```

Permalänk: https://www.webforum.nu/p/1163504

---

Tråden på webben: https://www.webforum.nu/amne/asp/86553-öppna-i-rätt-frame