---
title: "Dölja ipnummer!"
type: "forum-thread"
url: "https://www.webforum.nu/amne/asp/52632-dölja-ipnummer"
topic: "ASP"
topic_url: "https://www.webforum.nu/amne/asp"
author: "nisslass"
published: "2002-09-09T00:02:57.000Z"
updated: "2002-09-09T11:36:53.000Z"
replies: 11
views: 693
page: 1
pages: 1
language: "sv-SE"
site: "webForum — webforum.nu"
rights: "Upphovsrätten till varje inlägg tillhör dess författare."
attribution: "Citera som: webForum, https://www.webforum.nu/amne/asp/52632-dölja-ipnummer"
---

# Dölja ipnummer!

## #1 — nisslass, 2002-09-09T00:02Z

Hej!

En snabb fråga..

Vill att ip via en Funktion skrivs ut i formatet

192\.168.0.X
Eller
192\.168.168.XXX

Så att mina användare får en viss anonymitet när de syns i vem som surfar på sidan just nu. Vet inte riktigt hur man gör när ip adresserna har olika med antal siffror i sig...

Vill alltså att den 4:e delen av ip adressen ersätts med "x".

Permalänk: https://www.webforum.nu/p/52632

## #2 — OveRRidE, 2002-09-09T06:21Z

Helt otestat givetvis. :)

```
ipAddr = "192.168.200.100"
strIpAddr = left(ipAddr,len(ipAddr)-instrRev(ipAddr,".")-1)

for i = 1 to instrRev(ipAddr,".")-1
   strIpAddr = strIpAddr & "X"
next

response.write strIpAddr
```

Permalänk: https://www.webforum.nu/p/778519

## #3 — Erik Juhlin, 2002-09-09T06:39Z

En fin testad funktion. :)

```
<%
Function ReplaceLastSection(ByVal sStr, ByVal sSeperator, ByVal sReplaceCharacter)
	
	Dim vStr, i
	
	vStr = Split(sStr, sSeperator)
	
	sStr = ""
	
	For i = 0 To UBound(vStr)
		If i <> 0 Then sStr = sStr & sSeperator
		If i = UBound(vStr) Then
			sStr = sStr & String(Len(vStr(i)), sReplaceCharacter)
		Else
			sStr = sStr & vStr(i)
		End If
	Next 'i
	
	ReplaceLastSection = sStr
	
End Function

Response.Write ReplaceLastSection("192.168.200.100", ".", "X")
%>
```

Permalänk: https://www.webforum.nu/p/778528

## #4 — Gein, 2002-09-09T07:13Z

eller min funktion, som använder reguljära uttryck :)

```
	Function HideIP(userIP)
		Set objRegExp = New RegExp
		objRegExp.Global = true
		objRegExp.IgnoreCase = true
		objRegExp.Pattern = "\d{1,3}$"
		strReplace = "***"
		HideIP = objRegExp.Replace(userIP, strReplace)
	End Function
```

Permalänk: https://www.webforum.nu/p/778574

## #5 — @nders, 2002-09-09T07:18Z

Ännu ett förslag om man vill ha lite mindre kod:

```
strIP = "192.168.200.100"
strIP = Left(strIP, instrRev(strIP, ".")) & "xxx"
```

Jag tycker det känns onödigt att bry sig om hur många siffror som finns efter sista punkten.

Mvh,

Permalänk: https://www.webforum.nu/p/778579

## #6 — OveRRidE, 2002-09-09T07:20Z

> **@nders skrev:**
>
> Jag tycker det känns onödigt att bry sig om hur många siffror som finns efter sista punkten.

Visserligen funderade jag med på det, men det gör ju knappast någon skada. ;)

Permalänk: https://www.webforum.nu/p/778585

## #7 — voigtann1, 2002-09-09T07:27Z

slutar alltid IP med 3 siffror? kan det inte vara ibland 2?

Permalänk: https://www.webforum.nu/p/778589

## #8 — @nders, 2002-09-09T07:30Z

Det kan sluta med en, två eller tre siffror. Men jag tycker inte att det spelar någon roll.

Mvh,

Permalänk: https://www.webforum.nu/p/778590

## #9 — Gein, 2002-09-09T07:31Z

tycker iaf att regexp är snyggast ;)

Permalänk: https://www.webforum.nu/p/778591

## #10 — CatZ, 2002-09-09T08:53Z

tycker mest regexp är rörigt!

Permalänk: https://www.webforum.nu/p/778617

## #11 — OveRRidE, 2002-09-09T09:03Z

> tycker mest regexp är rörigt!

Fel. Kraftfullt. :)

Permalänk: https://www.webforum.nu/p/778624

## #12 — nisslass, 2002-09-09T11:36Z

Tack ska ni ha, kör på @nders förslag...

Permalänk: https://www.webforum.nu/p/778739

---

Tråden på webben: https://www.webforum.nu/amne/asp/52632-dölja-ipnummer