---
title: "Operation is not allowed when object..."
type: "forum-thread"
url: "https://www.webforum.nu/amne/asp/57698-operation-is-not-allowed-when-object"
topic: "ASP"
topic_url: "https://www.webforum.nu/amne/asp"
author: "crisse6"
published: "2002-11-01T03:38:08.000Z"
updated: "2002-11-01T18:02:32.000Z"
replies: 9
views: 226
page: 1
pages: 1
language: "sv-SE"
site: "webForum — webforum.nu"
rights: "Upphovsrätten till varje inlägg tillhör dess författare."
attribution: "Citera som: webForum, https://www.webforum.nu/amne/asp/57698-operation-is-not-allowed-when-object"
---

# Operation is not allowed when object...

## #1 — crisse6, 2002-11-01T03:38Z

Hej!

Ja, som ni ser pa rubriken sa ar det sa har felmeddelandet lyder:

Operation is not allowed when the object is closed!

Med denna kod:

```
[red]
<%
Dim objConn
Dim sql
Dim rs

'### Databaskoppling
Set objConn = Server.CreateObject("ADODB.Connection")
objConn.Open "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & server.mappath("/horjavel/db/banners.mdb")

If request.querystring("vad") = "" then
sql = "select * from Banners"
set rs = objConn.Execute(sql)
End if
If request.querystring("vad") = "delete" then
sql = "delete from Banners where BannerID = " & request.querystring("id") & ""
set rs = objConn.Execute(sql)
End if

If rs.eof then
response.write "Inga banners i databasen!"

'### ...annars
else

'### Startar en loop tills det ar tomt
Do until rs.Eof

'### Gor sa att det blir 2 olika farger i tabellen
if bgcolor = "#EFEFEF" then
bgcolor = "#FFFFFF"
else
bgcolor = "#EFEFEF"
end if

'### Skriver ut tabell...
response.write "<table bgcolor="""&bgcolor&"""><tr><td>"& rs("BannerURL") &"</td>" &_
"<td><a href=""modda.asp?vad=edit&id="& rs("BannerID") &""">Edit</a></td>" &_
"<td><a href=""modda.asp?vad=delete&id="& rs("BannerID") &""">Delete</a></td></tr></table>"
rs.movenext
loop
End if
rs.close
objConn.close
Set objConn = Nothing
%>
```

Ser inget fel, eller rattare sagt hittar inget fel, men ar trott ocksa! :e

Permalänk: https://www.webforum.nu/p/57698

## #2 — @nders, 2002-11-01T05:25Z

Vilken rad pekar felmeddelandet på?

Varför skapar du recordset när du gör delete?
Jag vet inte om det hjälper, men jag flyttade på lite kod och, tog bort recordsetet vid delete.

Och: Det är lättare att läsa kod om man använder indentering. Ett tips.

```
<%
Dim objConn
Dim sql
Dim rs

'### Databaskoppling
Set objConn = Server.CreateObject("ADODB.Connection")
objConn.Open "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & server.mappath("/horjavel/db/banners.mdb")

If request.querystring("vad") = "" then
   sql = "select * from Banners"
   set rs = objConn.Execute(sql)
   If rs.eof then
      response.write "Inga banners i databasen!"

   '### ...annars
   else

      '### Startar en loop tills det ar tomt
      Do until rs.Eof

         '### Gor sa att det blir 2 olika farger i tabellen
          if bgcolor = "#EFEFEF" then
             bgcolor = "#FFFFFF"
         else
             bgcolor = "#EFEFEF"
         end if

         '### Skriver ut tabell...
         response.write "<table bgcolor="""&bgcolor&"""><tr><td>"& rs("BannerURL") &"</td>" &_
         "<td><a href=""modda.asp?vad=edit&id="& rs("BannerID") &""">Edit</a></td>" &_
         "<td><a href=""modda.asp?vad=delete&id="& rs("BannerID") &""">Delete</a></td></tr></table>"
         rs.movenext
      loop
   End if
   rs.close
   set rs = Nothing
End if

If request.querystring("vad") = "delete" then
   sql = "delete from Banners where BannerID = " & request.querystring("id") & ""
   objConn.Execute sql,,128
End if

objConn.close
Set objConn = Nothing
%>
```

mvh,

Permalänk: https://www.webforum.nu/p/839087

## #3 — crisse6, 2002-11-01T14:05Z

ok. ska testa koden!
Kom pa det ocksa nu nar du sa det, varfor skulle jag skapa recset nar det ar delete? aja, var trott nar jag gjorde det, duger det? :e

Vad menar du med ditt tips @nders? Identiering?

Permalänk: https://www.webforum.nu/p/842388

## #4 — @nders, 2002-11-01T14:34Z

```
' ett eller annat börjar här, ex loop
            ' här görs saker i loopen, indenterat ett steg
            ' å lite mer
            ' här har vi en if-sats som börjar
                       ' så vi indenterar lite mer
                       ' å en gång till
            ' här tar if-satsen slut
' här drar vi vidare loopen från början
```

Du ser att koden blir betydligt mer lättläst med indrag som visar vilka kodblock som utförs ihop.

Mvh,

Permalänk: https://www.webforum.nu/p/842410

## #5 — trexter.com, 2002-11-01T14:59Z

En sak jag undrat.. när ni intenderar, trycker ni på mellanslag några gånger du eller?
För när jag trycker \>\>tab\<\< i mitt Notepad så blir det en enorm intendering.

... eller kör ni andra program med andra tabs?

 :)

Permalänk: https://www.webforum.nu/p/842435

## #6 — @nders, 2002-11-01T15:03Z

Jag använder tab.

Det är precis lika galet att använda mellanslag som att använda Notepad att skriva kod i ;). Det finns mängder av bra gratis editors med färgkodning och ordentliga tabbar.

Mvh,

Permalänk: https://www.webforum.nu/p/842440

## #7 — trexter.com, 2002-11-01T15:05Z

Säg en bra gratis editor du förespråkar.
Jag testade Ultra Edit men gilllade inte den...

(och ursäkta att jag drar in program i ASP-tråden ;) )

 :)

Permalänk: https://www.webforum.nu/p/842442

## #8 — crisse6, 2002-11-01T16:27Z

Skulle bara saga att @nders kod fungerade! (Visst ar jag duktig som foljer wF reglerna med att meddela korrekt kod?!)

Permalänk: https://www.webforum.nu/p/842498

## #9 — @nders, 2002-11-01T16:37Z

> **trexter.com skrev:**
>
> Säg en bra gratis editor du förespråkar.

Jag använder inte gratiseditorer, men det finns en hel del trådar i forumet Webbeditorer där det diskuterats, och massor av tips ges.

Mvh,

Permalänk: https://www.webforum.nu/p/842499

## #10 — OveRRidE, 2002-11-01T18:02Z

> (Visst ar jag duktig som foljer wF reglerna med att meddela korrekt kod?!)

Haha! :D

Permalänk: https://www.webforum.nu/p/842539

---

Tråden på webben: https://www.webforum.nu/amne/asp/57698-operation-is-not-allowed-when-object