---
title: "Problem med asp och en select-lista"
type: "forum-thread"
url: "https://www.webforum.nu/amne/asp/53181-problem-med-asp-och-en-select-lista"
topic: "ASP"
topic_url: "https://www.webforum.nu/amne/asp"
author: "Hulth"
published: "2002-09-14T08:43:24.000Z"
updated: "2002-09-15T10:56:40.000Z"
replies: 4
views: 289
page: 1
pages: 1
language: "sv-SE"
site: "webForum — webforum.nu"
rights: "Upphovsrätten till varje inlägg tillhör dess författare."
attribution: "Citera som: webForum, https://www.webforum.nu/amne/asp/53181-problem-med-asp-och-en-select-lista"
---

# Problem med asp och en select-lista

## #1 — Hulth, 2002-09-14T08:43Z

Jag har ett problem som jag är säker på att någon annan har råkat ut för tidigare.

Det är så att jag håller på med ett slags länk-arkiv till min hemsida och i adminsystemet ska man kunna ändra vilken kategori länkarna är i. Det är ju inget problem, fast jag gjorde så att kategorierna också ligger i en databas och när man har valt en länk skriver det ut alla kategorier. Jag har alltså två recordset (dom heter recset och kate).

Jag vill att den ska skriva ut selected i den kategorin där id-nummret (i kate) är detsamma som i fältet cat (i Recset).

Kan någon hjälpa mig? (Bifogar den koden jag har nedanför.

```
ElseIf what = "l_link" Then
	If l_link_id = "" Then
		l_link = "SELECT * FROM h_link_d"
		RecSet.Open l_link, Connect, AdOpenDynamic

		If RecSet.EOF Then
			Response.Write "Det finns inga länkar i databasen." & VbNewLine
		Else
			Do Until RecSet.EOF
			ID	= RecSet("ID")
			Response.Write "<a href=""admin.asp?do=edit&what=l_link&l_link_id=" & ID & """>Redigera</a> | <a href=""admin.asp?do=del&what=l_link&l_link_id=" & ID & """>Radera</a> - " & RecSet("link") & "<br>" & VbNewLine
			RecSet.MoveNext
			Loop
		End If
		RecSet.Close
	ElseIf l_link_id <> "" Then
		l_link_g = "SELECT * FROM h_link_d WHERE ID = " & l_link_id
		RecSet.Open l_link_g, Connect, AdOpenDynamic

		If RecSet.EOF Then
			Response.Write "Länken finns inte." & VbNewLine
		Else
			Response.Write "<form action=""admin.asp?do=save&what=l_link&l_link_id=" & l_link_id & """ method=""post"">" & VbNewLine
			Response.Write "<table align=""left"" width=""300"" border=""0"" cellpadding=""0"" cellspacing=""0"">" & VbNewLine
			Response.Write "<tr><td><font size=""1"">ID-nummer</font></td><td><input type=""text"" name=""ID"" value=""" & RecSet("ID") & """ disabled></td></tr>" & VbNewLine
			Response.Write "<tr><td><font size=""1"">Adress</font></td><td><input type=""text"" name=""link"" value=""" & RecSet("link") & """></td></tr>" & VbNewLine
			Response.Write "<tr><td><font size=""1"">Beskrivning</font></td><td><input type=""text"" name=""des"" value=""" & RecSet("des") & """></td></tr>" & VbNewLine
			Response.Write "<tr><td><font size=""1"">Kategori</font></td><td><select name=""cat"">" & VbNewLine

			kategorier = "SELECT * FROM h_link_c ORDER BY cat_lname DESC"
			Set kate = Connect.ExeCute(kategorier)

			If kate.EOF Then
			Response.Write "<option value=""ingen"">Inga kategorier hittades</option>" & VbNewLine
			Else
				Do Until kate.EOF
				%><option value="<%=kate("ID")%>"<% If kate("ID") = l_link_id Then %> selected<% End If %>><%=kate("cat_lname")%></option><%
				kate.MoveNext
				Loop
			End If
			kate.close

		Response.Write "</select></td></tr>" & VbNewLine
			Response.Write "<tr><td><a href=""admin.asp?do=edit&what=l_link"">Tillbaka</a></td><td><input type=""submit"" value=""Spara""></td></tr>" & VbNewLine
			Response.Write "</table>" & VbNewLine
			Response.Write "</form>" & VbNewLine
		End If
	End If	
End If
```

Permalänk: https://www.webforum.nu/p/53181

## #2 — @nders, 2002-09-14T08:47Z

Subtypskonvertering? Ett tal är aldrig samma som en sträng och vice versa. 

```
%><option value="<%=kate("ID")%>"<% If Clng(kate("ID")) = Clng(l_link_id) Then %> selected<% End If %>><%=kate("cat_lname")%></option><%
```

Permalänk: https://www.webforum.nu/p/785573

## #3 — Hulth, 2002-09-14T22:29Z

kan vara något sånt för jag har gjort liknande innan och då har det fungerat. fast då har det inte varit tal..

Permalänk: https://www.webforum.nu/p/786081

## #4 — @nders, 2002-09-15T06:41Z

Och om du gör som jag visade, fungerar det då?

Permalänk: https://www.webforum.nu/p/786147

## #5 — Hulth, 2002-09-15T10:56Z

Jadå, det fungerar perfekt.

Vad gör den koden som du skrev egentligen? förutom att den löser mina problem ;)

Permalänk: https://www.webforum.nu/p/786292

---

Tråden på webben: https://www.webforum.nu/amne/asp/53181-problem-med-asp-och-en-select-lista