---
title: "Sortera"
type: "forum-thread"
url: "https://www.webforum.nu/amne/asp/181924-sortera"
topic: "ASP"
topic_url: "https://www.webforum.nu/amne/asp"
author: "devotion"
published: "2010-01-08T11:01:21.000Z"
updated: "2010-01-08T13:31:05.000Z"
replies: 5
views: 606
page: 1
pages: 1
language: "sv-SE"
site: "webForum — webforum.nu"
rights: "Upphovsrätten till varje inlägg tillhör dess författare."
attribution: "Citera som: webForum, https://www.webforum.nu/amne/asp/181924-sortera"
---

# Sortera

## #1 — devotion, 2010-01-08T11:01Z

Hepp!

Jag har följande kod som ligger i en loop:

```
sDocNote = oChk.Data.Note
			sDocDate = oChk.Data.Date
			sDocUser = oChk.Data.User
			if sDocNote <> "" then
				sDocNotes = sDocNotes & "[" & FormatDateTime(sDocDate, 2) & "] " & sDocNote & " /" & sDocUser & "<br>"
			end if
```

Tanken är att jag senare skriver ut med:

```
Response.write sDocNotes
```

Problemet är att jag inte kan sortera på datum i loopen, utan det blir som det blir...

Kan man göra på något annat sätt, så man kan sortera om det innan man skriver ut?

Mvh
Henrik

Permalänk: https://www.webforum.nu/p/181924

## #2 — voigtann1, 2010-01-08T11:08Z

skapa ett recordset av alla dina loop:ar och sortera recordsetet.

Permalänk: https://www.webforum.nu/p/2219257

## #3 — devotion, 2010-01-08T11:33Z

Problemet är att jag inte kan det... :(  

Datat ligger inbäddad i ett fält, det finns ingen datumkolumn i databasen...

Kan man inte lösa det på annat sätt?

Mvh
Henrik

Permalänk: https://www.webforum.nu/p/2219259

## #4 — @nders, 2010-01-08T11:58Z

Varför kan du inte det? Kan du använda datat kan du väl lägga in det i ett recordset?

Vi pratar alltså om ett recordset som inte fylls av någon SQL-fråga, utan ett tomt recordset du skapar, som du sedan fyller post för post i din befintliga loop.

Permalänk: https://www.webforum.nu/p/2219261

## #5 — devotion, 2010-01-08T12:02Z

Hmm, ok! :)  

Jag kikar på det...

 :)  

Mvh
Henrik

Permalänk: https://www.webforum.nu/p/2219264

## #6 — devotion, 2010-01-08T13:31Z

Hepp!

Så här fick det bli:

```
dim Conn, Rs, sSQL
	dim sObjectNo
	dim oChk, oValue
	dim RsDocNotes
	dim sDocNotes
	
	sDocNotes = ""
	
	Set Conn = CreateObject( "ADODB.Connection" )
	Conn.Open Application.sDbConnectionString
	Set Rs = CreateObject( "ADODB.Recordset" )
	
	'Skapa ett tomt recordset med 3 kolumner
	Set RsDocNotes = CreateObject("ADODB.recordset")
	RsDocNotes.Fields.Append "NoteDate", 133 'adDBDate
	RsDocNotes.Fields.Append "Note", 129, 1024 'adChar
	RsDocNotes.Fields.Append "User", 129, 128 'adChar
	RsDocNotes.Open
	
	sSQL="SELECT DocId FROM tblDocRef WHERE OwnerType = 8 AND OwnerId = <Object1.Id> ORDER BY DocId"
	Rs.Open sSQL, Conn
	
	set oChk=Application.CreateUNChecklist()
	while not Rs.EOF
		if oChk.Open(CLng(Rs("DocId"))) then
			for i = 0 to oChk.Data.NrOfObjectListItems - 1
				set oValue = oChk.Data.GetValue("1_" & oChk.Data.ObjectListNr(i))
				sObjectNo = oChk.Data.ObjectListNr(i)
				
				if not oValue is nothing then
					'wee
				end if
				set oValue = Nothing
			next
			
			'Fylla på data i recordset
			if oChk.Data.Note <> "" then
				RsDocNotes.AddNew
				RsDocNotes("NoteDate").Value = FormatDateTime(oChk.Data.Date, 2)
				RsDocNotes("Note").Value = oChk.Data.Note
				RsDocNotes("User").Value = oChk.Data.User
				RsDocNotes.Update				
			end if
		end if
		Rs.Movenext
	wend
	set oChk = nothing
	
	'Sortera recordset och gå till första posten
	RsDocNotes.Sort = "NoteDate ASC"
	RsDocNotes.MoveFirst
	
	'Loopa ut recordsetet och skapa en sträng
	while not RsDocNotes.EOF
		sDocNotes = sDocNotes & "[" & RsDocNotes.Fields.Item("NoteDate") & "] " & RsDocNotes.Fields.Item("Note") & " /" & RsDocNotes.Fields.Item("User") & VbCrLf
		RsDocNotes.MoveNext
	wend 
	
	Response.write sDocNotes
	
	Rs.Close
	Set Rs=Nothing
	RsDocNotes.Close
	Set RsDocNotes=Nothing
	Set Conn=Nothing
```

Är det ok, eller kan det förbättras?

Mvh
Henrik

Permalänk: https://www.webforum.nu/p/2219274

---

Tråden på webben: https://www.webforum.nu/amne/asp/181924-sortera