---
title: "Recordset uppdelning."
type: "forum-thread"
url: "https://www.webforum.nu/amne/asp/7071-recordset-uppdelning"
topic: "ASP"
topic_url: "https://www.webforum.nu/amne/asp"
author: "cgi"
published: "2000-11-07T01:00:00.000Z"
updated: "2000-11-09T13:23:00.000Z"
replies: 16
views: 254
page: 1
pages: 1
language: "sv-SE"
site: "webForum — webforum.nu"
rights: "Upphovsrätten till varje inlägg tillhör dess författare."
attribution: "Citera som: webForum, https://www.webforum.nu/amne/asp/7071-recordset-uppdelning"
---

# Recordset uppdelning.

## #1 — cgi, 2000-11-07T01:00Z

Hello, sitter med en kod här som jag inte riktigt får igång, tänkte höra om någon här kanske kan se någon fel i den.

```
<%
persida = 5
For n = 1 to RS.recordcount step persida
IF n <> 1 then response.write " "
%>
<a href="gbok.asp?visa=<%=n%>"><%=n%> 
till 
<% If n + persida <=RS.recordcount then%><%=n + (persida -1)%>
<%else%>
<%=RS.recordcount%>
<%end if %>
</a>
<% next %>
<br> 
</p>
<%if RS.eof then
RS.close
set RS = nothing
else
if request("visa") = "" then
visa = 1
else
visa = Request("visa")
end if
RS.move visa -1
for row = visa to visa + (persida -1)
if RS.eof then exit for
%> 
<%=RS("tabell")%>
<% 
RS.MoveNext
next 
end if
%>
<%
End If
%>
```

jag får inte upp något felmeddelande, utan sidorna vill bara inte delas upp.

Permalänk: https://www.webforum.nu/p/7071

## #2 — cgi, 2000-11-07T17:42Z

Ingen som kan detta.??

Permalänk: https://www.webforum.nu/p/251700

## #3 — emission, 2000-11-07T17:57Z

Jådå, men du har en alldeles utmärkt fungerande version i FAQn

mvh

Permalänk: https://www.webforum.nu/p/251701

## #4 — cgi, 2000-11-07T19:46Z

Jovisst funkar den bra, men nu vill jag ha igång den här, du kan inte säga var felet ligger.
Mycket tacksam för hjälp.

Permalänk: https://www.webforum.nu/p/251702

## #5 — PatrikB, 2000-11-07T21:27Z

Hello,

vad är det som är fel? får du några felmeddelanden eller är det pagingen som ej bryter upp i olika sidor?

cya,

Permalänk: https://www.webforum.nu/p/251703

## #6 — cgi, 2000-11-07T21:35Z

Endast de 5 första inläggen printas ut utan att sidorna delas upp.

Permalänk: https://www.webforum.nu/p/251704

## #7 — PatrikB, 2000-11-07T23:03Z

Hello,
\[r\]
Såg fel ....
\[/r\]
cya,

Permalänk: https://www.webforum.nu/p/251705

## #8 — cgi, 2000-11-07T23:17Z

Kan du förklara lite närmare vad du menar.

Permalänk: https://www.webforum.nu/p/251706

## #9 — PatrikB, 2000-11-08T06:54Z

Hello igen,

undrar hur du öppnar recordsetet på för vis?
cya,

Permalänk: https://www.webforum.nu/p/251707

## #10 — cgi, 2000-11-08T13:18Z

Så här:

```
Set Databas = Server.CreateObject("ADODB.Connection")
Databas.Open "DSN=xxx-databas;Password=xxx"
```

Permalänk: https://www.webforum.nu/p/251708

## #11 — PatrikB, 2000-11-08T15:23Z

Hello,

Det är databaskontakten, det jag menade var om du kör:

Set rs = Databas.Execute(sql)
Eller
Set rs = Server.CreateObject("ADODB.Recordset")

ok, koden ovan(första inlägget) kan ej vara all kod du har i det scriptet.
Försökte att köra det och fick en del felmeddelanden.

Skulle du kunna posta all kod + en förklaring till hur den ska "dela" upp sidorna

cya,

Permalänk: https://www.webforum.nu/p/251709

## #12 — cgi, 2000-11-08T19:31Z

Konstigt, jag får då inte upp något felmeddelande, detta är hela koden:

```
<%
Set Databas = Server.CreateObject("ADODB.Connection")
Databas.Open "DSN=xxx-databas;Password=xxx"
SQL = "select * from Gbok order by nr desc"
Set RS = Databas.Execute(SQL)
persida = 5
For n = 1 to RS.recordcount step persida
IF n<> 1 then response.write " "
%>
<a href="gbok.asp?visa=<%=n%>"><%=n%> 
till 
<% If n + persida <=RS.recordcount then%><%=n + (persida -1)%>
<%else%>
<%=RS.recordcount%>
<%end if %>
</a>
<% next %>
<br> 
</p>
<%if RS.eof then
RS.close
set RS = nothing
else
if request("visa") = "" then
visa = 1
else
visa = Cint(request("visa"))
end if
RS.move visa -1
for row = visa to visa + (persida -1)
if RS.eof then exit for
%> 
Namn: <%=RS("G_namn")%><br>
Datum: <%=RS("G_datum")%><br>
Inlagg: <%=RS("G_inlagg")%><br>
<% 
RS.MoveNext
next 
end if
%>
```

sidorna ska sedan delas upp på följande sätt:
\<a href="gbok.asp?visa=1"\>1-5\</a\>
\<a href="gbok.asp?visa=6"\>6-10\</a\>
osv..
 

\[Redigerat av cgi den 08 nov 2000\]

Permalänk: https://www.webforum.nu/p/251710

## #13 — PatrikB, 2000-11-08T20:59Z

Hello,

Denna typ av RecSet - Set RS = Databas.Execute(SQL)
 \- stödjer inte ADODB.Recordsets RS.RecordCount utan får ett värde av -1

Prova med att skapa ett ADODB.Recordset istället.

```
Set RS = Server.CreateObject("ADODB.Recordset")
RS.Open SQL, Databas, 3, 3
```

cya,

Permalänk: https://www.webforum.nu/p/251711

## #14 — cgi, 2000-11-08T21:37Z

Får upp fel: Invalid connection. 
kan du beskriva lite mer hur man ska sätta ihop detta på ett bra sätt.

Permalänk: https://www.webforum.nu/p/251712

## #15 — PatrikB, 2000-11-09T08:32Z

Hello,

denna kod har jag kört, endat ändrat så att sql och rs("fält") stämde med min databas, och det funkade utan en enda ändring.

```
<HTML>
<HEAD>
<META NAME="GENERATOR" Content="Microsoft Visual Studio 6.0">
</HEAD>
<BODY>
<%
Set Databas = Server.CreateObject("ADODB.Connection")
	Databas.Open "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=x:\db.mdb;"

	SQL = "SELECT * FROM Gbok ORDER BY nr"

	Set RS = Server.CreateObject("ADODB.Recordset")
		RS.Open SQL, Databas, 3, 3
		
	persida = 5
	For n = 1 to RS.recordcount step persida
		IF n<> 1 then response.write " "
%>
<a href="gbok.asp?visa=<%=n%>"><%=n%> 
till 
<%
		If n + persida <=RS.recordcount then
			Response.Write(n + (persida -1))
		Else
			Response.Write RS.recordcount
		End If
%>
</a>&nbsp;
<%
	Next
%>
<br> 
</p>
<%
	If RS.eof then
		RS.close
		set RS = nothing
	Else
		If request("visa") = "" then
			visa = 1
		Else
			visa = Cint(request("visa"))
		End If
	RS.move visa -1
		For row = visa to visa + (persida -1)
			If RS.eof Then Exit For
%> 
<b>Namn:</b> <%=RS("G_namn")%><br>
<b>Datum:</b> <%=RS("G_datum")%><br>
<b>Inlagg:</b> <%=RS("G_inlagg")%><hr>
<% 
			RS.MoveNext
		Next 
	End if
%>
</BODY>
</HTML>
```

Ändra sökvägen till db så att det stämmer med sökvägen till din db.

cya,

Permalänk: https://www.webforum.nu/p/251713

## #16 — cgi, 2000-11-09T13:11Z

Konstigt, det funkar inte för mig.?

Permalänk: https://www.webforum.nu/p/251714

## #17 — PatrikB, 2000-11-09T13:23Z

Hello,

detta är din kod, ändrat till ADODB.Recordset och annat sql uttryck för att passa min db: <http://www.mrwize.nu/pageing/paging.asp> 

cya,

Permalänk: https://www.webforum.nu/p/251715

---

Tråden på webben: https://www.webforum.nu/amne/asp/7071-recordset-uppdelning