---
title: "Kan någon ta sig en titt"
type: "forum-thread"
url: "https://www.webforum.nu/amne/asp/69393-kan-någon-ta-sig-en-titt"
topic: "ASP"
topic_url: "https://www.webforum.nu/amne/asp"
author: "medialabs"
published: "2003-02-25T14:10:37.000Z"
updated: "2003-02-25T15:03:47.000Z"
replies: 9
views: 208
page: 1
pages: 1
language: "sv-SE"
site: "webForum — webforum.nu"
rights: "Upphovsrätten till varje inlägg tillhör dess författare."
attribution: "Citera som: webForum, https://www.webforum.nu/amne/asp/69393-kan-någon-ta-sig-en-titt"
---

# Kan någon ta sig en titt

## #1 — medialabs, 2003-02-25T14:10Z

På denna kod som inkluderas på varje sida på min webbsida.
Går det att förbättra den och göra den lite snabbare kanske.

Banner.asp - som inkluderas på varje sida

```
<!--#Include Virtual="/admin/banner_con.asp"-->

<%Set Conn = Server.CreateObject("Adodb.Connection")
Conn.Open "Driver={Microsoft Access Driver (*.mdb)}; dbq=" & db

Set RecSet=Conn.Execute("Select * From banner Order By rotator")%>

      <%If RecSet.EOF Then%>
           <font size="2" face="Tahoma">Inga banners inlagda!</font>
      <%Else
      x = 0
      Do Until RecSet.EOF Or x=Antal%>
          <a href="/admin/banner_klick.asp?go=ut&id=<%=RecSet("id")%>" target="_blank" onmouseover="self.status='<%=RecSet("link")%>';return true" onmouseout="self.status=' ';return true">&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp; <img src="<%=RecSet("banner")%>" border="0" width="88" height="31"></a>
      <%Conn.Execute("Update banner Set visad=visad+1 Where id = " & RecSet("id"))
      Conn.Execute("Update banner Set rotator=rotator+1 Where id = " & RecSet("id"))
      x=x+1
      RecSet.MoveNext
      Loop
      End If%>
```

 

banner_con.asp

```
<%
'#################################################
'---------------------Sökväg till databas från bannersidan!-----------
'#################################################

db = Server.MapPath("/database/banner.mdb")   

'#################################################
'-----------Antal banner på rad-----------------------------------------
'#################################################

Antal                           =  4

'#################################################
'-----------Adminnamn och lösen --------------------------------------
'#################################################

Admin1                       = "admin"
Admin2                       = "00000000"
%>
```

 

Banner_klick.asp 

```
<!--#Include Virtual="/admin/banner_con.asp"-->

<%Set Conn = Server.CreateObject("Adodb.Connection")
Conn.Open "Driver={Microsoft Access Driver (*.mdb)}; dbq=" & db

Set RecSet=Conn.Execute("Select * From banner Where id=" & request.querystring("id"))
Conn.Execute("Update banner Set klick=klick+1 Where id=" & request.querystring("id"))

Response.Redirect RecSet("link")%>
```

Permalänk: https://www.webforum.nu/p/69393

## #2 — crisse6, 2003-02-25T14:14Z

vad jag ser (har kollat lite snabbt) sa har du ju gamla kopplingen till db'n, byt ut den mot den nya, ska vara nagot snabbare(?) och mer problemfri...

Permalänk: https://www.webforum.nu/p/960728

## #3 — medialabs, 2003-02-25T14:16Z

> **crisse6 skrev:**
>
> vad jag ser (har kollat lite snabbt) sa har du ju gamla kopplingen till db'n, byt ut den mot den nya, ska vara nagot snabbare(?) och mer problemfri...

jag vet inte hur man gör det.....  :r

Permalänk: https://www.webforum.nu/p/960732

## #4 — Engine^, 2003-02-25T14:25Z

```
Conn.Open "Provider=Microsoft.Jet.OLEDB.4.0;Data Source =" & Server.MapPath("/Sökväg/dindatabas.mdb") & ";"
```

Antar att **crisse6** syftar på den.

Permalänk: https://www.webforum.nu/p/960739

## #5 — medialabs, 2003-02-25T14:32Z

ok, ska testa och ändra snart...

Permalänk: https://www.webforum.nu/p/960751

## #6 — Palle, 2003-02-25T14:34Z

Snabbt genomgånget på hur jag hade försökt strukturera upp det: :)
..med reservation för vissa fel, snabbkodat. ;)

**Banner.asp**

```
[RED]<%

Dim Conn, RecSet, arrRecSet

'// GetRows
Set Conn = Server.CreateObject("Adodb.Connection")
Conn.Open "Provider=Microsoft.Jet.OLEDB.4.0;Data Source ="& db

	Set RecSet = Conn.Execute("SELECT id, link, banner FROM banner ORDER BY rotator")
	If NOT RecSet.EOF Then arrRecSet = RecSet.GetRows()

RecSet.Close : Set RecSet = Nothing

'// Print
If IsArray(arrRecSet) Then
	For i = 0 To UBound(arrRecSet, 2)

		Dim intID, strLink, strBanner
		intID = arrRecSet(0,i)
		strLink = arrRecSet(1,i)
		strBanner = arrRecSet(2,i)
		Response.Write ""&_
		"<a href=""/admin/banner_klick.asp?go=ut&id="& intID &""" target=""_blank"" onmouseover=""self.status='"& strLink &"';return true;"" onmouseout=""self.status=' ';return true;"">"&_
		"<img src="""& strBanner &""" border=""0"" width=""88"" height=""31""></a>"

		Conn.Execute("UPDATE banner SET visad=visad+1, rotator=rotator+1 WHERE id = "& intID),,128

	Next
	Erase arrRecSet

Else
	Response.Write "<font size=""2"" face=""Tahoma"">Inga banners inlagda!</font>"

End If

[b]Conn.Close : Set Conn = Nothing[/b]

%>[/RED]
```

**Banner_klick.asp**

```
[RED]<%

Dim Conn, arrRecSet
Set Conn = Server.CreateObject("Adodb.Connection")
Conn.Open "Provider=Microsoft.Jet.OLEDB.4.0;Data Source ="& db

	arrRecSet = Conn.Execute("SELECT link FROM banner WHERE id="& trim(Request.Querystring("id"))).GetRows()
	Conn.Execute("UPDATE banner SET klick=klick+1 WHERE id="& trim(Request.Querystring("id"))),,128

Conn.Close : Set Conn =  Nothing
Response.Redirect arrRecSet(0,0)

%>[/RED]
```

**/r:** ..flyttade *Conn.Close : Set Conn = Nothing* till ett mer korrekt ställe. Se fet stil.

&nbsp;

Permalänk: https://www.webforum.nu/p/960753

## #7 — solbulle, 2003-02-25T14:41Z

Kanske kan vara en ide att använda en annan benämning ´på din querystring om det där är filer som du ska inkludera lite här och där. Risken att du redan använder dig av "id" känns ganska stor.

Permalänk: https://www.webforum.nu/p/960761

## #8 — Palle, 2003-02-25T14:49Z

> **solbulle skrev:**
>
> Kanske kan vara en ide att använda en annan benämning ´på din querystring om det där är filer som du ska inkludera lite här och där. Risken att du redan använder dig av "id" känns ganska stor.

Tanken är god. :)
Tror dock inte han behöver ändra det i just detta fall eftersom *Banner_klick.asp* öppnas 
i ett nytt fönster och endast sköter klickräkningen och vidareskickningen.. Har jag fel så rätta mig. ;)

Permalänk: https://www.webforum.nu/p/960770

## #9 — medialabs, 2003-02-25T14:53Z

> **Palle skrev:**
>
> > **solbulle skrev:**
> >
> > Kanske kan vara en ide att använda en annan benämning ´på din querystring om det där är filer som du ska inkludera lite här och där. Risken att du redan använder dig av "id" känns ganska stor.
>
> Tanken är god. :)
> Tror dock inte han behöver ändra det i just detta fall eftersom *Banner_klick.asp* öppnas 
> i ett nytt fönster och endast sköter klickräkningen och vidareskickningen.. Har jag fel så rätta mig. ;)

Du har rätt att den endast öppnas i ett nytt fönster och räknar klicken & vidareskickningen

Permalänk: https://www.webforum.nu/p/960775

## #10 — solbulle, 2003-02-25T15:03Z

> **Palle skrev:**
>
> Har jag fel så rätta mig. ;)

Eh... nja det behövs nog inte...  :r 

Läste inte så noggrant, såg just det där med en fil som inkluderades. Lätt att få dubletter i så fall.

Permalänk: https://www.webforum.nu/p/960795

---

Tråden på webben: https://www.webforum.nu/amne/asp/69393-kan-någon-ta-sig-en-titt