---
title: "Byta namn i mapp"
type: "forum-thread"
url: "https://www.webforum.nu/amne/asp/71106-byta-namn-i-mapp"
topic: "ASP"
topic_url: "https://www.webforum.nu/amne/asp"
author: "AG"
published: "2003-03-14T16:31:06.000Z"
updated: "2003-03-14T22:56:39.000Z"
replies: 1
views: 231
page: 1
pages: 1
language: "sv-SE"
site: "webForum — webforum.nu"
rights: "Upphovsrätten till varje inlägg tillhör dess författare."
attribution: "Citera som: webForum, https://www.webforum.nu/amne/asp/71106-byta-namn-i-mapp"
---

# Byta namn i mapp

## #1 — AG, 2003-03-14T16:31Z

Skulle behöva ha hjälp med några rader kod.
Behöver en kodsnutt som döper om alla filer i en mapp.
Filerna är i .jpg format. Alla bokstäver skall vara stora. " " skall bytas ut mot "-" och å,ä,ö skall ersättas med a,a,o.
Behöver hjälp med detta, annars får jag sitta och manuellt ändra varje filnamn.

Andreas

Permalänk: https://www.webforum.nu/p/71106

## #2 — Palle, 2003-03-14T22:56Z

Här är en variant som gör följande:

1. Hämtar alla jpg-bilderna i mappen där scriptet ligger
2. Skapar en ny mapp, i den aktuella mappen, som heter kopia
3. Byter namn på bilderna enligt dina önskemål och sparar dem i den nya mappen (kopia)
4. Raderar de gamla bilderna. Vill du inte radera de gamla bilderna kan du kommentera bort raden *objFSO.DeleteFile Server.MapPath(objFileItem.Name)*

```
[RED]<%

'// Funktion som fixar det nya filnamnet
Function fixName(str)
	str = trim(str)
	If Len(str) > 0 Then
		str = Replace(str, " ", "-")
		str = Replace(str, "å", "a")
		str = Replace(str, "ä", "a")
		str = Replace(str, "ö", "o")
		fixName = str
	End If
End Function

'// Hämta alla jpg-bilderna i mappen och döp om dem
Set objFSO = Server.CreateObject("Scripting.FileSystemObject")
Set objFile = objFSO.GetFile(Server.MapPath(Request.ServerVariables("PATH_INFO")))
Set objFolder = objFile.ParentFolder
Set objFolderContents = objFolder.Files 

	For Each objFileItem in objFolderContents
		If UCase(Right(objFileItem.Name,3)) = "JPG" Then
			If NOT objFSO.FolderExists(objFile.ParentFolder &"/kopia") Then objFSO.CreateFolder(objFile.ParentFolder &"/kopia")
			objFSO.CopyFile Server.MapPath(objFileItem.Name),Server.MapPath("kopia/"& UCase(fixName(objFileItem.Name)))
			objFSO.DeleteFile Server.MapPath(objFileItem.Name)
		End If
	Next

Set objFSO = Nothing
Set objFile = Nothing
Set objFolder = Nothing
Set objFolderContents = Nothing

Response.Write "Klart!"

%>[/RED]
```

Hoppas det fungerar som du tänkt dig. :)

Permalänk: https://www.webforum.nu/p/978168

---

Tråden på webben: https://www.webforum.nu/amne/asp/71106-byta-namn-i-mapp