---
title: "Hämta med radbrytning från Databas"
type: "forum-thread"
url: "https://www.webforum.nu/amne/asp/8130-hämta-med-radbrytning-från-databas"
topic: "ASP"
topic_url: "https://www.webforum.nu/amne/asp"
author: "Bjarne A"
published: "2001-02-13T18:22:00.000Z"
updated: "2001-02-13T19:48:00.000Z"
replies: 3
views: 335
page: 1
pages: 1
language: "sv-SE"
site: "webForum — webforum.nu"
rights: "Upphovsrätten till varje inlägg tillhör dess författare."
attribution: "Citera som: webForum, https://www.webforum.nu/amne/asp/8130-hämta-med-radbrytning-från-databas"
---

# Hämta med radbrytning från Databas

## #1 — Bjarne A, 2001-02-13T18:22Z

Jag har läst tidigare inlägg och försökt att fixa till så att radbrytningarna kommer med vid hämtning av text från en databas 
Men det vill sig inte 
koden nedan har jag inte skrivit själv utan modifierat från kod från en gästbok 
(jag vill nämligen bara ha en textruta och har tagit bort namnruta, e-post, möjlighet att ta bort meddelanden mm .....) 

Tacksam från hjälp från någon som kan
 

```
<!--#INCLUDE FILE="installningar.asp"--> 
<html> 
<head> 
<title>Info-sidan</title> 

</head> 
<body bgcolor="#FFFFFF" text="#000000"> 
<p> 
<font face="Verdana, Arial, Helvetica, sans-serif" color="#000000" size="2">Information:<br> 
<br> 
<%       
             
Dim CONN_STRING 
CONN_STRING = "DBQ=" & Server.MapPath(d_base) & ";" 
CONN_STRING = CONN_STRING & "Driver={Microsoft Access Driver (*.mdb)};" 

Dim iPageSize 
Dim iPageCount 
Dim iPageCurrent 
Dim strOrderBy 
Dim strSQL 
Dim objPagingConn 
Dim objPagingRS 
Dim iRecordsShown 
Dim I 

iPageSize = Msg_a_page 
strSQL = "SELECT * FROM gaster ORDER BY id DESC" 

Set objPagingConn = Server.CreateObject("ADODB.Connection") 
objPagingConn.Open CONN_STRING, CONN_USER, CONN_PASS 

Set objPagingRS = Server.CreateObject("ADODB.Recordset") 
objPagingRS.PageSize = iPageSize 
objPagingRS.CacheSize = iPageSize 

objPagingRS.Open strSQL, objPagingConn, 3, 1, adCmdText 

countinlagg = 0 
DO UNTIL objPagingRS.EOF 
countinlagg = countinlagg + 1 
objPagingRS.MoveNext 
LOOP 
objPagingRS.MoveFirst 

iPageCount = objPagingRS.PageCount 

If iPageCurrent > iPageCount Then iPageCurrent = iPageCount 
If iPageCurrent < 1 Then iPageCurrent = 1 

If iPageCount = 0 Then 
Response.Write txt_nomatch 
Else 
objPagingRS.AbsolutePage = iPageCurrent 
    
   %> <% 
   iRecordsShown = 0 
   Do While iRecordsShown < iPageSize And Not objPagingRS.EOF 
%> <%=Server.HTMLEncode(objPagingRS("text"))%> 
<HR> 
<BR> 
<% 
      iRecordsShown = iRecordsShown + 1 
      objPagingRS.MoveNext 
   Loop 
End If 

objPagingRS.Close 
Set objPagingRS = Nothing 
objPagingConn.Close 
Set objPagingConn = Nothing 

%> </font> 
</body> 
</html>
```

Permalänk: https://www.webforum.nu/p/8130

## #2 — @nders, 2001-02-13T18:36Z

byt

```
<%=Server.HTMLEncode(objPagingRS("text"))%>
```

mot 

```
<%=Replace(objPagingRS("text"), vbcrlf, "<br>")%>
```

eller om du verkligen vill ha htmlencoding

```
<%=replace(Server.HTMLEncode(objPagingRS("text")), vbcrlf, "<br>")%>
```

mvh,

Permalänk: https://www.webforum.nu/p/259114

## #3 — @nders, 2001-02-13T18:41Z

förresten, glömde nästan:

**välkommen till webforum**!!! :)

Permalänk: https://www.webforum.nu/p/259115

## #4 — Bjarne A, 2001-02-13T19:48Z

Tack!
Funkade (givetvis) perfekt
Och tack för välkomnandet

Permalänk: https://www.webforum.nu/p/259116

---

Tråden på webben: https://www.webforum.nu/amne/asp/8130-hämta-med-radbrytning-från-databas