---
title: "Server.createobject FAILED \"MAPI\""
type: "forum-thread"
url: "https://www.webforum.nu/amne/asp/85642-server-createobject-failed-mapi"
topic: "ASP"
topic_url: "https://www.webforum.nu/amne/asp"
author: "SteveP"
published: "2003-09-10T10:07:41.000Z"
updated: "2003-09-10T10:10:37.000Z"
replies: 1
views: 154
page: 1
pages: 1
language: "sv-SE"
site: "webForum — webforum.nu"
rights: "Upphovsrätten till varje inlägg tillhör dess författare."
attribution: "Citera som: webForum, https://www.webforum.nu/amne/asp/85642-server-createobject-failed-mapi"
---

# Server.createobject FAILED "MAPI"

## #1 — SteveP, 2003-09-10T10:07Z

Jag försöker skriva ut innehållet ur public folders på en exchange server, men får detta felet.

Server.CreateObject Failed 

line 28 

Invalid ProgID. 

Det är "Set objSession = Server.CreateObject("MAPI.Session")" som inte går att skapa. Har detta med rättigheter att göra?

Och vad exakt är MAPI inom exchange server ?

```
<%
  CONST strServer     = "xxxxxxx"
  CONST strMailbox    = "xxxxxxxx"
  Dim objSession
  Dim objMessages
  Dim objOneMessage
  Dim objInfoStores
  Dim objInfoStore
  Dim objTopFolder
  Dim objFolders
  Dim objSubFolder
  Dim objTargetFolder
  Dim strProfileInfo
  Dim i
  Dim bstrPublicRootID

  strProfileInfo = strServer & vblf & strMailbox
  [b]Set objSession = Server.CreateObject("MAPI.Session")[/b]
  objSession.Logon , , , False, , True, strProfileInfo
  Set objInfoStores = objSession.InfoStores
  For i = 1 To objInfoStores.Count
     If objInfoStores.Item(i)= "Public Folders" Then
        Set objInfoStore=objInfoStores.Item(i)
        Exit For
     End If
  Next

  bstrPublicRootID = objInfoStore.Fields.Item( &H66310102 ).Value
  Set objTopFolder = objSession.GetFolder(bstrPublicRootID, _
                     objInfoStore.ID)
  Set objFolders = objTopFolder.Folders
  Set objFolder = objFolders.GetFirst()
   Do Until objFolder.Name = "Internet Newsgroups"
     Set objFolder=objFolders.GetNext()
  Loop
  Set objMessages = objFolder.Messages
  For Each objOneMessage in objMessages
     Response.Write("objOneMessage.Subject = " & _
                    objOneMessage.Subject & "<br>")
     Response.Write("objOneMessage.Text = " & _
                    objOneMessage.Text & "<br>")
  Next
   objSession.Logoff
  Set objOneMessage = Nothing
  Set objMessages = Nothing
  Set objFolder = Nothing
  Set objTopFolder = Nothing
  Set objSession = Nothing
%>
```

Permalänk: https://www.webforum.nu/p/85642

## #2 — SteveP, 2003-09-10T10:10Z

Jag hade tydligen inte nog med rättigheter för att köra mapi objectet. Fick stänga av anonymous authentication och ändra lite rättigheter.

Permalänk: https://www.webforum.nu/p/1154168

---

Tråden på webben: https://www.webforum.nu/amne/asp/85642-server-createobject-failed-mapi