Aspjpeg problem

Har gjort en upload med aspjpeg. Halva bilden blir grå...undrar lite vart jag kan ha tänkt fel i mitt kodande här kommer koden...

<% If Request.Querystring("spara") = "foto" Then

If session("eree") = "ja" THEN
mappid = Request.Querystring("mappid")
Set Upload = Server.CreateObject("Persits.Upload")

Upload.OverwriteFiles = False
Upload.SetMaxSize 100000, False

Upload.Save(Server.MapPath("../../uploadbilder/"))
Set File = Upload.Files("file")
	
If Not File Is Nothing Then
        ' Är det en bild?
	If File.ImageType = "UNKNOWN" Then
		File.Delete
		Response.Write("Filen du försöker ladda upp är ingen bild...")
		Response.End
End If

' Skapa AspJpeg Objekten
	Set JpegPic	= Server.CreateObject("Persits.Jpeg")
	Set JpegTmb	= Server.CreateObject("Persits.Jpeg")
	
' Välj ett filnamn (File.Name är 'originalnamnet') och spara filen
	FilNamn = Upload.Files("file").ExtractFileName
	File.Move Server.MapPath("../../uploadbilder") & "/" & FilNamn
	
' Öppna den uppladdade bilden för att skala om den:
    JpegPic.Open Server.MapPath("../../uploadbilder") & "/" & FilNamn

' Om storleken ä'r större än 400px, skala ner den till 400px, behåll proportionerna.
If JpegPic.Width > JpegPic.Height Then
   'Liggande bild.
   If JpegPic.Width > 400 Then
	mWidth = 400
	JpegPic.PreserveAspectRatio = True
	JpegPic.Width = mWidth
   End If
Else
   'Stående bild
   If JpegPic.Height > 400 Then
	mHeight = 400
	JpegPic.PreserveAspectRatio = True
	JpegPic.Height = mHeight
   End If
End If

' Spara bilden
	JpegPic.Save Server.MapPath("../../uploadbilder") & "/" & FilNamn

	tWidth	= JpegPic.Width
	tHeight	= JpegPic.Height
	
' Öppna bilden en gång till för att skapa miniatyr:			
	JpegTmb.Open Server.MapPath("../../uploadbilder/") & "/" & FilNamn
	mHeight = 85
	JpegTmb.PreserveAspectRatio = True
	JpegTmb.Height = mHeight

' Spara miniatyr
	JpegTmb.Save Server.MapPath("../../uploadbilder/pics") & "/" & FilNamn

'Spara in till databas

	Set Connect = Server.CreateObject("ADODB.Connection")
	Connect.Open "driver={Microsoft Access Driver (*.mdb)};dbq=" & Server.MapPath("../../../db/bild_bank.mdb") & ";pwd=olle;"
	Set RecSet = Server.CreateObject("ADODB.Recordset")

	Adbild = "SELECT * FROM bild"
	RecSet.Open Adbild, Connect, adOpenDynamic, adLockOptimistic

RecSet.AddNew

	If FilNamn <> "" Then
	RecSet("filnamn") = FilNamn
	end if
	
	If Upload.Form("kommentar") <> "" Then
	RecSet("kommentar") = Upload.Form("kommentar")
	End If
	
	If Upload.Form("skapad") <> "" Then
	RecSet("skapad") = Upload.Form("skapad")
	End If
	
	If Upload.Form("mappid") <> "" Then
	RecSet("mappid") = Upload.Form("mappid")
	End If
		
	RecSet.Update

	RecSet.Close
	Set RecSet = Nothing

	Connect.Close
	Set Connect = Nothing
	
' Stäng objekten
	Set JpegPic		= Nothing
	Set JpegTmb		= Nothing
	
	End If
	Set Upload		= Nothing

	end if
	
	Response.Redirect("default.asp?meny=bildbank&skapa=bild&mappid="&mappid&"&status=Bilden är sparad")
%>

<% end if %>