---
title: "Hjälp med upload, som filnamn sparas i databasen"
type: "forum-thread"
url: "https://www.webforum.nu/amne/asp/119694-hjälp-med-upload-som-filnamn-sparas-i-databasen"
topic: "ASP"
topic_url: "https://www.webforum.nu/amne/asp"
author: "cyeclone"
published: "2005-01-09T17:38:49.000Z"
updated: "2005-01-10T04:16:31.000Z"
replies: 3
views: 307
page: 1
pages: 1
language: "sv-SE"
site: "webForum — webforum.nu"
rights: "Upphovsrätten till varje inlägg tillhör dess författare."
attribution: "Citera som: webForum, https://www.webforum.nu/amne/asp/119694-hjälp-med-upload-som-filnamn-sparas-i-databasen"
---

# Hjälp med upload, som filnamn sparas i databasen

## #1 — cyeclone, 2005-01-09T17:38Z

Hejsan!

Sitter nu och klämmer till en del av det sista på min webshop, behöver nu lite hjälp med uploadscriptet. Om jag inte "bläddrar" och lägger till en bild i formen, så får jag ett fel meddelande på denna kod.
Jag vill att det ska fungera att skicka en post utan en bild..

```
<!--#include file="includes/settings.asp"-->
<%
	Set Upload = Server.CreateObject("Persits.Upload.1")
	
	Upload.OverwriteFiles = False

	Upload.SetMaxSize 1048576	' Limit files to 1MB
	Count = Upload.Save(""&rooten&"")
	%>
<%
Set Connect = Server.CreateObject("ADODB.Connection")
  	Connect.Open "driver={Microsoft Access Driver (*.mdb)};dbq=" & Server.MapPath(" "&databas&" ")&";pwd=lurifix!"
  	Set RecSet = Server.CreateObject("ADODB.Recordset")
	lol = "Select * FROM Produkter"
	RecSet.Open lol, Connect, 1, 3
	
	RecSet.addnew
	Recset("Art-Nr") = Upload.Form("Art-Nr")
	Recset("produktnamn") = Upload.Form("produktnamn")
	Recset("pris") = Upload.Form("pris")
	Recset("reapris") = Upload.Form("reapris")
	Recset("besk") = Upload.Form("besk")
	Recset("bild") = Upload.Files(1).ExtractFileName
	Recset("MID") = Upload.Form("MID")
	Recset("KAID") = Upload.Form("KAID")
	Recset("visa") = Upload.Form("visa")
	
	RecSet.Update
	RecSet.Close
	
	session("adminmess") = "Produkten är nu tillagt."
	response.Redirect "index.asp?page=login_admin&admin_page=start&a=produkter" 
		%>
```

felmedelande:

```
Microsoft VBScript runtime error '800a01a8' 

Object required: 'Upload' 

/admin_produkter_new3.asp, line 23
```

line 23:

```
Recset("bild") = Upload.Files(1).ExtractFileName
```

För när jag laddar upp en bild, så vill jag att filnamnet ska sparas i databasen, men eftersom det inte är någon fil med så vet jag inte hur det ska bli, man kanske kan ersätta line23 alltså "Recset("bild") = Upload.Files(1).ExtractFileName" med att man skriver in värdet ingenbild.gif istället? men jag har inte kommit på någon bra lösning för detta.. och vet inte hur jag ska göra det.

Skulle vara tacksam för svar!

Permalänk: https://www.webforum.nu/p/119694

## #2 — airwolf, 2005-01-10T00:08Z

är det inte enklare om du döper om bilden vid uppladdning till tex artikelnummer så kommer du även undan risken att en bild blir överskriven med en som har samma namn

Permalänk: https://www.webforum.nu/p/1524451

## #3 — cyeclone, 2005-01-10T01:51Z

"Upload.OverwriteFiles = False" löser det med risken att en bild blir överskriven.... Men hur skulle det hjälpa mig om jag bytte namn på filen innan uppladdning?

Permalänk: https://www.webforum.nu/p/1524476

## #4 — @nders, 2005-01-10T04:16Z

1) Skapa ett filobjekt innan du lägger in informationen i databasen:

```
Set file = Upload.Files("Namnet på file-fältet i formuläret")
If not file is nothing then
   strBild = File.ExtractFileName
Else
   strBild = "ingenbild.gif"
End if
```

Byt sedan ut denna rad:

```
Recset("bild") = Upload.Files(1).ExtractFileName
```

Mot:

```
Recset("bild") = strBild
```

Sedan kan du ta bort de onödiga tomsträngstilläggen här:

```
Count = Upload.Save(""&rooten&"")
```

:

```
Count = Upload.Save(rooten)
```

Försök att inte konkatenera en massa i onödan.

mvh

Permalänk: https://www.webforum.nu/p/1524497

---

Tråden på webben: https://www.webforum.nu/amne/asp/119694-hjälp-med-upload-som-filnamn-sparas-i-databasen