---
title: "Nytt Script på wF Script!"
type: "forum-thread"
url: "https://www.webforum.nu/amne/asp/13579-nytt-script-på-wf-script/page5"
topic: "ASP"
topic_url: "https://www.webforum.nu/amne/asp"
author: "PatrikB"
published: "2001-05-03T22:22:00.000Z"
updated: "2002-01-05T19:09:00.000Z"
replies: 95
views: 786
page: 5
pages: 5
language: "sv-SE"
site: "webForum — webforum.nu"
rights: "Upphovsrätten till varje inlägg tillhör dess författare."
attribution: "Citera som: webForum, https://www.webforum.nu/amne/asp/13579-nytt-script-på-wf-script"
---

# Nytt Script på wF Script!

_Sida 5 av 5._

## #81 — LarsG, 2001-11-04T20:21Z

I tabellen forum_svar borde det finnas en kolumn som anger vilket forum ett visst svar tillhör. Det är det namnet och vilken kolumn i forum den är kopplad till som är relevant.

Sen så bör du inte döpa en kolumn till count då det är ett reserverat ord i SQL.

Permalänk: https://www.webforum.nu/p/302913

## #82 — jimpa, 2001-11-04T20:35Z

Hej,

Nu hänger jag inte med riktigt! **SvarID** är samma ID till aktuellt inlägg. 

Mvh

Permalänk: https://www.webforum.nu/p/302914

## #83 — jimpa, 2001-11-05T19:20Z

Hej,

Behöver lite hjälp här :o :l

Permalänk: https://www.webforum.nu/p/302915

## #84 — LarsG, 2001-11-05T19:56Z

Om du vill joina två tabeller så måste man du ha en kolumn som binder ihop tabellerna, t.ex.

```
sql = "Select * From Forum_svar,forum Where forum.id = forum_svar.forumid SvarID= " & ID & " Order by dte DESC
```

Du måste ha någon kolumn i tabellen forum_svar som visar vilket forum ett svar tillhör.

Permalänk: https://www.webforum.nu/p/302916

## #85 — jimpa, 2001-11-05T21:17Z

Hej,

Provade att skriva så här:

```
SQL = "Select * From Forum_svar,Forum Where Forum_svar.SvarID = Forum.ID = " & [ID]
```

Inga felmeddelande men nu hittas det heller inga poster :o
**Forum.ID** och **Forum_svar.SvarID** är lika!?

Spelar det någon roll om man har samma namn på fälten i dom olika tabellerna??

Mvh

Permalänk: https://www.webforum.nu/p/302917

## #86 — LarsG, 2001-11-05T21:27Z

Nej, namnen har ingen betydelse

```
SQL = "Select * From Forum_svar,Forum Where Forum_svar.SvarID = Forum.ID and forum.svarID = " & ID
```

Permalänk: https://www.webforum.nu/p/302918

## #87 — jimpa, 2001-11-05T22:01Z

Hej,

Nu funka det betydligt bättre :)
Men hur gör jag nu för att hämta värdet i Tabellen Forum ?

Mvh

Permalänk: https://www.webforum.nu/p/302919

## #88 — LarsG, 2001-11-05T22:04Z

Det är som vanligt

```
set rs = connect.execute(sql)
while not rs.eof 
c = rs("count")
rs.movenext
wend
```

det är bara kolumnnamnet som har betydelse, inte i vilken tabell den finns.

Permalänk: https://www.webforum.nu/p/302920

## #89 — jimpa, 2001-11-05T22:12Z

Hej

Ok! TACK o BOCK :)

Mvh

Permalänk: https://www.webforum.nu/p/302921

## #90 — Sico, 2002-01-05T17:06Z

Problem... 
Pageingen funkar perfekt men det e layouten av det hela.. Jag har använt mig "varannan-färg-på-tables"-koden jag hittade här på FAQ. Den funkade perfekt innan jag la in pageingen men nu får jag det inte å funka. 

```
<%
Function getRecords
	Dim m_objConn
	Dim m_strConnString
	Dim m_strSQL
	Dim m_objRS
	Dim m_arrRecords
		
	m_strConnString = "provider=Microsoft.Jet.OLEDB.4.0;" & _
		"Data Source=" & Server.MapPath("/guestbook/guestbook.mdb")

	Set m_objConn = Server.CreateObject("ADODB.Connection")
		m_objConn.Open m_strConnString

		m_strSQL = "SELECT f_ID, f_Title, f_Name, f_Text, f_Date, f_Time FROM t_Guestbook Order By f_ID DESC"

			Set m_objRS = m_objConn.Execute(m_strSQL)
			
				If Not m_objRS.EOF Then
					m_arrRecords = m_objRS.GetRows
					getRecords = m_arrRecords
				End If
				
				m_objRS.Close
			Set m_objRS = Nothing
			
		m_objConn.Close
	Set m_objConn = Nothing

End Function

Sub PrevPage(ByVal WichPage)
	Dim strScriptName
	strScriptName = Request.ServerVariables("SCRIPT_NAME")

	If CInt(WichPage) > 1 Then
		Response.Write "<A href='" & strScriptName & "?" & _
			"page=" & WichPage - 1 & "'> Föregående</A> "
	Else
		Response.Write " Föregående "
	End If
End Sub

Sub NextPage(ByVal HowManyPages, ByVal WichPage)
	Dim strScriptName
	strScriptName = Request.ServerVariables("SCRIPT_NAME")
	
	If CInt(WichPage) < CInt(HowManyPages) Then
		Response.Write "<A href='" & strScriptName & "?" & _
			"page=" & WichPage + 1 & "'>Nästa </A>"
	Else
		Response.Write " Nästa "
	End If

End Sub

Sub PageNumbers(ByVal HowManyPages, WichPage)
	Dim strScriptName
	Dim I
	
	If HowManyPages = 0 Then
		Response.Write "0"
		Exit Sub
	End If
	
	strScriptName = Request.ServerVariables("SCRIPT_NAME")

	For I = 1 To HowManyPages
		If CInt(I) <> CInt(WichPage) Then
			Response.Write "<A href='" & strScriptName & "?" & _
				"page=" & I & "'>" & I & "</A> "
		Else
			Response.Write "<B>" & I & "</B> "
		End If
	Next

End Sub

Function getStartID(ByVal PageSize, ByVal ViewPage) ' As Integer
	Dim m_intStart
	m_intStart = ((PageSize * ViewPage) - PageSize)
	getStartID = m_intStart
End Function

Function countPages(ByVal HowManyRecords, ByVal PageSize)
	Dim m_intTotalPages, m_intRest

	m_intTotalPages = HowManyRecords / PageSize

	If m_intTotalPages < 1 Then
		m_intTotalPages = 1
	Else
		m_intRest = m_intTotalPages - CLng(m_intTotalPages)
		
		If m_intRest > 0 AND m_intRest < 0.5 Then
			m_intTotalPages = CLng(m_intTotalPages) + 1
		Else
			m_intTotalPages = CLng(m_intTotalPages)
		End If
	End If

	countPages = m_intTotalPages
End Function

Dim arrRecords
Dim intPageSize
Dim intPage
Dim intStartID
Dim I
Dim intId
Dim strTitle
Dim strName
Dim strText
Dim strDate
Dim strTime
Dim intTotalPages
Dim intTotalRecords

intPage = Request.QueryString("page")
If intPage = "" Then intPage = 1

intPageSize = 4

arrRecords = getRecords

intStartID = getStartID(intPageSize, intPage)

If IsArray(arrRecords) Then
	'Response.Write "E ju en array<BR>"
	intTotalRecords = UBound(arrRecords,2) + 1
	
	intTotalPages = countPages(intTotalRecords, intPageSize)

	Response.Write "<P>Visar nu sida <B>" & intPage & "</B> av " & intTotalPages & "</P>"
	For I = intStartID To ((intStartID + intPageSize) -1)

		intId = arrRecords(0,I)
		strTitle = arrRecords(1,I)
		strName = arrRecords(2,I)
		strText = arrRecords(3,I)
		strDate = arrRecords(4,I)
		strTime = arrRecords(5,I)

Response.Write	"<table border=0 width=400 cellspacing=0 cellpadding=0>"&_
		  "<tr><td class=smallertext>"&_
			"<b>Rubrik:</b> "& strTitle &"</td></tr>"&_
		  "<tr><td class=smallertext>"&_
			"<b>Namn:</b> "& strName &"</td></tr>"&_
		  "<tr><td class=smallertext>"&_
			""& strDate &" : "& strTime &"</td></tr>"&_
		  "<tr height=10><td></td></tr>"&_
		  "<tr><td class=smallertext>"&_
			""& strText &"</td></tr>"&_
		"</table><br>"

		If I = UBound(arrRecords,2) Then Exit For
	Next
Else
	intPage = 0
	intTotalRecords = 0
	intTotalPages = 0
	
	Response.Write "<P>No records found.</P>"
End If

Call PrevPage(intPage)
Response.Write " &#0124; "

Call NextPage(intTotalPages,intPage)

Response.Write "&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;Pages: "

Call PageNumbers(intTotalPages,intPage)
%>
```

Nån som vet hur jag ska skriva koden för att det ska funka.

Detta är tabell-koden som finns under FAQ här på Asp forumet.

```
<table>
<%
Do Until rs.Eof
cnt = cnt + 1
strColor = "#CCCC66" 
If cnt Mod 2 = 0 then strColor = "#CCCC99"
Response.Write "<tr bgcolor='" & strColor & "'><td>" & rs("namn")& "</td></tr>"
rs.MoveNext
Loop
%>
</table>
```

Permalänk: https://www.webforum.nu/p/302922

## #91 — PatrikB, 2002-01-05T17:50Z

vad innehåller din css-class: smallertext?

innehåller den info om bg-färgen? eller?

cya,
PatrikB

Permalänk: https://www.webforum.nu/p/302923

## #92 — PatrikB, 2002-01-05T17:59Z

```
strTime = arrRecords(5,I)

If I mod 2 = 0 Then
	strBgColor = "#F4F4F4"
Else
	strBgColor = "#FFFFFF"
End If

Response.Write "<table border=0 width=400 cellspacing=0 cellpadding=0>"&_
"<tr><td bgcolor=""" & strBgColor & """ class=smallertext>"&_
"<b>Rubrik:</b> "& strTitle &"</td></tr>"&_
"<tr><td bgcolor=""" & strBgColor & """  class=smallertext>"&_
"<b>Namn:</b> "& strName &"</td></tr>"&_
"<tr><td bgcolor=""" & strBgColor & """  class=smallertext>"&_
""& strDate &" : "& strTime &"</td></tr>"&_
"<tr height=10><td></td></tr>"&_
"<tr><td bgcolor=""" & strBgColor & """  class=smallertext>"&_
""& strText &"</td></tr>"&_
"</table><br>"

If I = UBound(arrRecords,2) Then Exit For
```

som du ser "klippte" jag ned din kod lite och la in det som var väsentligt.

cya,
PatrikB

Permalänk: https://www.webforum.nu/p/302924

## #93 — Sico, 2002-01-05T18:43Z

> Variable is undefined: 'strBgColor'

det felmeddelandet får jag då..

smallertext = lite font å bös... ingen du behöver grubbla på :)

Permalänk: https://www.webforum.nu/p/302925

## #94 — jorgen, 2002-01-05T18:52Z

Hej, misstänker att du använt option explicit längst upp på sidan. Då måste du dimma alla variabler.

lägg till:

```
Dim strBgColor
```

i övriga skaran av dimmar.

mvh Jörgen :)

Permalänk: https://www.webforum.nu/p/302926

## #95 — Sico, 2002-01-05T19:08Z

funka prima.. tackar

Permalänk: https://www.webforum.nu/p/302927

## #96 — Sico, 2002-01-05T19:09Z

funka prima.. tackar

Permalänk: https://www.webforum.nu/p/302928

---

Tråden på webben: https://www.webforum.nu/amne/asp/13579-nytt-script-på-wf-script/page5  
Föregående sida: https://www.webforum.nu/amne/asp/13579-nytt-script-på-wf-script/page4.md