Jag försöker returnera ett recordset, med denna enkla funktion:
function returnRS(SQL)
Dim conn
Set conn = Server.CreateObject("ADODB.Connection")
Set rs = Server.CreateObject("ADODB.RecordSet")
conn.Open ("Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & Server.MapPath(strDatabasePath) )
set rs = conn.execute(SQL)
set returnRS = rs
end function
som jag anropar med
set rs = returnRS(SQLstr)
men jag får
Item cannot be found in the collection corresponding to the requested name or ordinal.
på den första raden där jag skall hämta ur recordset:et på sidan:
Men om jag använder en array kan jag väl inte loopa igenom "recordsetet" på samma sätt? Det är väl mest bra ifall man vill ha ut en rad och enbart en, typ..? Eller har jag missuppfattat det helt? :q Har faktiskt aldrig använt getRows.. :l
Yada, yada. Om det är en sub eller function har ingen betydelse för vilket scope som objekt har.
Jo, jag skulle nog göra skapa connection-objektet utanför sub
dim conn
set conn = server.createobject("adodb.connection")
och sedan skicka det som parameter till din funktion där du kan kolla om det behöver öppnas eller inte
function (conn,sqlstr)
if conn.state = 0 then 'adStateClosed
conn.Open ("Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & Server.MapPath(strDatabasePath) )
end if
set returnRS = conn.execute(sqlstr)
end function
red: Det som händer i din kod är att recordsetet stängs när ditt conn-objekt försvinner.
------------------ essentitia preter non sans multiplicandum
Det är superenkelt! Eftersom att jag är så dålig på att förklara, visar jag med lite kod istället...
Function getRows ( sSQL )
Dim conn
set conn = Server.CreateObject ( "ADODB.Connection" )
conn.Open ( "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & Server.MapPath ( strDatabasePath ) )
set rs = conn.execute ( sSQL )
If rs.EOF Then
rs.Close
conn.Close
set rs = Nothing
set conn = Nothing
getRows = Null
Else
Dim arrRows
arrRows = rs.GetRows ()
rs.Close
conn.Close
set rs = Nothing
set conn = Nothing
getRows = arrRows
End If
End Function
Dim arrRows
arrRows = getRows ( "SELECT fldName, fldEmail FROM users WHERE id = " & Session ( "userid" ) )
If IsArray ( arrRows ) Then
Dim i
For i = lBound ( arrRows, 2 ) To uBound ( arrRows, 2 )
Response.Write "Namn: " & arrRows ( 0, i ) ' 0:an anger vilket fält som ska hämtas, i från vilken rad
Response.Write "<br/>"
Response.Write "E-mail: " & arrRows ( 1, i )
Next
Else
Response.Write "Inga poster"
End If
Det är lite som skiljer, dvs. bör du ange vilka fält som ska hämtas med SQL-frågan, så att du vet i vilken ordning du får dem. Arrayen använder du sedan som en vanlig tvådimensionell array, med fältet i första dimensionen och värdet på fältet i andra dimensionen.
Hoppas det blev lite klarare, annars får någon mer pedagogisk försöka... ;)
