---
title: "Hämta XML data"
type: "forum-thread"
url: "https://www.webforum.nu/amne/asp/155866-hämta-xml-data"
topic: "ASP"
topic_url: "https://www.webforum.nu/amne/asp"
author: "asp"
published: "2007-01-11T12:45:03.000Z"
updated: "2007-03-20T18:01:45.000Z"
replies: 11
views: 1028
page: 1
pages: 1
language: "sv-SE"
site: "webForum — webforum.nu"
rights: "Upphovsrätten till varje inlägg tillhör dess författare."
attribution: "Citera som: webForum, https://www.webforum.nu/amne/asp/155866-hämta-xml-data"
---

# Hämta XML data

## #1 — asp, 2007-01-11T12:45Z

Hej.

Skulle någon vänlig själ kunna visa ett enkelt exempel på hur man hämta XML-data från denna sida?

<http://www.managerzone.com/xml/team_matchlist.php?sport_id=1&team_id=78700&match_status=1&limit=50>

Saken är den att nu står det goals="2" istället för \<goals\>2\</goals\> som jag har arbetat med innan.

/ Marcus

Permalänk: https://www.webforum.nu/p/155866

## #2 — Peter S, 2007-01-11T13:59Z

Hej!

```
set node = xmlDoc.documentElement.selectSingleNode("/ManagerZone_MatchList/Match[@id = 149612250]/Team[@field = 'away']")
if not node is nothing then
  response.write node.getAttribute("goals")
end if
```

Permalänk: https://www.webforum.nu/p/1919973

## #3 — asp, 2007-01-11T15:08Z

Tackar. Är lite nybörjare på detta område. Denna kod retunerar inget, inget felmeddelande alltså utan bara tomt.

```
<%
Response.ContentType = "text/plain"

set xmlDoc=Server.CreateObject("Microsoft.XMLDOM")
xmlDoc.async="false"
xmlDoc.load (Server.MapPath("http://www.managerzone.com/xml/team_matchlist.php?sport_id=1&team_id=78700&match_status=1&limit=50"))

set node = xmlDoc.documentElement.selectSingleNode("/ManagerZone_MatchList/Match[@id = 149612250]/Team[@field = 'away']")
if not node is nothing then
	response.write node.getAttribute("goals")
end if
%>
```

/ Marcus

Permalänk: https://www.webforum.nu/p/1920002

## #4 — Peter S, 2007-01-11T15:13Z

Du vill nog inte ha med *Server.MapPath*\-delen.

Vid fel kan du använda följande:

```
xmlDoc.load(...)
if xmlDoc.parseError <> 0 then
  response.write xmlDoc.parseError.reason
end if
```

Permalänk: https://www.webforum.nu/p/1920005

## #5 — asp, 2007-01-11T15:15Z

Hej igen.

Vill inte vara krävande på något vis. Men tanken är att jag skall loop igenom alla matcher. Så om någon väldigt vänlig själ hade lust att hjälpa med göra en funktion som ser ut något såhär:

```
For i = 0 to node.all
      hemmalag = node.getAttribut("home")
      bortalag = node.getAttribut("away")
      hemmaid = node.getAttribut("teamid")
      'osv...

      'Spara enskild match i databasen. Klarar jag själv dock ;-)
Next
```

Permalänk: https://www.webforum.nu/p/1920006

## #6 — Peter S, 2007-01-12T01:11Z

```
set nodes = obj.documentElement.selectNodes("Match")
for each node in nodes
  'home team
  set home = node.selectSingleNode("Team[@field = 'home']")
  homeGoals = home.getAttribute("goals")
  'away team
  set away = node.selectSingleNode("Team[@field = 'away']")
  awayGoals = away.getAttribute("goals")
  
  '...
next
```

Permalänk: https://www.webforum.nu/p/1920122

## #7 — asp, 2007-01-12T11:40Z

Tusen tack Peter.

Fungerade dock inte med förra XLM-kopplingen, dock med denna:

```
set xml = createObject("Msxml.DOMDocument")
xml.async = false
xml.setProperty "ServerHTTPRequest", true
xml.load("http://www.managerzone.com/xml/team_matchlist.php?sport_id=1&team_id=78700&match_status=1&limit=50")
```

/ Marcus

Permalänk: https://www.webforum.nu/p/1920191

## #8 — Peter S, 2007-01-12T11:41Z

Bra att veta  (y)

Permalänk: https://www.webforum.nu/p/1920192

## #9 — asp, 2007-01-14T12:23Z

```
set nodes = xml.documentElement.selectNodes("Match")
for each node in nodes
```

Finns det något sätt att loopa igenom backlänges istället. Så den börjar med den äldsta matchen, d.v.s. längst ner på sidan.

Permalänk: https://www.webforum.nu/p/1923617

## #10 — Peter S, 2007-01-14T15:51Z

```
for i = nodes.length-1 to 0 step -1
  set home = nodes.item(i).selectSingleNode("Team[@field = 'home']")
  ...
```

Permalänk: https://www.webforum.nu/p/1923655

## #11 — asp, 2007-01-14T17:09Z

Tackar ännu en gång. Får se om det blir det slutgiltiga svaret denna gång... =)

Permalänk: https://www.webforum.nu/p/1923673

## #12 — halo.beauty, 2007-03-20T18:01Z

Fick du till det? kan du skriva ut HELA koden? sitter själv och klurar på detta men kommer ingen vart alls  x(

Permalänk: https://www.webforum.nu/p/1949719

---

Tråden på webben: https://www.webforum.nu/amne/asp/155866-hämta-xml-data