---
title: "problem med Upload.Form"
type: "forum-thread"
url: "https://www.webforum.nu/amne/asp/169728-problem-med-upload-form"
topic: "ASP"
topic_url: "https://www.webforum.nu/amne/asp"
author: "SteveP"
published: "2008-03-08T21:15:17.000Z"
updated: "2008-03-08T21:53:50.000Z"
replies: 1
views: 448
page: 1
pages: 1
language: "sv-SE"
site: "webForum — webforum.nu"
rights: "Upphovsrätten till varje inlägg tillhör dess författare."
attribution: "Citera som: webForum, https://www.webforum.nu/amne/asp/169728-problem-med-upload-form"
---

# problem med Upload.Form

## #1 — SteveP, 2008-03-08T21:15Z

Jag använder mig av ASPUPLOAD och ASPJPEG för att ladda upp en bild som sedan gör en kopia av bilden, ändrar storlek på den och sparar kopian som en thumbnail. Detta fungerar utmärkt men problemet är att jag inte vill ladda upp alla bilder i samma mapp, utan istället ladda upp bilden till den mappen jag valt i en dropdown när jag laddar upp bilden.

Jag måste ta emot katalognamnet genom att använda :
Upload.Form("Foldername")
Men problemet är att jag inte får nåt värde från **Upload.Form("Foldername")**  förens jag lägger den efter **Set File = Upload.Files(1)**

Men jag vill ta emot värdet högst upp eftersom jag vill använda variablen till att specificera katalogen.

Som ni ser nu så blir pathen "d:\\www\\mypage\\html\\pictures\\pictures\\" eftersom jag inte får med foldername värdet.

Verkar som att pathen måste specifieras högst upp och detta är ju problemet.
Hur ska jag göra för att få med Foldername variabeln i pathen ?

```
Set Upload = Server.CreateObject("Persits.Upload")

[B]foldername = Upload.Form("Foldername")[/B]

[B]Path = "d:\www\mypage\html\pictures\pictures\" & foldername [/B]

Count = Upload.Save(Path)

If Count = 0 Then
  Response.Write "No images selected."
  Response.End
Else

  [B]Set File = Upload.Files(1)[/B]

  	If File.ImageType <> "UNKNOWN" Then

    Set jpeg = Server.CreateObject("Persits.Jpeg")

    jpeg.Open( File.Path )

    jpeg.PreserveAspectRatio = True

    L = 78

    jpeg.Width = L

    SavePath = Path & "\small_" & File.ExtractFileName

    If UCase(Right(SavePath, 3)) <> "JPG" Then
      SavePath = SavePath & ".jpg"
    End If

    jpeg.Save SavePath

    ' Save both images in the database along with description.

	set rs= Server.CreateObject("ADODB.Recordset")
	SQL= "SELECT * FROM tblPICS"
	rs.Open SQL,Conn,1,2
	rs.AddNew

    ' Use File.Binary to access binary data of uploaded file.
    rs("original_image")= Upload.Files(1).Filename
    Set ThumbFile = Upload.OpenFile(SavePath)
    rs("thumbnail") = "small_" & Upload.Files(1).Filename
    rs("picinfo") = Upload.Form("picinfo")
    rs("category") = Upload.Form("cat")
    rs.Update
    rs.Close
    Set rs = Nothing

  Else
    Response.Write "This is not a valid image."
    Response.End
  End If
End If
```

Permalänk: https://www.webforum.nu/p/169728

## #2 — SteveP, 2008-03-08T21:53Z

Jag löste det genom att använda File.Move och flytta första bilden från pictures katalogen till katalogen jag fick i värdet Upload.Form("foldername") 

Thumbnailen sparade jag också genom att använda Upload.Form("foldername")  då båda dessa kunde göras efter 
Set File = Upload.Files(1) hade skapats.

```
Set Upload = Server.CreateObject("Persits.Upload")

Path = "d:\www\mypage\html\pictures\pictures\"

Count = Upload.Save(Path)

If Count = 0 Then
  Response.Write "No images selected."
  Response.End
Else

  Set File = Upload.Files(1)

	[B]File.move "d:\www\mypage\html\pictures\pictures\" & Upload.Form("foldername") & "\" & File.ExtractFileName[/B]

  	If File.ImageType <> "UNKNOWN" Then

    Set jpeg = Server.CreateObject("Persits.Jpeg")

    jpeg.Open( File.Path )

    jpeg.PreserveAspectRatio = True

    L = 78

    jpeg.Width = L

    [B]SavePath = "d:\www\mypage\html\pictures\pictures\" & Upload.Form("foldername") & "\small_" & File.ExtractFileName[/B]

    If UCase(Right(SavePath, 3)) <> "JPG" Then
      SavePath = SavePath & ".jpg"
    End If

    jpeg.Save SavePath

    ' Save both images in the database along with description.

	set rs= Server.CreateObject("ADODB.Recordset")
	SQL= "SELECT * FROM tblPICS"
	rs.Open SQL,Conn,1,2
	rs.AddNew

    ' Use File.Binary to access binary data of uploaded file.
    rs("original_image")= Upload.Files(1).Filename
    Set ThumbFile = Upload.OpenFile(SavePath)
    rs("thumbnail") = "small_" & Upload.Files(1).Filename
    rs("picinfo") = Upload.Form("picinfo")
    rs("category") = Upload.Form("cat")
    rs.Update
    rs.Close
    Set rs = Nothing

  Else
    Response.Write "This is not a valid image."
    Response.End
  End If
End If
```

Permalänk: https://www.webforum.nu/p/2086939

---

Tråden på webben: https://www.webforum.nu/amne/asp/169728-problem-med-upload-form