---
title: "Paging igen"
type: "forum-thread"
url: "https://www.webforum.nu/amne/asp/80602-paging-igen"
topic: "ASP"
topic_url: "https://www.webforum.nu/amne/asp"
author: "web00132"
published: "2003-06-25T18:25:09.000Z"
updated: "2003-06-26T09:20:50.000Z"
replies: 2
views: 212
page: 1
pages: 1
language: "sv-SE"
site: "webForum — webforum.nu"
rights: "Upphovsrätten till varje inlägg tillhör dess författare."
attribution: "Citera som: webForum, https://www.webforum.nu/amne/asp/80602-paging-igen"
---

# Paging igen

## #1 — web00132, 2003-06-25T18:25Z

Har fastnat med lite paging-problem. Jag har 13 inlägg i min databas. Om jag sätter att den ska skriva ut 11 inlägg per sida så skriver den ut 10 på första sidan och 2 på nästa sida. Ett försvinner alltså spårlöst ut i webbrymden.

Jag tog mitt pagingscript från någon wF:are för länge sen men hittar inte det inlägget nu.
Högst upp i koden står... 

```
<%
dim intStart, strStart, intPage, intPageSize
strStart = Request.QueryString("strStart")
intPage = Request.QueryString("Page")
intPageSize = 11
if intPage = "" then intPage = 1 end if
%>
```

 ...i mitten av koden står... 

```
<table border="0" width="550" bgcolor="#eeeeee" cellpadding="3" cellspacing="0" class="table" ID="Table2">
		<% dim rsitems, sqlopen
		set rsitems = server.createobject("ADODB.Recordset")
		if strStart <> "" then
			sqlopen = "SELECT * FROM kunder WHERE efternamn LIKE '" & strStart & "%' ORDER BY efternamn;"
		else
			sqlopen = "SELECT * FROM kunder ORDER BY efternamn;"
		end if
		
		rsitems.PageSize = intPageSize
		rsitems.Open sqlopen, objConn, 3, 1, adLockReadOnly
		
		If rsitems.EOF Then
			Response.Write "<br><br>No results<br><br>"
		Else
			rsitems.AbsolutePage = intPage
			intTotalPages = rsitems.PageCount
			
			dim intCounter, intAntal
			intCounter = 1

			'## -- lista alla inlägg som finns i db --
			Do Until rsitems.EOF or intCounter >= intPageSize
			valuebgcolor = "#cccccc"
			if intCounter Mod 2 then valuebgcolor = "#dddddd"
			%>
				<tr border="1">
					<td bgcolor="<%= valuebgcolor %>" width="5">
					</td>
					<td bgcolor="<%= valuebgcolor %>" width="150">
					<a href="#" onClick="JavaScript:PopWindow938658(<%= rsitems("kundid")%>)">
					<b><%= rsitems("efternamn") %>, <%= rsitems("fornamn") %></b></a>
					</td>
					<td bgcolor="<%= valuebgcolor %>" width="130">
					Telenr: <%= rsitems("telenr")%>
					</td>
					<td bgcolor="<%= valuebgcolor %>" width="130">
					Mobil: <%= rsitems("mobil")%>
					</td>
					<% if session("email") = "admin" then %>
					<td bgcolor="<%= valuebgcolor %>" width="100">
					<a href="default.asp?action=edititem&item=<%= rsitems("itemid") %>&genre=<%= strgenre %>">Edit/Delete</a>
					</td>
					<% end if %>
				</tr>
			<%
			intCounter = intCounter + 1	
			rsitems.MoveNext
			loop
		end if
		rsitems.close
		set rsitems = nothing
		
		objConn.close
		set objConn = nothing
		%>
		</table>
		<br />
		<table border="0" width="100%" bgcolor="#eeeeee" cellpadding="3" cellspacing="0">
			<tr>
				<td colspan="4" align="center">
				<% call PageNavigation(intPage, intTotalPages) %>
				</td>
			</tr>
		</table>">
```

 ...och i slutet av koden...

```
<%
'## -- skapa sid-navigering --
Sub PageNavigation(ByVal WhichPage, ByVal HowManyPages)
	Dim strScriptName
	Dim I
	
	'## -- vilken sida ska navigeringen länka till --
	strScriptName = Request.ServerVariables("SCRIPT_NAME")
	
	'## -- visa föregående, länkat eller olänkat beroende på vilken sida som visas --
	If CInt(WhichPage) > 1 Then
		Response.Write "<a href='" & strScriptName & "?" & "page=" & WhichPage - 1 & "&genre=" & strGenre & "'><< Previous</a> "
	Else
		Response.Write "<< Previous "
	End If
	
	'## -- lista ut alla sidnummer --
	For I = 1 To HowManyPages
		If CInt(WhichPage) <> I Then
			Response.Write "<a href='" & strScriptName & "?" & "page=" & I & "&genre=" & strGenre & "'>" & I & "</a> "
		Else
			Response.Write "[ <b>" & I & "</b> ] "
		End If
	Next
	
	'## -- visa Nästa, länkad eller olänkad beroende på vilken sida som visas --
	If CInt(WhichPage) < CInt(HowManyPages) Then
		Response.Write "<a href='" & strScriptName & "?" & "page=" & WhichPage + 1 & "&genre=" & strGenre & "'>Next >>"
	Else
		Response.Write "Next >>"
	End If
	
End Sub
%>
```

 Tack på förhand!  :bire

Permalänk: https://www.webforum.nu/p/80602

## #2 — PatrikB, 2003-06-25T19:26Z

Tror att du behöver ändra: intCounter = 1 till intCounter = 0 

... scriptet ser bekant ut ;) ...

cya,
PatrikB

Permalänk: https://www.webforum.nu/p/1092801

## #3 — web00132, 2003-06-26T09:20Z

Utmärkt! Man kan ju nästan tro att det är du som har kodat  :birp

Permalänk: https://www.webforum.nu/p/1096040

---

Tråden på webben: https://www.webforum.nu/amne/asp/80602-paging-igen