---
title: "2 funktioner"
type: "forum-thread"
url: "https://www.webforum.nu/amne/asp/122857-2-funktioner"
topic: "ASP"
topic_url: "https://www.webforum.nu/amne/asp"
author: "asp"
published: "2005-02-20T11:49:21.000Z"
updated: "2005-03-02T21:18:36.000Z"
replies: 11
views: 464
page: 1
pages: 1
language: "sv-SE"
site: "webForum — webforum.nu"
rights: "Upphovsrätten till varje inlägg tillhör dess författare."
attribution: "Citera som: webForum, https://www.webforum.nu/amne/asp/122857-2-funktioner"
---

# 2 funktioner

## #1 — asp, 2005-02-20T11:49Z

Hej, jag efterlyser två stycken funktioner.

\#1. Allt mellan \< och \> tas bort.

\#2. Gör \<br\> på alla vbCrLf men dock inte mellan \< och \>.

Permalänk: https://www.webforum.nu/p/122857

## #2 — Sharkie, 2005-02-20T12:35Z

\#1: Hm... låter som Regular Expression är nått för dig, har tyvärr inte själv satt mig in i det så jag kan inte hjälpa dig tyvärr.

\#2: replace(TEXTEN,vbcrlf,"\<br\>")

Permalänk: https://www.webforum.nu/p/1557484

## #3 — Erik Juhlin, 2005-02-20T14:53Z

Båda kräver RegExp.
Ettan är ganska enkel:

```
Function RemoveHTML(ByVal sString)
	Dim objRegExp
	Set objRegExp = New RegExp
	objRegExp.Global = True
	objRegExp.Pattern = "<[^>]*>"
	RemoveHTML = objRegExp.Replace(sString, "")
	Set objRegExp = Nothing
End Function
```

Tvåan är dock lite mer krånglig...

```
Function BreakNonHTML(ByVal sString)
	Dim objRegExp, mc, mi, lLastIndex, sMatch, sBefore, vMatch, i
	
	Set objRegExp = New RegExp
	objRegExp.Global = True
	objRegExp.Pattern = "<[^>]*>"
	Set mc = objRegExp.Execute(sString)
	Set objRegExp = Nothing
	
	ReDim vMatch(mc.Count * 2)
	lLastIndex = 1
	For Each mi In mc
		sBefore = Mid(sString, lLastIndex, mi.FirstIndex - lLastIndex + 1)
		sMatch = mi.Value
		vMatch(i) = Replace(sBefore, vbCrLf, "<br>")
		vMatch(i + 1) = sMatch
		
		lLastIndex = mi.FirstIndex + Len(sMatch) + 1
		i = i + 2
	Next 'mi
	vMatch(i) = Replace(Mid(sString, lLastIndex), vbCrLf, "<br>")
	
	Set mi = Nothing
	
	BreakNonHTML = Join(vMatch, "")
End Function
```

Permalänk: https://www.webforum.nu/p/1557516

## #4 — asp, 2005-02-20T16:08Z

Grymt mkt tack!

Permalänk: https://www.webforum.nu/p/1557527

## #5 — asp, 2005-02-20T16:23Z

Jag får detta.

Körningsfel i Microsoft VBScript (0x800A005E)
Ogiltig användning av Null: 'Replace'

På denna rad: vMatch(i) = Replace(Mid(sString, lLastIndex), vbCrLf, "\<br\>")

Såhär skriver jag ut.

makeBr(objRs("brodtext"))

Permalänk: https://www.webforum.nu/p/1557534

## #6 — @nders, 2005-02-20T16:32Z

Om fältet brodtext är null så måste du hantera det på något sätt. Exempel:

```
response.write makeBr("" & objRs("brodtext"))
```

Permalänk: https://www.webforum.nu/p/1557540

## #7 — asp, 2005-02-24T15:38Z

Tack, det fungerar. Men oavsett om fältet var tomt eller inte fick jag felmeddelande, konstigt!

Permalänk: https://www.webforum.nu/p/1559473

## #8 — asp, 2005-02-26T13:44Z

Hmm en fråga..

Den andra funktionen var lite fel, jag beskrev fel.

Det jag vill är att den inte skall lägga till \<br\> på varje rad om det är mellan \< och \> utan att den skall inte lägga till \<br\> om det är html kod.

t.ex. så krånglar det när man skapar en tabell...

Permalänk: https://www.webforum.nu/p/1563116

## #9 — Erik Juhlin, 2005-02-27T18:52Z

Koden jag skrev lägger till \<br\> om det inte är mellan \< och \>.

Hur menade du?

Permalänk: https://www.webforum.nu/p/1563586

## #10 — asp, 2005-03-01T20:31Z

Jo, det är bra. Men t.ex. det blir buggigt vid detta exempel. (Jag vet att inte funktionen klarar av det.)

Här är texten:

```
<table>
  <tr>
  <td>Hej</td>
  <td>Då!</td>
  </tr>
</table>
```

Såhär blir det:

```
<table><br>
  <tr><br>
  <td>Hej</td><br>
  <td>Då!</td><br>
  </tr><br>
</table><br>
```

Förstår du? En smart lösning kanske skulle vara att skriva (kod) och (/kod) runt HTML-kod när den innehåller flera rader kod.

Permalänk: https://www.webforum.nu/p/1564398

## #11 — Erik Juhlin, 2005-03-02T12:54Z

Varför inte se till att texterna inuti tabellcellerna innehåller \<br\>-radbrytningar då?

Permalänk: https://www.webforum.nu/p/1564601

## #12 — asp, 2005-03-02T21:18Z

Hmm.. vad menar du?

Kanske man skall göra så att det inte blir \<br\> på de rader som börjar på \< och slutar på \>. ?

Permalänk: https://www.webforum.nu/p/1564843

---

Tråden på webben: https://www.webforum.nu/amne/asp/122857-2-funktioner