Letar efter detta.

medialabsMedlem sedan mars 20023 686 inlägg

Trådstart19 juli 2002 23:49#1

Hej!

Jag har sökt och sökt efter ett login script som gör så att man loggar in på index.asp med kund nummer, användarnman och lösenord.

Sen kommer man tillbax till index.asp och så har man fått en session som heter: 8zb8K7pq43wDh91zV3

Man kommer alltså tillbax till index.asp efter att ha loggat in.

men nu till det svåra! Jag skulle vilja så att scriptet är säkert mot elaka tacken som: ', '' och liknande.

MVH

OJJE - Desperat.

icaaqMedlem sedan okt. 20005 273 inlägg

20 juli 2002 07:24#2

Här är ett exempel som du kanske kan modifiera:

[red]
<%Option Explicit
Response.Buffer = TRUE
'************************************************
'Dimmar alla variabler
Dim intStartnr
Dim strPassword
Dim objCon
Dim objRS
Dim strSQL
Dim strError
'************************************************
If Request.Form > "" Then
	If Request.Form("strPassword") = "" OR Request.Form("intStartnr") = "" Then
		strError = "Du måste fylla i båda fälten!"
		Call Page
	Else
		intStartnr = FixRequests(Trim(Request.Form("intStartnr")))
		strPassword = FixRequests(Trim(Request.Form("strPassword")))
		'****************************************
		strSQL = "SELECT Startnr, [password] FROM AnmaldaLag WHERE "&_
		"Startnr = "&intStartnr&" AND [password] = '"&strPassword&"'"
		'****************************************
		Set objCon = Server.CreateObject("ADODB.Connection")
			objCon.Provider = "Microsoft.Jet.OLEDB.4.0"
			objCon.ConnectionString = "Data Source="& Server.MapPath("VASA2002.mdb")
			objCon.open
			Set objRS = objCon.Execute(strSQL)
			If objRS.EOF then
				strError = "Fel startnr eller användarnamn, försök igen."
				Set objCon = Nothing
				Call Page
			Else
				If Cint(objRS("Startnr")) = Cint(intStartnr) AND Cstr(objRS("password")) = Cstr(strPassword) Then
					Session("permission") = TRUE
					Session("intStartnr") = Cint(intStartnr)
					Set objCon = Nothing
					Response.Redirect "Secured.asp"
				Else
					strError = "Fel startnr eller användarnamn, försök igen."
					Set objCon = Nothing
					Call Page
				End If
			End If
	End If
Else
Call Page
End If
Sub page
%>
<html>
<head>
<title>Untitled Document</title>
<meta http-equiv="Content-Type" content="text/html; charset=iso-8859-1">
</head>

<body bgcolor="#FFFFFF" text="#000000">
<form name="form1" method="post" action="<%=Request.ServerVariables("SCRIPT_NAME")%>">
  <table width="100%" border="0" cellspacing="2" cellpadding="0">
  <%
  If strError > "" Then
  %>
      <tr> 
      <td colspan="2"> 
        <p align="left"><font face="Verdana, Arial, Helvetica, sans-serif" size="2"><%=strError%></font></p>
      </td>
    </tr>
    <%
    Else
    %>
    <tr> 
      <td colspan="2"> 
        <p align="left"><font face="Verdana, Arial, Helvetica, sans-serif" size="2">Skriv 
          in ditt startnr och l&ouml;senord:</font></p>
      </td>
    </tr>
    <%
    End If
    %>
    <tr> 
      <td><font face="Verdana, Arial, Helvetica, sans-serif" size="2">Startnr:</font></td>
      <td> <font face="Verdana, Arial, Helvetica, sans-serif" size="2"> 
        <input type="text" name="intStartnr">
        </font></td>
    </tr>
    <tr> 
      <td><font face="Verdana, Arial, Helvetica, sans-serif" size="2">L&ouml;senord:</font></td>
      <td> <font face="Verdana, Arial, Helvetica, sans-serif" size="2"> 
        <input type="password" name="strPassword">
        </font></td>
    
        <tr> 
      <td> </td>
      <td>
        <input type="submit" name="Submit" value="Logga in">
        </td>
    </tr></tr>
  </table>
</form>
</body>
</html>
<%
End Sub 
'************************************************
Function CheckForms()
	Dim Item
	CheckForms = 0
		For Each Item In Request.Form
			If Item = "" then CheckForms = 1
		Next
End Function
'************************************************
Function FixRequests(ByVal x)
	x = Replace(x, "'", "''")
	x = Replace(x, "|", "")
	FixRequests = x
End Function
'************************************************	
		
			
%>
[/red]

medialabsMedlem sedan mars 20023 686 inlägg

20 juli 2002 11:21#3

Tack icaaq.

ska kolla lite närmare på detta.