---
title: "xmlhttp"
type: "forum-thread"
url: "https://www.webforum.nu/amne/asp/71240-xmlhttp"
topic: "ASP"
topic_url: "https://www.webforum.nu/amne/asp"
author: "jboy_87"
published: "2003-03-16T16:04:16.000Z"
updated: "2003-03-17T22:27:40.000Z"
replies: 9
views: 491
page: 1
pages: 1
language: "sv-SE"
site: "webForum — webforum.nu"
rights: "Upphovsrätten till varje inlägg tillhör dess författare."
attribution: "Citera som: webForum, https://www.webforum.nu/amne/asp/71240-xmlhttp"
---

# xmlhttp

## #1 — jboy_87, 2003-03-16T16:04Z

hejsan vill hämta ut bara texten i horoskop sidan hur gör jag det? nu ser min kod ut såhär:

```
<% 
Function redigera(strText) 
strText = replace(strtext,"<CENTER>","</CENTER>")

redigera = strText
End Function

Set objHTTP = Server.CreateObject("Microsoft.XMLHTTP")
objHTTP.Open "GET","http://zodiaken.net/cgi-bin/dagens.pl?id=5", False

objHTTP.Send
strHTML=objHTTP.responseText
Set objHTTP = Nothing

Set objRegExp = New regexp
objRegExp.Global = false
objRegExp.IgnoreCase = true
objRegExp.Pattern = "<CENTER>(.*)</CENTER>"
Set hittade = objRegExp.Execute(strHTML)

For each item in hittade

Response.Write redigera(item.value)
Response.Write strhtml

Next%>
```

Permalänk: https://www.webforum.nu/p/71240

## #2 — jboy_87, 2003-03-17T11:17Z

sidan = <http://zodiaken.net/cgi-bin/dagens.pl?id=5>

Permalänk: https://www.webforum.nu/p/982267

## #3 — solbulle, 2003-03-17T12:17Z

Kanske en lite onödigt avancerad lösning, men den fungerar.
I din kod resp. sidans källa kan jag inte se var du finner dina "CENTER" ?

För övrigt så förstår jag inte varför ovanstående kod sällan fungerar med ett regexp så där? Någon som vet?
Det har varit tre trådar med snarlika problem den senaste helgen?

```
<BODY bgcolor="#000000" TEXT=#BCB59B >
<img src="http://zodiaken.net/bild/zc1.jpg"  WIDTH=130 HEIGHT=130 border="0" alt="">
<%
'© solbulle 13:14 2003-03-17
Response.Charset="ISO8859-1"
Response.ContentType="text/html"

Set objHTTP = Server.CreateObject("Microsoft.XMLHTTP")
objHTTP.Open "GET", "http://zodiaken.net/cgi-bin/dagens.pl?id=5", False

objHTTP.setRequestHeader "Content-Type", "text/xml; charset=utf-8"

objHTTP.Send
'strHTML=objHTTP.responseText

strHTML = BinToText(objHTTP.responseBody,35000)

Set objHTTP = Nothing

Set RegEx = New RegExp
RegEx.Global = True
RegEx.Pattern = "<TABLE WIDTH=80%"&"><TR><TD>"
strHTML= RegEx.Replace(strHTML,( chr(253) ))
RegEx.Pattern = "</TD></TR></TABLE>"
strHTML= RegEx.Replace(strHTML,( chr(254) ))
RegEx.Pattern = chr(253) & "[^" & chr(254) & "]*" & chr(254)
Set strOut = RegEx.execute(strHTML)

Function rensa(strHtml)
Set RegEx = New RegExp
RegEx.Global = True

RegEx.pattern = "(\n)"
strHtml = RegEx.replace(strHtml, " ")

Set RegEx = Nothing

strHtml = Replace(strHtml,chr(253)," ")
strHtml = Replace(strHtml,chr(254)," ")

set r = new regexp
r.ignorecase = true
r.global = true
r.pattern = "(\<a.*?\<\/a\>)"
rensa = trim(r.replace(strHtml,""))

End Function

function BinToText(varBinData, intDataSizeInBytes)
  const adFldLong = 128
  const adVarChar = 200
  set objRS = Server.CreateObject("ADODB.Recordset")
  
  objRS.Fields.Append "txt", adVarChar, intDataSizeInBytes, adFldLong
  objRS.Open
  
  objRS.AddNew
  objRS.Fields("txt").AppendChunk(varBinData)
  tmp = objRS("txt").Value
  objRS.Close
  BinToText = tmp
end function

If strOut.count > 0 then
	response.write "<p>" 
	response.write "Horoskop:<br> " & rensa(strOut.Item(0)) & "<br>" & vbcrlf
Else
	Response.write "Tyvärr inget horoskop."
End If
%>
```

Permalänk: https://www.webforum.nu/p/982305

## #4 — jboy_87, 2003-03-17T12:41Z

sjyst  :e

Permalänk: https://www.webforum.nu/p/982320

## #5 — solbulle, 2003-03-17T12:48Z

[Version 1](http://www.solbulle.com/wf/jboy_87/index2.asp) 
[Version 2](http://www.solbulle.com/wf/jboy_87/index.asp)

Permalänk: https://www.webforum.nu/p/982328

## #6 — jboy_87, 2003-03-17T13:14Z

jävligt snyggt asså!!

Permalänk: https://www.webforum.nu/p/982351

## #7 — Jesper T, 2003-03-17T13:38Z

> **Solbulle skrev:**
>
> I din kod resp. sidans källa kan jag inte se var du finner dina "CENTER" ?

 ;)

Bilagor:

- [center.gif](https://www.webforum.nu/a/1176.gif)

Permalänk: https://www.webforum.nu/p/982384

## #8 — solbulle, 2003-03-17T13:51Z

Åfan!  :e 

He he, jag såg dom faktist inte. Var så inriktad på att det bara var "texten" som skulle plockas ut.  :r

Permalänk: https://www.webforum.nu/p/982396

## #9 — jboy_87, 2003-03-17T14:06Z

Jesper T\> Coola pekfingrar!

Permalänk: https://www.webforum.nu/p/982406

## #10 — ulsy, 2003-03-17T22:27Z

.

Permalänk: https://www.webforum.nu/p/982813

---

Tråden på webben: https://www.webforum.nu/amne/asp/71240-xmlhttp