---
title: "Skriv asp-kod med WriteLine"
type: "forum-thread"
url: "https://www.webforum.nu/amne/asp/144847-skriv-asp-kod-med-writeline"
topic: "ASP"
topic_url: "https://www.webforum.nu/amne/asp"
author: "Oputres"
published: "2006-03-31T12:04:18.000Z"
updated: "2006-03-31T23:08:43.000Z"
replies: 5
views: 597
page: 1
pages: 1
language: "sv-SE"
site: "webForum — webforum.nu"
rights: "Upphovsrätten till varje inlägg tillhör dess författare."
attribution: "Citera som: webForum, https://www.webforum.nu/amne/asp/144847-skriv-asp-kod-med-writeline"
---

# Skriv asp-kod med WriteLine

## #1 — Oputres, 2006-03-31T12:04Z

Allå!

Jag använder FSO för att skapa en mapp och i den mapp skapa en default.asp-fil. När den är klar skall den se ut så här:

```
<%
Option Explicit
Response.Buffer = True
%>

<!-- #include file="../inst/dbanslutning_medlem2.asp" -->

<%
Dim User, RS, strKontonamn, strAnvId, blnAktiverat
'############## ANGE KONTONAMN NEDAN ##############
strKontonamn = "Donald" 'Namn hämtat från strKontonamn-variabeln
'##################################################

Set RS = Connect.Execute("Select AnvId, OrgNamn, Aktiverat From AnvDb Where Kontonamn = '" & strKontonamn & "';")

If Not RS.EOF Then
  blnAktiverat = CBool(RS("Aktiverat"))
End If

If RS.EOF Then
  Response.Redirect("error_fyranollfyra.asp")
ElseIf blnAktiverat = False Then
  Response.Redirect("error_inactive.asp")
Else
  strAnvId = RS("AnvId")
End If
%>

<!DOCTYPE HTML PUBLIC "-//W3C//DTD HTML 4.01 Frameset//EN" "http://www.w3.org/TR/html4/frameset.dtd">
<html>
<head>
  <title><% =RS("OrgNamn") %></title>
  <meta http-equiv="Content-Type" content="text/html; charset=iso-8859-1">
</head>

<frameset rows="*,1" cols="*" framespacing="0" frameborder="NO" border="0">
  <frame src="../ks/default.asp?AnvId=<% =strAnvId %>">
  <frame src="../bottom.htm" scrolling="NO" noresize>
</frameset>
<noframes><body>

</body></noframes>
</html>
```

Till min hjälp har jag fått följande exempel:

```
SkapaFil.WriteLine("Hej "& strKontonamn &", detta är din unika fil.<br>")
```

Men hur går det då att skriva asp-tecken i denna process? Ta t.ex. den här raden:

```
<!-- #include file="../inst/dbanslutning_medlem2.asp" -->
```

När jag kommer till "-tecknet kommer ju WriteLine stoppa här. Likaså har jag ju \<% och %\>-tecken som skall in. Måste jag här leta upp alla alternativa koder, typ &nbsp; för mellanslag (den enda jag kan utantill  :)) och skriva:

```
SkapaFil.WriteLine("[I]&knasigkodförprocent;[/I] "& strKontonamn &" m.m.<br>")
```

 eller finns det ett enklare sätt?

Vad händer om jag skriver **SkapaFil.WriteLine(""")**. Blir det ett " av det?

Och slutligen den här raden: 
\<!DOCTYPE HTML PUBLIC "-//W3C//DTD HTML 4.01 Frameset//**EN**" "http://www.w3.org/TR/html4/frameset.dtd"\>
Står EN för engelska och skall bytas ut mot SV om det är en svensk sida?

Permalänk: https://www.webforum.nu/p/144847

## #2 — @nders, 2006-03-31T12:09Z

Citationstecken escapeas med citationstecken. Ska du skriva ett citationstecken till fil blir det alltså:

```
SkapaFil.WriteLine("""")
```

Så i alla strängar där du har citationstecken måste du istället ha två. Om du ska ha med contextswitchar så måste du dela på dem:

```
SkapaFil.WriteLine("<" & "%")
' resp
SkapaFil.WriteLine("%" & ">")
```

Permalänk: https://www.webforum.nu/p/1792316

## #3 — Oputres, 2006-03-31T21:32Z

Får det inte att fungera   :( 

Till exempel ger följande kod:

```
SkapaFil.WriteLine("Set RS = Connect.Execute(""""Select AnvId, OrgNamn, Aktiverat From AnvDb Where Kontonamn = '"""" & strKontonamn & """"';"""")")
```

det här resultatet:

```
Set RS = Connect.Execute(""Select AnvId, OrgNamn, Aktiverat From AnvDb Where Kontonamn = '"" & strKontonamn & ""';"")
```

vilket bjuder på det här felmeddelandet:

```
Microsoft VBScript compilation  error '800a03ee'

Expected ')'

/test/default.asp, line 6

Set RS = Connect.Execute(""Select AnvId, OrgNamn, Aktiverat From AnvDb Where Kontonamn = '"" & strKontonamn & ""';"")
---------------------------^
```

Hur trycker jag dit enbart ett citationstecken?  :q

Permalänk: https://www.webforum.nu/p/1792427

## #4 — Oputres, 2006-03-31T21:34Z

Ps. I övrigt fungerar det utmärkt, det är alltså bara citationstecknen som lurar Ds.

Permalänk: https://www.webforum.nu/p/1792428

## #5 — Jesper T, 2006-03-31T21:53Z

Överdriv inte med citationstecken.  ;) 

```
SkapaFil.WriteLine("Set RS = Connect.Execute(""Select AnvId, OrgNamn, Aktiverat From AnvDb Where Kontonamn = '"" & strKontonamn & ""';"")")
```

Permalänk: https://www.webforum.nu/p/1792435

## #6 — Oputres, 2006-03-31T23:08Z

Se där, det fungerade ju utmärkt.

En dag kommer jag titta tillbaka på min kod ovan och skämmas :)

Permalänk: https://www.webforum.nu/p/1792443

---

Tråden på webben: https://www.webforum.nu/amne/asp/144847-skriv-asp-kod-med-writeline