---
title: "Få ut datat i min ordning utan dubletter?"
type: "forum-thread"
url: "https://www.webforum.nu/amne/asp/44929-få-ut-datat-i-min-ordning-utan-dubletter"
topic: "ASP"
topic_url: "https://www.webforum.nu/amne/asp"
author: "solbulle"
published: "2002-05-30T18:57:41.000Z"
updated: "2002-05-30T19:17:18.000Z"
replies: 2
views: 265
page: 1
pages: 1
language: "sv-SE"
site: "webForum — webforum.nu"
rights: "Upphovsrätten till varje inlägg tillhör dess författare."
attribution: "Citera som: webForum, https://www.webforum.nu/amne/asp/44929-få-ut-datat-i-min-ordning-utan-dubletter"
---

# Få ut datat i min ordning utan dubletter?

## #1 — solbulle, 2002-05-30T18:57Z

Nu har det slagit helt slint,

Jag har en sqlfråga som ger mig en array innehållandes namn, yrke o arbetsplats.
(Med data från flera tabeller "genom" eb relationstabell.

```
<%
Set connect = Server.CreateObject("ADODB.Connection")
connect.Open "DRIVER={Microsoft Access Driver (*.mdb)}; DBQ=" & Server.MapPath("db1.mdb")

'denna tar ut all textinfo o lägger i en array. Tar ej ut någon info om det saknas någon post.
SQL = "SELECT tblforetag.foretag, tblperson.person, tblyrke.yrke FROM tblforetag inner JOIN (tblyrke INNER JOIN (tblperson INNER JOIN tblsamband ON tblperson.idnr = tblsamband.person) ON tblyrke.idnr = tblsamband.yrke) ON tblforetag.idnr = tblsamband.foretag where tblforetag.idnr =1"

set rs = connect.execute(SQL)

found = not rs.eof
if found then

allaFields=rs.getrows

	ant_inlagg = ubound(allaFields,2)

For i = 0 to ant_inlagg
for t = 0 to ubound(allaFields,1)

'Response.write rs.Fields(t).Name & "    "
response.write allaFields(t,i) & "<br>"
'response.write "t,i= " & t & "," & i & "<br>"

Next
Response.write "------<br>" 				'Nytt varv
Next

End If

	rs.close
	set rs = nothing
	connect.Close
	set connect = nothing
%>
```

Hyr gör jag för att visa resultatet på en sida?
Om jag bara loopar ut innehåller som nu blir det:

Bygg AB
Kalle
Snickare
\------
Bygg AB
Anders
Nagelbitare
\------
Bygg AB
Lotta
Snickare

Men jag vill ju kunna typ överst kunna skriva företagets namn och sen lista alla yrkeskategorier typ:

Bygg AB

Snickare
Kalle
Lotta

Nagelbitare
Anders

Hur attans gör jag det!?!
Är jag fel ute när jag lägger det hela i en array?

Med vanliga recordset fixar jag det inte heller...

```
<%
Set connect = Server.CreateObject("ADODB.Connection")
connect.Open "DRIVER={Microsoft Access Driver (*.mdb)}; DBQ=" & Server.MapPath("db1.mdb")

'denna tar ut all textinfo. Tar ej ut någon info om det saknas någon post.
SQL = "SELECT tblforetag.foretag, tblperson.person, tblyrke.yrke FROM tblforetag inner JOIN (tblyrke INNER JOIN (tblperson INNER JOIN tblsamband ON tblperson.idnr = tblsamband.person) ON tblyrke.idnr = tblsamband.yrke) ON tblforetag.idnr = tblsamband.foretag where tblforetag.idnr =1"

set rs = connect.execute(SQL)

found = not rs.eof
if found then

response.write rs("foretag")

response.write "<p>"
WHILE NOT rs.EOF

response.write rs("yrke")
response.write "<p>"
response.write rs("person")

response.write "<p>"
rs.movenext
wend

End If
	rs.close
	set rs = nothing
	connect.Close
	set connect = nothing
%>
```

Permalänk: https://www.webforum.nu/p/44929

## #2 — LarsG, 2002-05-30T19:07Z

```
SQL = "SELECT tblforetag.foretag, tblperson.person, tblyrke.yrke FROM tblforetag inner JOIN " &_
" (tblyrke INNER JOIN (tblperson INNER JOIN tblsamband ON tblperson.idnr = tblsamband.person) ON tblyrke.idnr = tblsamband.yrke) ON tblforetag.idnr = tblsamband.foretag " &_
"where tblforetag.idnr =1 order by tblforetag.foretag,tblyrke.yrke "
set rs = connect.execute(sql)
pforetag = ""
while not rs.eof
  if  pforetag <> rs("foretag") then
      pforetag = rs("foretag")
      response.write pforetag & "<br>"
      pyrke = ""
  end if
  if  pyrke <> rs("yrke") then
      pyrke = rs("yrke")
      response.write pyrke & "<br>"
  end if
  response.write rs("person")
  rs.movenext
wend
```

Permalänk: https://www.webforum.nu/p/687510

## #3 — solbulle, 2002-05-30T19:17Z

Lysande, fungerar perfekt! :)

Permalänk: https://www.webforum.nu/p/687518

---

Tråden på webben: https://www.webforum.nu/amne/asp/44929-få-ut-datat-i-min-ordning-utan-dubletter