---
title: "Tid är tid"
type: "forum-thread"
url: "https://www.webforum.nu/amne/asp/123124-tid-är-tid"
topic: "ASP"
topic_url: "https://www.webforum.nu/amne/asp"
author: "Fraggel"
published: "2005-02-23T17:31:29.000Z"
updated: "2005-02-23T20:26:05.000Z"
replies: 2
views: 223
page: 1
pages: 1
language: "sv-SE"
site: "webForum — webforum.nu"
rights: "Upphovsrätten till varje inlägg tillhör dess författare."
attribution: "Citera som: webForum, https://www.webforum.nu/amne/asp/123124-tid-är-tid"
---

# Tid är tid

## #1 — Fraggel, 2005-02-23T17:31Z

```
 
Function timeSelect()
    Dim HTML
    Dim hrs
    Dim min
    Dim timeVal
    Dim hrsCount,minCount
    HTML = "<select>" & vbCrLf
    For hrsCount=0 to 24
      For minCount = 0 To 3
        hrs = hrsCount
        min = minCount * 15
        If Len(min) = 1 Then
          min = "0" & min 
        End If
        If Len(hrs) = 1 Then
        hrs = "0" & hrs
        End If
        timeVal =  hrs & ":" & min
        HTML = HTML & "<option value=""" & timeVal & """ >" &  timeVal & "</option>" & vbCrLf
      Next
    Next
    HTML = HTML & "</select>" 
    timeSelect = HTML 
  End Function
```

Min önskan är att selected optin skall bli närmaste hela kvart innan "nutid"

Tips ?

Permalänk: https://www.webforum.nu/p/123124

## #2 — Engine^, 2005-02-23T18:50Z

Här är ett tips. Du kan möjligen behöva mickla lite med funktionen, eftersom jag har feber för tillfället och i sådana lägen kan det bli konstig kod ;)

```
function CreateTimeSelect()
  dim dteTime
  dim dteStop
  dim IsSelected
  dim strHtml

  dteTime = TimeSerial(0, 0, 0)
  dteStop = TimeSerial(24, 0, 0)

  IsSelected = false
  strHtml = "<select>"

  while dteTime < dteStop
    if(DateAdd("n", 15, dteTime > Time) and not IsSelected then
      strHtml = strHtml & "<option value=""" & FormatDateTime(dteTime, 4) & """ selected>" &  _
        FormatDateTime(dteTime, 4) & "</option>"

      IsSelected = true
    else
      strHtml = strHtml & "<option value=""" & FormatDateTime(dteTime, 4) & """>" &  _
        FormatDateTime(dteTime, 4) & """</option>"
    end if

    dteTime = DateAdd("n", 15, dteTime)
  wend

  strHtml = strHtml & "</select>"

  CreateTimeSelect = strHtml
end function
```

Permalänk: https://www.webforum.nu/p/1559061

## #3 — Fraggel, 2005-02-23T20:26Z

```
  Function CreateTimeSelect()
    Dim dteTime,dteStop,IsSelected,HTML
    dteTime = TimeSerial(0, 0, 0)
    dteStop = TimeSerial(24, 0, 0)
    IsSelected = False
    HTML = "<select>" & vbCrLf
    While dteTime < dteStop
      If(DateAdd("n", 15, dteTime) > Time) And NOT IsSelected Then
        HTML = HTML & "<option value=""" & FormatDateTime(dteTime, 4) & """ selected>" & FormatDateTime(dteTime, 4) & "</option>" &vbCrLf
        IsSelected = True
      Else
        HTML = HTML & "<option value=""" & FormatDateTime(dteTime, 4) & """>" & FormatDateTime(dteTime, 4) & "</option>" & vbCrLf
    End if
      dteTime = DateAdd("n", 15, dteTime)
    Wend
    HTML = HTML & "</select>" & vbCrLf
    CreateTimeSelect = HTML
  End Function
```

En missad ) det var allt annats så var den som tåget. Tog mig friheten att doda till den lite så den ser ut som resten av min kod...

Tack för hjälpen, detta var vad jag var inne på men detta blev skit snyggt... Mysig kod och jag lärde mig något nytt i dag  nämligen TimeSerial()

Permalänk: https://www.webforum.nu/p/1559116

---

Tråden på webben: https://www.webforum.nu/amne/asp/123124-tid-är-tid