---
title: "Visa ett antal filer från en katalog med FSO"
type: "forum-thread"
url: "https://www.webforum.nu/amne/asp/49283-visa-ett-antal-filer-från-en-katalog-med-fso"
topic: "ASP"
topic_url: "https://www.webforum.nu/amne/asp"
author: "lejzer"
published: "2002-08-02T09:38:25.000Z"
updated: "2002-08-02T12:43:07.000Z"
replies: 2
views: 237
page: 1
pages: 1
language: "sv-SE"
site: "webForum — webforum.nu"
rights: "Upphovsrätten till varje inlägg tillhör dess författare."
attribution: "Citera som: webForum, https://www.webforum.nu/amne/asp/49283-visa-ett-antal-filer-från-en-katalog-med-fso"
---

# Visa ett antal filer från en katalog med FSO

## #1 — lejzer, 2002-08-02T09:38Z

Hej!

Jag har en katalog med massor av filer. Jag presenterar filerna med hjälp av FSO, men listan växer stadigt hela tiden. 

Jag skulle vilja dela upp filerna i 10-20 per sida. Någon som har ett exempel på hur man kan göra detta?

Tack på förhand!

/ Martin

Permalänk: https://www.webforum.nu/p/49283

## #2 — sailsoft, 2002-08-02T10:53Z

Jag skrev ihop ett litet skript...

```php
<%
'Sökväg till katalogen
sSokvag_Katalog = "din sökväg"

'Visa antal filer per sida
iAntal_Filer_Per_Sida = 10

'Kollar om någon sida är vald
iVald_Sida = Trim(Request("sid_nr"))

'Validerar
If IsNumeric(iVald_Sida) = false then iVald_Sida = 1

'Skapar objekt
Set objFso = CreateObject("Scripting.FileSystemObject")

'Hämtar katalog
Set objKat = objFso.GetFolder(sSokvag_Katalog)

'Räknare
i = 1

'Startposition
iStart_Pos = (iVald_Sida * iAntal_Filer_Per_Sida) - iAntal_Filer_Per_Sida + 1

'Slutposition
iSlut_Pos = (iVald_Sida * iAntal_Filer_Per_Sida)

'Loopar igenom
For each objFil in objKat.Files

	'Kollar intervallet, skriver ut filen om den är inom
	If i >= iStart_Pos and i <= iSlut_Pos then

		Response.Write(objFil.Name & "<br>" & vbCrLf)
		
	end if	
	
	'Ökar
	i = i + 1

next

'Stänger
Set objFso = Nothing

'Kollar hur många sidor det finns
iAntal_Sidor = CInt((i / iAntal_Filer_Per_Sida) + 0.99)

'Text
Response.Write("<br>Sidor:&nbsp;")

'Skriver ut sidlänkarna
For i = 1 to iAntal_Sidor

	'Sida
	Response.Write("<a href='lista_filer.asp?sid_nr="& i &"'>"& i &"</a>&nbsp;")

Next
%>
```

Permalänk: https://www.webforum.nu/p/738856

## #3 — lejzer, 2002-08-02T12:43Z

Hej!

Helt perfekt, precis vad jag behövde! 

Tack för hjälpen!!

Mvh

Martin

Permalänk: https://www.webforum.nu/p/738953

---

Tråden på webben: https://www.webforum.nu/amne/asp/49283-visa-ett-antal-filer-från-en-katalog-med-fso