---
title: "Dynamisk update"
type: "forum-thread"
url: "https://www.webforum.nu/amne/asp/123089-dynamisk-update"
topic: "ASP"
topic_url: "https://www.webforum.nu/amne/asp"
author: "jonne"
published: "2005-02-23T09:39:21.000Z"
updated: "2005-02-23T09:56:56.000Z"
replies: 2
views: 461
page: 1
pages: 1
language: "sv-SE"
site: "webForum — webforum.nu"
rights: "Upphovsrätten till varje inlägg tillhör dess författare."
attribution: "Citera som: webForum, https://www.webforum.nu/amne/asp/123089-dynamisk-update"
---

# Dynamisk update

## #1 — jonne, 2005-02-23T09:39Z

På sida 1 har jag två formfält. Vi kallar dessa "ffIn" och "ffUt".
Dessa fylls från befintlig data i databasen och antalet kan variera.

Hur hanterar jag dessa på sida 2 där jag kör update? Om jag har flera än en(1) av ffIn och ffUt så delas värdena upp med komman, men hur placerar jag in dem rätt i min updatesträng?

Permalänk: https://www.webforum.nu/p/123089

## #2 — @nders, 2005-02-23T09:53Z

Jag litar inte på att formulärfält kommer fram i samma ordning som de visas i formuläret (de gör de nämligen inte alltid), så jag brukar göra så här:

\*) Namnge alla fält i formuläret med postens ID som del. På så sätt vet man vilka fält som hör ihop
\*) När värdena tas emot, loopa igenom hela form collection.

Exempel:

```
While not objRS.EOF
	Response.write "<input type=""text"" name=""namn|" & objRS("ID") & """ value=""" & objRS("namn") & """>"
	Response.write "<input type=""text"" name=""adress|" & objRS("ID") & """ value=""" & objRS("adress") & """>"
	Response.write "<input type=""text"" name=""postadress|" & objRS("ID") & """ value=""" & objRS("postadress") & """>"
	objRS.Movenext
Wend
```

```
For each v in Request.Form
	If left(v, 5) = "namn|" then  ' vi ska ju bara göra detta en gång per post, så då bestämmer vi ett fält som ska vara chef.
		lID = clng(split(v,"|")(1))  ' vi plockar ut ID så vi kan sätta ihop de andra fältnamnen.
		sNamn = Replace(Request.Form(v), "'", "''")
		sAdress = Replace(Request.Form("adress|" & lID), "'", "''")
		sPostadress = Replace(Request.Form("postadress|" & lID), "'", "''")
		sSQL = "UPDATE tbl SET namn = '" & sNamn & "', adress = '" & sAdress & "', postadress = '" & sPostadress & "' " &_
		       "WHERE ID = " & lID
		objConn.Execute sSQL,,128
	end if
Next
```

Permalänk: https://www.webforum.nu/p/1558784

## #3 — jonne, 2005-02-23T09:56Z

Tack och bock

Permalänk: https://www.webforum.nu/p/1558785

---

Tråden på webben: https://www.webforum.nu/amne/asp/123089-dynamisk-update