---
title: "Åtgärden som programmet begärt stöds inte av leverantören.."
type: "forum-thread"
url: "https://www.webforum.nu/amne/asp/12985-åtgärden-som-programmet-begärt-stöds-inte-av-leverantören"
topic: "ASP"
topic_url: "https://www.webforum.nu/amne/asp"
author: "Hulth"
published: "2001-12-03T19:24:00.000Z"
updated: "2001-12-04T01:40:00.000Z"
replies: 11
views: 230
page: 1
pages: 1
language: "sv-SE"
site: "webForum — webforum.nu"
rights: "Upphovsrätten till varje inlägg tillhör dess författare."
attribution: "Citera som: webForum, https://www.webforum.nu/amne/asp/12985-åtgärden-som-programmet-begärt-stöds-inte-av-leverantören"
---

# Åtgärden som programmet begärt stöds inte av leverantören..

## #1 — Hulth, 2001-12-03T19:24Z

Varför får jag detta felmedelandet av pws?

Jag har win98 och Access 97

> ADODB.Recordset fel '800a0cb3' 
>
> Åtgärden som programmet begärt stöds inte av leverantören. 
>
> /icq/add.asp, rad 15

```
<!--#include file="adovbs.inc"-->
<%
	' Sökvägen till din databas
	db_ad = Server.MapPath("lista.mdb")

	If Request.Querystring("vad") = "save" Then

	Set Connect = Server.CreateObject("ADODB.Connection")
	Connect.Open "driver={Microsoft Access Driver (*.mdb)};dbq=" & db_ad
	
	Set RecSet = Server.CreateObject("ADODB.RecordSet")
	hamta = "SELECT * FROM lista"
	RecSet.Open hamta, Connect, adOpenStatic

	RecSet.AddNew ' <-- rad 15

	RecSet("namn")	= Request.Form("namn")
	RecSet("email")	= Request.Form("email")
	RecSet("icq")	= Request.Form("icq")
	Recset("add")	= Request.Form("add")
	RecSet("ip")	= Request.ServerVariables("REMOTE_ADDR")

	RecSet.Update
	RecSet.Close

	Set RecSet = Nothing
	Connect.Close
	Set Connect = Nothing

	Response.Redirect "visa.asp"

	End If

	If Request.Querystring("vad") = "" Then

	Set db = Server.CreateObject("ADODB.Connection")
	db.Open "Driver={Microsoft Access Driver (*.mdb)}; DBQ="& db_ad
 
	SQL = "SELECT Count(*) From lista"
	Set rs = db.Execute(SQL)

	antal = RS.Fields(0)
%>
<html>
<head>
<title>ICQ-lista ver 1.0 av David Hulth</title>
</head>
<body>
<table align="center" width="700" border="0" cellpadding="0" cellspacing="0">
<tr><td><font face="Verdana" size="4" color="#FF0000">ICQ-listan ver 1.0 av David Hulth</font></td></tr>
<tr><td><font face="Verdana" size="2" color="#003399"><b>Gör som <%=antal%> andra och gå med i ICQ-listan du också</b></font></td></tr>
<tr><td>&nbsp;</td></tr>
<tr><td>
<table align="center" width="100%" border="0" cellpadding="0" cellspacing="0">
<form action="add.asp?vad=save" method="post">
	<tr><td><div align="right"><font face="Verdana" size="1"><b>Ditt namn</b></font></div></td><td>&nbsp;</td><td><input type="text" name="namn"></td></tr>
	<tr><td><div align="right"><font face="Verdana" size="1"><b>Din Email</b></font></div></td><td>&nbsp;</td><td><input type="text" name="email"></td></tr>
	<tr><td><div align="right"><font face="Verdana" size="1"><b>Ditt ICQ-nummer</b></font></div></td><td>&nbsp;</td><td><input type="text" name="icq"></td></tr>
	<tr><td><div align="right"><font face="Verdana" size="1"><b>Auth</b></font></div></td><td>&nbsp;</td><td><select name="auth"><option value="Alltid" selected>Alltid</option><option value="Tillstånd krävs">Tillstånd krävs</option></select></td></tr>
	<tr><td><div align="right"><input type="reset" name="Nollställ"></div></td><td>&nbsp;</td><td><input type="submit" value="Skicka"></td></tr>
</form>
</table>
</td></tr>
</table>
</body>
</html>
<% End If %>
```

Permalänk: https://www.webforum.nu/p/12985

## #2 — @nders, 2001-12-03T19:25Z

Om du ska lägga till data kan du nog inte öppna ditt recordset med en statisk cursor. Försök med adOpenDynamic istället för adOpenStatic, eller ännu hellre, skriv en INSERT-fråga för att lägga till data.

Mvh,

Permalänk: https://www.webforum.nu/p/299695

## #3 — Hulth, 2001-12-03T20:11Z

kom på det nu.. är lite trött... ;)

Permalänk: https://www.webforum.nu/p/299696

## #4 — Hulth, 2001-12-03T20:15Z

Hur skriver jag en insert? vad ska jag ersätta då?

är lite rookie på databaser.. kör alltid med recordset

Permalänk: https://www.webforum.nu/p/299697

## #5 — @nders, 2001-12-03T20:17Z

Jag hjälper dig en liten bit på väg, med syntaxen. :)

```
strSQL = "INSERT INTO tblTable (fldField1, fldField2, fldField3) VALUES ('" & strValue1 & "', " & intValue1 & ", #" & dteValue1 & "#)"
```

Det blir lite krångligare, men det blir färre kodrader, bättre prestanda, och du blir en bättre man. Eller kvinna. :)

Mvh,

Permalänk: https://www.webforum.nu/p/299698

## #6 — Hulth, 2001-12-03T20:24Z

Föredrar man..

ska genast testa din kod..

Permalänk: https://www.webforum.nu/p/299699

## #7 — Hulth, 2001-12-03T20:25Z

Hur ska jag anropa insert-koden då?

Permalänk: https://www.webforum.nu/p/299700

## #8 — Hulth, 2001-12-03T20:29Z

Du tror inte du kunde skriva fullständig kod inklusive koppling till databas?

alla variabler osv finns i första inlägget i denna tråden..

Permalänk: https://www.webforum.nu/p/299701

## #9 — LarsG, 2001-12-03T20:42Z

Det är några besvärligheter med insert. Det första är att man måste anpassa sig till vilka datatyper som kolumnerna har, nu förutsätter jag att alla kolumner är av typen text och dessa värden skall anges inom ' i insert-statementet. Om det är numeriska värden så anger man inget alls. Anledningen till att jag gör replace är att det annars skulle bli fel om värdet i sig innehåller en '

Ett annat problem är reserverade ord. Nu har du använt ADD som kolumnnamn och då det är ett reserverat ord i SQL så måste man ange det inom \[\]. Det är kanske bäst att byta namn om du skall börja använda sql direkt.

```
If Request.Querystring("vad") = "save" Then

Set Connect = Server.CreateObject("ADODB.Connection")
Connect.Open "driver={Microsoft Access Driver (*.mdb)};dbq=" & db_ad

sql = "insert into lista(namn,email,icq,[ADD],ip) values ('" & _
replace(request.form("namn"),"'","''") & "','" & _
replace(request.form("email"),"'","''") & "','" & _
replace(request.form("icq"),"'","''") & "','" & _
replace(request.form("add"),"'","''") & "','" & _
request.server_variables("REMOTE_ADDR") & "')"
connect.execute sql,,128

Connect.Close
Set Connect = Nothing

end if
```

Permalänk: https://www.webforum.nu/p/299702

## #10 — Hulth, 2001-12-03T20:53Z

Jag har ändrat add till auth... är denna koden rätt då?

```
If Request.Querystring("vad") = "save" Then
Set Connect = Server.CreateObject("ADODB.Connection")
Connect.Open "driver={Microsoft Access Driver (*.mdb)};dbq=" & db_ad

sql = "insert into lista(namn,email,icq,auth,ip) values ('" & _
replace(request.form("namn"),"'","''") & "','" & _
replace(request.form("email"),"'","''") & "','" & _
replace(request.form("icq"),"'","''") & "','" & _
replace(request.form("auth"),"'","''") & "','" & _
request.server_variables("REMOTE_ADDR") & "')"
connect.execute sql,,128

Connect.Close
Set Connect = Nothing

end if
```

tack för hjälpen..

Permalänk: https://www.webforum.nu/p/299703

## #11 — LarsG, 2001-12-03T20:59Z

Ja, såvitt jag kan se och under förutsättning att alla kolumner är av typen text.

Permalänk: https://www.webforum.nu/p/299704

## #12 — Hulth, 2001-12-04T01:40Z

Tack för hjälpen Lars.

Allt fungerar.

Permalänk: https://www.webforum.nu/p/299705

---

Tråden på webben: https://www.webforum.nu/amne/asp/12985-åtgärden-som-programmet-begärt-stöds-inte-av-leverantören