---
title: "slumpa fram 5 olika bilder"
type: "forum-thread"
url: "https://www.webforum.nu/amne/asp/40921-slumpa-fram-5-olika-bilder/page3"
topic: "ASP"
topic_url: "https://www.webforum.nu/amne/asp"
author: "ampy"
published: "2002-04-05T11:06:25.000Z"
updated: "2004-08-16T10:37:46.000Z"
replies: 42
views: 1116
page: 3
pages: 3
language: "sv-SE"
site: "webForum — webforum.nu"
rights: "Upphovsrätten till varje inlägg tillhör dess författare."
attribution: "Citera som: webForum, https://www.webforum.nu/amne/asp/40921-slumpa-fram-5-olika-bilder"
---

# slumpa fram 5 olika bilder

_Sida 3 av 3._

## #41 — solbulle, 2004-08-14T23:32Z

Det där ser smart ut. Det tycker jag borde fungera. Är du säker på att din sql-fråga verkligen ger träff? (iofs skulle du få ett mess annars...
Vad visar källkoden?

Permalänk: https://www.webforum.nu/p/1410639

## #42 — WebbisNet, 2004-08-15T00:35Z

när jag kör med färgkodning så ser jag en brytning vid If Count \> antalBilder Then

Detta blir output tillsammans med bilderna
Active Server Pages error 'ASP 0113' 

Script timed out 

/default.asp 

The maximum amount of time for a script to execute was exceeded. You can change this limit by specifying a new value for the property Server.ScriptTimeout or by changing the value in the IIS administration tools.

Permalänk: https://www.webforum.nu/p/1410676

## #43 — WebbisNet, 2004-08-16T10:37Z

Detta verkar funka bra :-)

```
Dim rs 
Dim oConn 

Dim strSQL 

Dim bilder 

Dim i, j 
Dim Count 
Dim post 
Dim antalBilder 

Dim Found 
     
    Set oConn = server.CreateObject("ADODB.Connection") 
    oConn.Open "Provider=Microsoft.Jet.OLEDB.4.0; Data Source= " & server.MapPath("/db/databasnamn.mdb") & ";" 

    strSQL = "SELECT picture, username, visaBild" & vbCrLf & _ 
             "FROM tabell" & vbCrLf & _ 
             "WHERE not picture='nopic.jpg' and visaBild=true" 

    Set rs = oConn.Execute(strSQL) 
    If rs.EOF Then 
        Response.Write "Det finns inga bilder..." 
    Else 
        Response.Write "<table width=""95%""><tr><td align=""center"">" 
        bilder = rs.GetRows() 
        antalBilder = UBound(bilder, 2) + 1 

        Count = 6 
        If Count > antalBilder Then 
            Count = antalBilder 
        End If 
        ReDim Shown(Count) 

        Randomize 

        For i = 1 To Count 
            Do 
                Found = False 
                post = Int(Rnd * antalBilder) 

                For j = 1 To i - 1 
                    If Shown(j) = post Then 
                        Found = True 
                        Exit For 
                    End If 
                Next 
            Loop While Found 
            Shown(i) = post 

            Response.Write "<img border=""1"" height=""120"" width=""100"" src=""/images/users/" & bilder(0, post) & """ alt=""" & bilder(1, post) & """>&nbsp; &nbsp;" 
        Next 
        Response.Write "</td></tr></table>" 
    End If 
    rs.Close 
    Set rs = Nothing
```

Permalänk: https://www.webforum.nu/p/1411318

---

Tråden på webben: https://www.webforum.nu/amne/asp/40921-slumpa-fram-5-olika-bilder/page3  
Föregående sida: https://www.webforum.nu/amne/asp/40921-slumpa-fram-5-olika-bilder/page2.md