---
title: "ASP: Skapa fakturanummer per automatik."
type: "forum-thread"
url: "https://www.webforum.nu/amne/asp/143502-asp-skapa-fakturanummer-per-automatik"
topic: "ASP"
topic_url: "https://www.webforum.nu/amne/asp"
author: "oskars"
published: "2006-03-06T12:35:26.000Z"
updated: "2006-03-07T22:19:14.000Z"
replies: 5
views: 553
page: 1
pages: 1
language: "sv-SE"
site: "webForum — webforum.nu"
rights: "Upphovsrätten till varje inlägg tillhör dess författare."
attribution: "Citera som: webForum, https://www.webforum.nu/amne/asp/143502-asp-skapa-fakturanummer-per-automatik"
---

# ASP: Skapa fakturanummer per automatik.

## #1 — oskars, 2006-03-06T12:35Z

Hej,

  :i 

jag har ett grymt bra och enkelt beställningsformulär som bl.a Erik hjälpt mig att göra. Det bygger på en \<form\> och en .ASP-fil som skickar mailet.

Jag får alltså alla beställningar som skickas med formuläret via mail. Och nu vill jag att varje beställning ska ha ett unikt ordernummer, t.ex Erik01, Erik02, Erik03 osv osv. Planen är ju att inte använda en databas utan att lagra dessa nummer i en textfil...

Jag hoppas ni förstår vad jag menar. Hur skulle en kod för detta se ut? 

Tacksam för hjälp!

Mvh / Oskar   :)

Permalänk: https://www.webforum.nu/p/143502

## #2 — Jesper T, 2006-03-06T12:38Z

```
Function AlmostUniqueID(n)
 
  AlmostUniqueID= n & Month(Now) & Day(Now) & Year(Now) & Hour(Now) _
    & Minute(Now) & Second(Now)

End Function

Response.Write AlmostUniqueId("Erik")
```

Permalänk: https://www.webforum.nu/p/1777494

## #3 — oskars, 2006-03-06T13:12Z

Hm. Jag vill att ID:et ska vara kontinuerligt.. Alltså så här:

FP0601
FP0602
FP0603
FP0604
FP0605
FP0606
FP0607

\=)

Visserligen såg ditt smart ut! Ska fundera på det! Men det vore bra med ett sånt system jag skrev här över! =)

Permalänk: https://www.webforum.nu/p/1777502

## #4 — Fredde Mannen, 2006-03-06T13:33Z

det vore väl att börja räkna från 1, 100 eller vad som önskas, så första ordern blir FP100, så när nästa order görs så hämtas sista raden från textfilen, där förhoppningsvis FP100 finns, och plockar ut siffrorna och ökar med 1 och sparar den nya ordern som då blir FP101, har inget kodexempel, det är bara en tankegång! :)

Permalänk: https://www.webforum.nu/p/1777506

## #5 — oskars, 2006-03-07T19:39Z

Ja jo, någon som har kodtips? =)

Permalänk: https://www.webforum.nu/p/1778134

## #6 — Jesper T, 2006-03-07T22:19Z

Det räcker kanske med en räknare.
Skapa en textfil som du döper till ex. my_count.txt
och se till att du har skrivrättigheter i katalogen.

```
Class uniqueId
	Private fn, objFso
	
	Public property Let Filename(value)
		fn = value
	End property
	
	Private Function GetLastID()
		Dim objFile
		on error resume next
		set objFile = objFso.OpenTextFile(fn, 1)
		If err.number = 62 then
			GetLastID = 0
		Else
			GetLastID = trim(objFile.ReadLine)
		End if
		objFile.Close : Set objFile = Nothing
	End Function
	
	Private Function SetUniqueId()
		Dim lastRow
		lastRow = GetLastID()
		set objFile = objFSO.OpenTextFile(fn, 2)
		lastRow = cStr(cLng("0"& lastRow)+1)
		objFile.Write lastRow
		SetUniqueId = lastRow	
		objFile.Close : Set objFile = Nothing
	End Function
	
	Public Function MakeUniqueId()
		Set objFso = Server.CreateObject("Scripting.FileSystemObject")
			MakeUniqueId = SetUniqueId()
		Set objFso = Nothing
	End Function
	
End Class

Dim q
Set q = new uniqueId
q.Filename = Server.Mappath(".") & "\my_count.txt"
Response.write "SuperID_"& q.MakeUniqueId()
Set q = nothing
```

Permalänk: https://www.webforum.nu/p/1778197

---

Tråden på webben: https://www.webforum.nu/amne/asp/143502-asp-skapa-fakturanummer-per-automatik